/usr/share/ada/adainclude/opentoken/opentoken-recognizer-string.adb is in libopentoken5-dev 6.0b-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 | -------------------------------------------------------------------------------
--
-- Copyright (C) 1999 Ted Dennison
--
-- This file is part of the OpenToken package.
--
-- The OpenToken package is free software; you can redistribute it and/or
-- modify it under the terms of the GNU General Public License as published
-- by the Free Software Foundation; either version 3, or (at your option)
-- any later version. The OpenToken package is distributed in the hope that
-- it will be useful, but WITHOUT ANY WARRANTY; without even the implied
-- warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
-- GNU General Public License for more details. You should have received
-- a copy of the GNU General Public License distributed with the OpenToken
-- package; see file GPL.txt. If not, write to the Free Software Foundation,
-- 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
--
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an
-- executable, this unit does not by itself cause the resulting
-- executable to be covered by the GNU General Public License. This
-- exception does not however invalidate any other reasons why the
-- executable file might be covered by the GNU Public License.
--
-------------------------------------------------------------------------------
-----------------------------------------------------------------------------
-- This package implements a token recognizer for a string literal.
-- It can optionally use an escape character to introduce special
-- character mappings, and can thus be used to recognize either Ada
-- or C-style strings.
-----------------------------------------------------------------------------
package body OpenToken.Recognizer.String is
overriding procedure Analyze
(The_Token : in out Instance;
Next_Char : in Character;
Verdict : out Analysis_Verdict)
is
begin
case The_Token.State is
when Delimit =>
-- A string must start with the string delimiter
if Next_Char = The_Token.Delimiter then
The_Token.State := Text;
Verdict := So_Far_So_Good;
elsif Next_Char = EOL_Character then
The_Token.State := Done;
Verdict := Failed;
else
The_Token.State := Done;
Verdict := Failed;
end if;
when Text =>
-- Process normal text contents
if Next_Char = The_Token.Delimiter then
-- If its a delimiter, report that we have a good
-- string, but look for the next character to possibly
-- be another delimiter.
if The_Token.Double_Delimiter then
The_Token.State := Double_Delimit;
else
The_Token.State := Done;
end if;
The_Token.Good_Length := The_Token.Value_Length;
Verdict := Matches;
elsif Next_Char = EOL_Character then
The_Token.State := Done;
Verdict := Failed;
-- If its an escape character and we are using escape
-- characters go into escape mode.
elsif Next_Char = The_Token.Escape then
if The_Token.Escapeable then
The_Token.State := Escaped_Text;
Verdict := So_Far_So_Good;
else
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Next_Char;
end if;
else
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Next_Char;
end if;
-- Process escaped characters
when Escaped_Text =>
-- If its a number, start to calculate its value.
if Next_Char in '0' .. '7' then
The_Token.State := Escaped_Octal_Number;
The_Token.Esc_Code := Natural'Value ((1 => Next_Char));
Verdict := So_Far_So_Good;
-- ..otherwise, if its an x, the next characters should be hex digits
elsif Next_Char = 'x' then
The_Token.State := First_Hex_Digit;
Verdict := So_Far_So_Good;
-- ...otherwise, return the mapped value for the character.
else
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) :=
Ada.Strings.Maps.Value (Map => The_Token.Escape_Mapping,
Element => Next_Char);
end if;
-- Process escaped octal numbers
when Escaped_Octal_Number =>
-- If its a number, continue to calculate its value.
if Next_Char in '0' .. '7' then
The_Token.Esc_Code := The_Token.Esc_Code * 8 + Natural'Value ((1 => Next_Char));
-- Verify that the number isn't too large to be a character value
if The_Token.Esc_Code <= Character'Pos (Character'Last) then
The_Token.State := Escaped_Octal_Number;
Verdict := So_Far_So_Good;
else
The_Token.State := Done;
Verdict := Failed;
end if;
elsif Next_Char = EOL_Character then
The_Token.State := Done;
Verdict := Failed;
-- ...otherwise, return the character value for the given number, and process the character as text
else
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Character'Val (The_Token.Esc_Code);
if Next_Char = The_Token.Delimiter then
-- If its a delimiter, report that we have a good
-- string, but look for the next character to
-- possibly be another delimiter.
if The_Token.Double_Delimiter then
The_Token.State := Double_Delimit;
else
The_Token.State := Done;
end if;
The_Token.Good_Length := The_Token.Value_Length;
Verdict := Matches;
elsif Next_Char = The_Token.Escape then
The_Token.State := Escaped_Text;
Verdict := So_Far_So_Good;
else
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Next_Char;
end if;
end if;
-- Process the first hex digit
when First_Hex_Digit =>
-- If its a number, continue to calculate its value.
if Next_Char in '0' .. '9' then
The_Token.Esc_Code := Natural'Value ((1 => Next_Char));
The_Token.State := Escaped_Hex_Number;
Verdict := So_Far_So_Good;
elsif Next_Char in 'a' .. 'f' then
The_Token.Esc_Code := Character'Pos (Next_Char) - (Character'Pos ('a') - 10);
The_Token.State := Escaped_Hex_Number;
Verdict := So_Far_So_Good;
elsif Next_Char in 'A' .. 'F' then
The_Token.Esc_Code := Character'Pos (Next_Char) - (Character'Pos ('A') - 10);
The_Token.State := Escaped_Hex_Number;
Verdict := So_Far_So_Good;
elsif Next_Char = EOL_Character then
The_Token.State := Done;
Verdict := Failed;
-- ...otherwise, return the character value for the given
-- number, and process the character as text
else
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Character'Val (The_Token.Esc_Code);
if Next_Char = The_Token.Delimiter then
-- If its a delimiter, report that we have a good
-- string, but look for the next character to
-- possibly be another delimiter.
if The_Token.Double_Delimiter then
The_Token.State := Double_Delimit;
else
The_Token.State := Done;
end if;
The_Token.Good_Length := The_Token.Value_Length;
Verdict := Matches;
elsif Next_Char = The_Token.Escape then
The_Token.State := Escaped_Text;
Verdict := So_Far_So_Good;
else
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Next_Char;
end if;
end if;
-- Process the first hex digit
when Escaped_Hex_Number =>
-- If its a number, continue to calculate its value.
if Next_Char in '0' .. '9' then
The_Token.Esc_Code := The_Token.Esc_Code * 16 + Natural'Value ((1 => Next_Char));
The_Token.State := Text;
Verdict := So_Far_So_Good;
elsif Next_Char in 'a' .. 'f' then
The_Token.Esc_Code := The_Token.Esc_Code * 16 +
Character'Pos (Next_Char) - (Character'Pos ('a') - 10);
The_Token.State := Text;
Verdict := So_Far_So_Good;
elsif Next_Char in 'A' .. 'F' then
The_Token.Esc_Code := The_Token.Esc_Code * 16 +
Character'Pos (Next_Char) - (Character'Pos ('A') - 10);
The_Token.State := Text;
Verdict := So_Far_So_Good;
elsif Next_Char = EOL_Character then
The_Token.State := Done;
Verdict := Failed;
-- ...otherwise, return the character value for the given
-- number, and process the character as text
else
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Character'Val (The_Token.Esc_Code);
if Next_Char = The_Token.Delimiter then
-- If its a delimiter, report that we have a good
-- string, but look for the next character to
-- possibly be another delimiter.
if The_Token.Double_Delimiter then
The_Token.State := Double_Delimit;
else
The_Token.State := Done;
end if;
The_Token.Good_Length := The_Token.Value_Length;
Verdict := Matches;
elsif Next_Char = The_Token.Escape then
The_Token.State := Escaped_Text;
Verdict := So_Far_So_Good;
else
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := Next_Char;
end if;
end if;
-- Process the character after the delimiter
when Double_Delimit =>
-- if its another delimiter, insert the delimiter
-- character itself and keep going.
if Next_Char = The_Token.Delimiter then
The_Token.State := Text;
Verdict := So_Far_So_Good;
The_Token.Value_Length := The_Token.Value_Length + 1;
The_Token.Value (The_Token.Value_Length) := The_Token.Delimiter;
else
The_Token.State := Done;
Verdict := Failed;
end if;
-- It can't possibly match after this...
when Done =>
Verdict := Failed;
end case;
end Analyze;
overriding procedure Clear (The_Token : in out Instance) is
begin
The_Token.State := Delimit;
The_Token.Value_Length := 0;
The_Token.Good_Length := 0;
end Clear;
--------------------------------------------------------------------------
-- This procedure will be called to create a String literal token.
-- If Escapable is set to False, the string will treat the Escape
-- character as any other character.
--
-- If all parameters are defaulted, an Ada-style string token will
-- be created. If Escapeable is set to True and all other
-- parameters are defaulted, a C-style string token will be
-- created.
--------------------------------------------------------------------------
function Get
(Delimiter : in Character := '"';
Double_Delimiter : in Boolean := True;
Escapeable : in Boolean := False;
Escape : in Character := '\';
Escape_Mapping : in Ada.Strings.Maps.Character_Mapping := C_Style_Escape_Code_Map)
return Instance
is begin
return (Report => True,
State => Delimit,
Esc_Code => 0,
Delimiter => Delimiter,
Double_Delimiter => Double_Delimiter,
Escapeable => Escapeable,
Escape => Escape,
Escape_Mapping => Escape_Mapping,
Value => (others => Ada.Characters.Latin_1.NUL),
Value_Length => 0,
Good_Length => 0
);
end Get;
--------------------------------------------------------------------------
-- Return the translated value of the recognized string. This will
-- not include any quotation characters. The escape mapping will
-- have been applied, and internal sets of double quotes will
-- appear as a single double-quote character.
--------------------------------------------------------------------------
function Value (Recognized_String : in Instance) return Standard.String is
begin
return Recognized_String.Value (1 .. Recognized_String.Good_Length);
end Value;
end OpenToken.Recognizer.String;
|