/usr/share/ada/adainclude/opentoken/opentoken-recognizer-bracketed_comment.adb is in libopentoken5-dev 6.0b-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 | -------------------------------------------------------------------------------
--
-- Copyright (C) 2010, 2012, 2014 Stephen Leake
-- Copyright (C) 1999 Christoph Karl Walter Grein
--
-- This file is part of the OpenToken package.
--
-- The OpenToken package is free software; you can redistribute it and/or
-- modify it under the terms of the GNU General Public License as published
-- by the Free Software Foundation; either version 3, or (at your option)
-- any later version. The OpenToken package is distributed in the hope that
-- it will be useful, but WITHOUT ANY WARRANTY; without even the implied
-- warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
-- GNU General Public License for more details. You should have received
-- a copy of the GNU General Public License distributed with the OpenToken
-- package; see file GPL.txt. If not, write to the Free Software Foundation,
-- 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
--
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an
-- executable, this unit does not by itself cause the resulting
-- executable to be covered by the GNU General Public License. This
-- exception does not however invalidate any other reasons why the
-- executable file might be covered by the GNU Public License.
--
-------------------------------------------------------------------------------
-----------------------------------------------------------------------------
-- This package implements a token recognizer for a bracketed
-- comment. A bracketed comment is a comment that runs from the
-- opener to the closer, optionally enclosing several lines.
-----------------------------------------------------------------------------
package body OpenToken.Recognizer.Bracketed_Comment is
overriding procedure Clear (The_Token : in out Instance) is
begin
The_Token.State := Opener;
The_Token.Bracket_State := 1;
The_Token.Nested_Depth := 0;
end Clear;
overriding procedure Analyze
(The_Token : in out Instance;
Next_Char : in Character;
Verdict : out Analysis_Verdict)
is
use Ada.Strings.Unbounded;
begin
case The_Token.State is
when Opener =>
-- The character must match the comment opener string
if Next_Char = The_Token.Opener_Text (The_Token.Bracket_State) then
Verdict := So_Far_So_Good;
if The_Token.Bracket_State = The_Token.Opener_Length then
The_Token.State := Text;
else
The_Token.Bracket_State := The_Token.Bracket_State + 1;
end if;
else
Verdict := Failed;
The_Token.State := Done;
end if;
when Nest_Opener =>
if Next_Char = The_Token.Opener_Text (The_Token.Bracket_State) then
if The_Token.Bracket_State = The_Token.Opener_Length then
The_Token.Nested_Depth := The_Token.Nested_Depth + 1;
Verdict := So_Far_So_Good;
The_Token.State := Text;
else
Verdict := So_Far_So_Good;
The_Token.Bracket_State := The_Token.Bracket_State + 1;
end if;
if The_Token.Report then
The_Token.Text := The_Token.Text & Next_Char;
end if;
else
Verdict := So_Far_So_Good;
The_Token.State := Text;
end if;
when Text =>
-- When we hit the first character of the closer, it might
-- be the end of the comment.
Verdict := So_Far_So_Good;
if Next_Char = The_Token.Closer_Text (1) then
if The_Token.Nested then
if The_Token.Closer_Length = 1 then
The_Token.Nested_Depth := The_Token.Nested_Depth - 1;
else
The_Token.State := Nest_Closer;
The_Token.Bracket_State := 2;
end if;
else
if The_Token.Closer_Length = 1 then
Verdict := Matches;
The_Token.State := Done;
else
The_Token.State := Closer;
The_Token.Bracket_State := 2;
end if;
end if;
elsif The_Token.Nested and then Next_Char = The_Token.Opener_Text (1) then
The_Token.State := Nest_Opener;
The_Token.Bracket_State := 2;
end if;
when Nest_Closer =>
if Next_Char = The_Token.Closer_Text (The_Token.Bracket_State) then
if The_Token.Bracket_State = The_Token.Closer_Length then
The_Token.Nested_Depth := The_Token.Nested_Depth - 1;
Verdict := So_Far_So_Good;
The_Token.State := Text;
else
Verdict := So_Far_So_Good;
The_Token.Bracket_State := The_Token.Bracket_State + 1;
end if;
elsif Next_Char = The_Token.Closer_Text (1) then
The_Token.Bracket_State := 2;
Verdict := So_Far_So_Good;
else
Verdict := So_Far_So_Good;
The_Token.State := Text;
end if;
when Closer =>
if Next_Char = The_Token.Closer_Text (The_Token.Bracket_State) then
if The_Token.Bracket_State = The_Token.Closer_Length then
Verdict := Matches;
The_Token.State := Done;
else
Verdict := So_Far_So_Good;
The_Token.Bracket_State := The_Token.Bracket_State + 1;
end if;
elsif Next_Char = The_Token.Closer_Text (1) then
Verdict := So_Far_So_Good;
The_Token.State := Closer;
The_Token.Bracket_State := 2;
else
Verdict := So_Far_So_Good;
The_Token.State := Text;
end if;
when Done =>
-- We shouldn't get called from here.
Verdict := Failed;
end case;
end Analyze;
function Get
(Comment_Opener : in String;
Comment_Closer : in String;
Reportable : in Boolean := False;
Nested : in Boolean := False)
return Instance
is
begin
return
(Report => Reportable,
Nested => Nested,
Opener_Text => Comment_Opener & (Comment_Opener'Length + 1 .. Max_Bracket_Length => ' '),
Closer_Text => Comment_Closer & (Comment_Closer'Length + 1 .. Max_Bracket_Length => ' '),
Opener_Length => Comment_Opener'Length,
Closer_Length => Comment_Closer'Length,
State => Opener,
Bracket_State => 1,
Nested_Depth => 0,
Text => Ada.Strings.Unbounded.Null_Unbounded_String);
end Get;
function Value (Item : in Instance) return String
is begin
return Ada.Strings.Unbounded.To_String (Item.Text);
end Value;
end OpenToken.Recognizer.Bracketed_Comment;
|