/usr/share/ada/adainclude/opentoken/opentoken-recognizer-based_integer_real_ada.adb is in libopentoken5-dev 6.0b-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 | -- Abstract :
--
-- See spec
--
-- Copyright (C) 2014-2015 Stephen Leake
--
-- This file is part of the OpenToken package.
--
-- The OpenToken package is free software; you can redistribute it
-- and/or modify it under the terms of the GNU General Public License
-- as published by the Free Software Foundation; either version 3, or
-- (at your option) any later version. The OpenToken package is
-- distributed in the hope that it will be useful, but WITHOUT ANY
-- WARRANTY; without even the implied warranty of MERCHANTABILITY or
-- FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
-- License for more details. You should have received a copy of the
-- GNU General Public License distributed with the OpenToken package;
-- see file GPL.txt. If not, write to the Free Software Foundation,
-- 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
--
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an
-- executable, this unit does not by itself cause the resulting
-- executable to be covered by the GNU General Public License. This
-- exception does not however invalidate any other reasons why the
-- executable file might be covered by the GNU Public License.
pragma License (Modified_GPL);
package body OpenToken.Recognizer.Based_Integer_Real_Ada is
overriding procedure Clear (Token : in out Instance)
is begin
-- Reset number_recognizer to decimal
Token.Number_Recognizer := Extended_Digits.Get
(Allow_Underscores => True,
For_Base => 10);
Token.Last_Digits_Verdict := Failed;
Token.State := Base;
Token.Base := 0;
Token.Need_Hash := False;
end Clear;
overriding procedure Analyze
(Token : in out Instance;
Next_Char : in Character;
Verdict : out Analysis_Verdict)
is
Digits_Verdict : Analysis_Verdict := Failed;
begin
case Token.State is
when Base =>
Extended_Digits.Analyze (Token.Number_Recognizer, Next_Char, Digits_Verdict);
case Digits_Verdict is
when Matches =>
-- Next_Char is decimal digit
Token.Base := (Token.Base * 10) + (Character'Pos (Next_Char) - Character'Pos ('0'));
if Token.Base <= Extended_Digits.Maximum_Base then
-- A based integer, decimal integer, or decimal real
Verdict := Matches;
else
-- A decimal integer or decimal real
Token.State := Fore;
Verdict := Matches;
end if;
when So_Far_So_Good =>
-- Next_Char is '_'
Verdict := So_Far_So_Good;
when Failed =>
-- Extended_Digits can fail for a trailing underscore, or for a non-digit.
case Token.Last_Digits_Verdict is
when Matches =>
-- non-digit
if Next_Char = '#' then
Token.Need_Hash := True;
-- use Base for the rest of the number
Token.Number_Recognizer := Extended_Digits.Get
(Allow_Underscores => True,
For_Base => Token.Base);
Verdict := So_Far_So_Good;
Token.State := Fore;
else
Verdict := Failed;
Token.State := Done;
end if;
when So_Far_So_Good =>
-- trailing underscore in base
Verdict := Failed;
Token.State := Done;
when Failed =>
-- First char in token; not a number
Verdict := Failed;
Token.State := Done;
end case;
end case;
when Fore =>
Extended_Digits.Analyze (Token.Number_Recognizer, Next_Char, Digits_Verdict);
case Digits_Verdict is
when So_Far_So_Good | Matches =>
-- integer or real. Extended_Digits returns So_Far_So_Good for underscore
Verdict := Digits_Verdict;
when Failed =>
case Token.Last_Digits_Verdict is
when Matches =>
-- non-digit
if Next_Char = '.' then
-- real number
Verdict := So_Far_So_Good;
Token.State := Aft;
Extended_Digits.Clear (Token.Number_Recognizer);
elsif Next_Char = '#' and Token.Need_Hash then
Verdict := Matches;
Token.State := Exponent_E;
else
Verdict := Failed;
Token.State := Done;
end if;
when So_Far_So_Good =>
-- Trailing underscore
Verdict := Failed;
Token.State := Done;
when Failed =>
raise Programmer_Error with "Fore: State should be Done";
end case;
end case;
when Aft =>
Extended_Digits.Analyze (Token.Number_Recognizer, Next_Char, Digits_Verdict);
case Digits_Verdict is
when So_Far_So_Good | Matches =>
Verdict := Digits_Verdict;
when Failed =>
case Token.Last_Digits_Verdict is
when Matches =>
-- Non-digit
if Token.Need_Hash then
if Next_Char = '#' then
Verdict := Matches;
Token.State := Exponent_E;
else
Verdict := Failed;
Token.State := Done;
end if;
elsif Next_Char = 'e' or Next_Char = 'E' then
Verdict := So_Far_So_Good;
Token.State := Exponent_Sign;
-- Reset to decimal for exponent
Token.Number_Recognizer := Extended_Digits.Get
(Allow_Underscores => True,
For_Base => 10);
else
Verdict := Failed;
Token.State := Done;
end if;
when So_Far_So_Good =>
-- Trailing underscore
Verdict := Failed;
Token.State := Done;
when Failed =>
-- First char in aft; not a real
Verdict := Failed;
Token.State := Done;
end case;
end case;
when Exponent_E =>
if Next_Char = 'e' or Next_Char = 'E' then
Verdict := So_Far_So_Good; --
Token.State := Exponent_Sign;
-- Reset to decimal for exponent
Token.Number_Recognizer := Extended_Digits.Get
(Allow_Underscores => True,
For_Base => 10);
else
Verdict := Failed;
Token.State := Done;
end if;
when Exponent_Sign =>
if Next_Char = '+' or Next_Char = '-' then
Verdict := So_Far_So_Good;
Token.State := Exponent;
else
Extended_Digits.Analyze (Token.Number_Recognizer, Next_Char, Digits_Verdict);
if Digits_Verdict = Matches then
Verdict := Matches;
Token.State := Exponent;
else
Verdict := Failed;
Token.State := Done;
end if;
end if;
when Exponent =>
Extended_Digits.Analyze (Token.Number_Recognizer, Next_Char, Digits_Verdict);
case Digits_Verdict is
when So_Far_So_Good | Matches =>
Verdict := Digits_Verdict;
when Failed =>
Verdict := Failed;
Token.State := Done;
end case;
when Done =>
Verdict := Failed;
end case;
Token.Last_Digits_Verdict := Digits_Verdict;
end Analyze;
function Get return Instance
is begin
return
(Report => True,
Number_Recognizer => Extended_Digits.Get (Allow_Underscores => True, For_Base => 10),
Last_Digits_Verdict => Failed,
State => Base,
Base => 0,
Need_Hash => False);
end Get;
end OpenToken.Recognizer.Based_Integer_Real_Ada;
|