/usr/share/dialer-app/DialerPage/DialerPage.qml is in dialer-app 0.1+16.04.20160317-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 | /*
* Copyright 2012-2013 Canonical Ltd.
*
* This file is part of dialer-app.
*
* dialer-app is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* dialer-app is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtContacts 5.0
import QtQuick 2.0
import Ubuntu.Components 1.3
import Ubuntu.Components.Popups 1.3
import Ubuntu.Telephony 0.1
import Ubuntu.Contacts 0.1
import Ubuntu.Components.ListItems 1.3 as ListItems
import "../"
PageWithBottomEdge {
id: page
property alias dialNumber: keypadEntry.value
property alias input: keypadEntry.input
property alias callAnimationRunning: callAnimation.running
property bool greeterMode: false
property var mmiPlugins: []
property var accountsModel: {
var model = []
// do not show any accounts in greeter mode
if (mainView.greeterMode) {
return []
}
// populate model with all active phone accounts
for (var i in telepathyHelper.activeAccounts) {
var account = telepathyHelper.activeAccounts[i]
if (account.type == AccountEntry.PhoneAccount) {
model.push(account)
}
}
// do not show dual sim switch if there is only one sim
if (model.length == 1 && model[0].type == AccountEntry.PhoneAccount) {
return []
}
return model
}
property list<Action> actionsGreeter
property list<Action> actionsNormal: [
Action {
objectName: "contacts"
iconName: "contact"
text: i18n.tr("Contacts")
onTriggered: pageStackNormalMode.push(Qt.resolvedUrl("../ContactsPage/ContactsPage.qml"))
},
Action {
iconName: "settings"
text: i18n.tr("Settings")
onTriggered: Qt.openUrlExternally("settings:///system/phone")
}
]
head.actions: mainView.greeterMode ? actionsGreeter : actionsNormal
head.backAction: Action {
iconName: "back"
text: i18n.tr("Close")
visible: mainView.greeterMode
onTriggered: {
greeter.showGreeter()
dialNumber = "";
}
}
objectName: "dialerPage"
title: {
// avoid clearing the title when app is inactive
// under some states
if (!mainView.telepathyReady) {
return i18n.tr("Initializing...")
} else if (greeter.greeterActive) {
if (mainView.applicationActive) {
return i18n.tr("Emergency Calls")
} else {
return " "
}
} else if (telepathyHelper.flightMode) {
return i18n.tr("Flight Mode")
} else if (mainView.account && mainView.account.simLocked) {
return i18n.tr("SIM Locked")
} else if (mainView.account && mainView.account.networkName != "") {
return mainView.account.networkName
} else if (multiplePhoneAccounts && !mainView.account) {
return i18n.tr("Phone")
}
return i18n.tr("No network")
}
state: mainView.state
// -------- Greeter mode ----------
states: [
State {
name: "greeterMode"
PropertyChanges {
target: contactLabel
visible: false
}
PropertyChanges {
target: addContact
visible: false
}
},
State {
name: "normalMode"
PropertyChanges {
target: contactLabel
visible: true
}
PropertyChanges {
target: addContact
visible: true
}
}
]
// -------- Bottom Edge Setup -----
bottomEdgeEnabled: !mainView.greeterMode
bottomEdgePageSource: Qt.resolvedUrl("../HistoryPage/HistoryPage.qml")
// NOTE: uncomment the next line to re-enable progressive bottom edge swiping.
//bottomEdgeExpandThreshold: bottomEdgePage ? bottomEdgePage.delegateHeight * 3 : 0
bottomEdgeTitle: i18n.tr("Recent")
reloadBottomEdgePage: true
property int historyDelegateHeight: bottomEdgePage ? bottomEdgePage.delegateHeight : 1
onBottomEdgeExposedAreaChanged: {
if (!bottomEdgePage) {
return
}
var index = Math.floor(bottomEdgeExposedArea / historyDelegateHeight)
if (index < 3) {
bottomEdgePage.currentIndex = index
} else {
bottomEdgePage.currentIndex = -1
}
}
onBottomEdgeReleased: {
if (bottomEdgePage.currentIndex < 3) {
bottomEdgePage.activateCurrentIndex()
} else {
bottomEdgePage.currentIndex = -1
}
}
onIsCollapsedChanged: {
if (isCollapsed && bottomEdgePage) {
// reset the history page to the "All" view
bottomEdgePage.head.sections.selectedIndex = 0;
}
}
function accountIndex(account) {
var index = -1;
for (var i in page.accountsModel) {
if (page.accountsModel[i] == account) {
index = i;
break;
}
}
return index;
}
function triggerCallAnimation() {
callAnimation.start();
}
Connections {
target: mainView
onPendingNumberToDialChanged: {
keypadEntry.value = mainView.pendingNumberToDial;
if (mainView.pendingNumberToDial !== "") {
mainView.switchToKeypadView();
}
}
}
Component.onCompleted: {
// load MMI plugins
var plugins = application.mmiPluginList()
for (var i in plugins) {
var component = Qt.createComponent(plugins[i]);
mmiPlugins.push(component.createObject(page))
}
}
head.sections.model: {
var accountNames = []
for (var i in page.accountsModel) {
accountNames.push(page.accountsModel[i].displayName)
}
return accountNames
}
Connections {
target: mainView
onAccountChanged: {
// FIXME: the selectedIndex binding is being broken by the sdk. this is just a workaround.
head.sections.selectedIndex = Qt.binding(function() { return accountIndex(mainView.account) })
}
}
head.sections.selectedIndex: accountIndex(mainView.account)
Connections {
target: page.head.sections
onSelectedIndexChanged: {
mainView.account = page.accountsModel[page.head.sections.selectedIndex]
}
}
// background
Rectangle {
anchors.fill: parent
color: Theme.palette.normal.background
}
FocusScope {
id: keypadContainer
anchors.fill: parent
focus: true
Item {
id: entryWithButtons
anchors {
top: parent.top
left: parent.left
leftMargin: units.gu(2)
right: parent.right
rightMargin: units.gu(2)
}
height: units.gu(10)
CustomButton {
id: addContact
anchors {
left: parent.left
verticalCenter: parent.verticalCenter
}
width: opacity > 0 ? units.gu(4) : 0
height: (keypadEntry.value !== "" && contactWatcher.isUnknown) ? parent.height : 0
icon: "contact-new"
iconWidth: units.gu(3)
iconHeight: units.gu(3)
opacity: (keypadEntry.value !== "" && contactWatcher.isUnknown) ? 1.0 : 0.0
Behavior on opacity {
UbuntuNumberAnimation { }
}
Behavior on width {
UbuntuNumberAnimation { }
}
onClicked: mainView.addNewPhone(keypadEntry.value)
}
KeypadEntry {
id: keypadEntry
objectName: "keypadEntry"
anchors {
top: parent.top
topMargin: units.gu(3)
left: addContact.right
right: backspace.left
}
height: units.gu(4)
focus: true
placeHolder: i18n.tr("Enter a number")
Keys.forwardTo: [callButton]
value: mainView.pendingNumberToDial
}
CustomButton {
id: backspace
objectName: "eraseButton"
anchors {
right: parent.right
verticalCenter: parent.verticalCenter
}
width: opacity > 0 ? units.gu(4) : 0
height: input.text !== "" ? parent.height : 0
icon: "erase"
iconWidth: units.gu(3)
iconHeight: units.gu(3)
opacity: input.text !== "" ? 1 : 0
Behavior on opacity {
UbuntuNumberAnimation { }
}
Behavior on width {
UbuntuNumberAnimation { }
}
onPressAndHold: input.text = ""
onClicked: {
if (input.cursorPosition > 0) {
input.remove(input.cursorPosition, input.cursorPosition - 1)
}
}
}
}
ListItems.ThinDivider {
id: divider
anchors {
left: parent.left
leftMargin: units.gu(2)
right: parent.right
rightMargin: units.gu(2)
top: entryWithButtons.bottom
}
}
ContactWatcher {
id: contactWatcher
identifier: keypadEntry.value
// for this contact watcher we are only interested in matching phone numbers
addressableFields: ["tel"]
}
Label {
id: contactLabel
anchors {
horizontalCenter: divider.horizontalCenter
bottom: entryWithButtons.bottom
bottomMargin: units.gu(1)
}
text: contactWatcher.isUnknown ? "" : contactWatcher.alias
color: UbuntuColors.darkGrey
opacity: text != "" ? 1 : 0
fontSize: "small"
Behavior on opacity {
UbuntuNumberAnimation { }
}
}
Keypad {
id: keypad
showVoicemail: true
anchors {
top: divider.bottom
topMargin: units.gu(2)
horizontalCenter: parent.horizontalCenter
}
onKeyPressed: {
callManager.playTone(keychar);
input.insert(input.cursorPosition, keychar)
if(checkMMI(dialNumber)) {
// check for custom strings
for (var i in mmiPlugins) {
if (mmiPlugins[i].code == dialNumber) {
dialNumber = ""
mmiPlugins[i].trigger()
}
}
}
}
onKeyPressAndHold: {
// we should only call voicemail if the keypad entry was empty,
// but as we add numbers when onKeyPressed is triggered, the keypad entry will be "1"
if (keycode == Qt.Key_1 && dialNumber == "1") {
dialNumber = ""
mainView.callVoicemail()
} else if (keycode == Qt.Key_0) {
// replace 0 by +
input.remove(input.cursorPosition - 1, input.cursorPosition)
input.insert(input.cursorPosition, "+")
}
}
}
}
Item {
id: footer
anchors {
left: parent.left
right: parent.right
bottom: parent.bottom
}
height: units.gu(10)
CallButton {
id: callButton
objectName: "callButton"
enabled: mainView.telepathyReady
anchors {
bottom: footer.bottom
bottomMargin: units.gu(5)
horizontalCenter: parent.horizontalCenter
}
onClicked: {
if (dialNumber == "") {
if (mainView.greeterMode) {
return;
}
keypadEntry.value = generalSettings.lastCalledPhoneNumber
return;
}
if (mainView.greeterMode && !mainView.isEmergencyNumber(dialNumber)) {
// we only allow users to call any number in greeter mode if there are
// no sim cards present. The operator will block the number if it thinks
// it's necessary.
// for phone accounts, active means the the status is not offline:
// "nomodem", "nosim" or "flightmode"
var denyEmergencyCall = false
// while in flight mode we can't detect if sims are present in some devices
if (telepathyHelper.flightMode) {
denyEmergencyCall = true
} else {
for (var i in telepathyHelper.activeAccounts) {
var account = telepathyHelper.activeAccounts[i]
if (account.type == AccountEntry.PhoneAccount) {
denyEmergencyCall = true;
}
}
}
if (denyEmergencyCall) {
// if there is at least one sim card present, just ignore the call
showNotification(i18n.tr("Emergency call"), i18n.tr("This is not an emergency number."))
keypadEntry.value = "";
return;
}
// this is a special case, we need to call using callEmergency() directly to avoid
// all network and dual sim checks we have in mainView.call()
mainView.callEmergency(keypadEntry.value)
return;
}
console.log("Starting a call to " + keypadEntry.value);
mainView.call(keypadEntry.value);
}
}
}
SequentialAnimation {
id: callAnimation
PropertyAction {
target: callButton
property: "color"
value: "red"
}
ParallelAnimation {
UbuntuNumberAnimation {
target: keypadContainer
property: "opacity"
to: 0.0
duration: UbuntuAnimation.SlowDuration
}
UbuntuNumberAnimation {
target: callButton
property: "iconRotation"
to: -90.0
duration: UbuntuAnimation.SlowDuration
}
}
ScriptAction {
script: {
mainView.switchToLiveCall(i18n.tr("Calling"), keypadEntry.value)
keypadEntry.value = ""
callButton.iconRotation = 0.0
keypadContainer.opacity = 1.0
callButton.color = callButton.defaultColor
}
}
}
}
|