/usr/share/z88dk/lib/pps_crt0.asm is in z88dk-data 1.8.ds1-10.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 | ; Kludgey startup for Peters Plus Sprinter
;
; djm 18/5/99
;
; $Id: pps_crt0.asm,v 1.4 2007/06/27 20:49:27 dom Exp $
;
MODULE pps_crt0
;--------
; Include zcc_opt.def to find out some info
;--------
INCLUDE "zcc_opt.def"
;--------
; Some scope definitions
;--------
XREF _main ;main() is always external to crt0 code
XDEF cleanup ;jp'd to by exit()
XDEF l_dcal ;jp(hl)
XDEF _std_seed ;Integer rand() seed
XDEF _vfprintf ;jp to the printf() core
XDEF exitsp ;atexit() variables
XDEF exitcount
XDEF heaplast ;Near malloc heap variables
XDEF heapblocks
XDEF __sgoioblk ;stdio info block
XDEF base_graphics ;Graphical variables
XDEF coords ;Current xy position
XDEF snd_tick ;Sound variable
org $8100 - 512
defw $5845 ;EXE signature
defb $45 ;Reserved (EXE type)
defb $00 ;Version of EXE file
defl 512 ;Offset to code
defw 0 ;Primary loader size or 0 (no primary loader)
defl 0 ;Reserved
defw 0 ;Reserved
defw start ;Loading address
defw start ;Starting address
defw $bfff ;Stack
defs 490 ;Reserved space
.start
ld (start1+1),sp ;Save entry stack
ld hl,-64
add hl,sp
ld sp,hl
ld (exitsp),sp
ld (start_prefix),ix
IF !DEFINED_nostreams
IF DEFINED_ANSIstdio
; Set up the std* stuff so we can be called again
ld hl,__sgoioblk+2
ld (hl),19 ;stdin
ld hl,__sgoioblk+6
ld (hl),21 ;stdout
ld hl,__sgoioblk+10
ld (hl),21 ;stderr
ENDIF
ENDIF
ld de,0
ld hl,$2350
ld b,7
ld a,' '
ld c,$56 ;CLEAR
rst $10
; Work out argc/argv - same as the CPM version
ld hl,0 ; NULL pointer at the end
push hl
ld b,0 ;arguments
ld hl,(start_prefix)
ld a,(hl) ;length of arguments
and a
jr z,argv_done
ld c,a
add hl,bc ;now points to end of arguments
; Try to find the end of the arguments
.argv_loop_1
ld a,(hl)
cp ' '
jr nz,argv_loop_2
ld (hl),0
dec hl
dec c
jr nz,argv_loop_1
; We've located the end of the last argument, try to find the start
.argv_loop_2
ld a,(hl)
cp ' '
jr nz,argv_loop_3
ld (hl),0
inc hl
push hl
inc b
dec hl
.argv_loop_3
dec hl
dec c
jr nz,argv_loop_2
.argv_done
ld hl,end ;name of program (NULL)
push hl
inc b
ld hl,0
add hl,sp ;address of argv
ld c,b
ld b,0
push bc ;argc
push hl ;argv
call _main ;Call user code
pop bc ;kill argv
pop bc ;kill argc
.cleanup
;
; Deallocate memory which has been allocated here!
;
push hl ;save return code
IF !DEFINED_nostreams
IF DEFINED_ANSIstdio
LIB closeall
call closeall
ENDIF
ENDIF
pop bc
.start1 ld sp,0 ;Restore stack to entry value
ld bc,$41 ;exit with - error code
rst $10
ret
.l_dcal jp (hl) ;Used for function pointer calls
;-----------
; Define the stdin/out/err area. For the z88 we have two models - the
; classic (kludgey) one and "ANSI" model
;-----------
.__sgoioblk
IF DEFINED_ANSIstdio
INCLUDE "#stdio_fp.asm"
ELSE
defw -11,-12,-10
ENDIF
;---------------------------------
; Select which printf core we want
;---------------------------------
._vfprintf
IF DEFINED_floatstdio
LIB vfprintf_fp
jp vfprintf_fp
ELSE
IF DEFINED_complexstdio
LIB vfprintf_comp
jp vfprintf_comp
ELSE
IF DEFINED_ministdio
LIB vfprintf_mini
jp vfprintf_mini
ENDIF
ENDIF
ENDIF
;-----------
; Now some variables
;-----------
.coords defw 0 ; Current graphics xy coordinates
.base_graphics defw 0 ; Address of the Graphics map
._std_seed defw 0 ; Seed for integer rand() routines
.exitsp defw 0 ; Address of where the atexit() stack is
.exitcount defb 0 ; How many routines on the atexit() stack
.heaplast defw 0 ; Address of last block on heap
.heapblocks defw 0 ; Number of blocks
.start_prefix defw 0 ; Entry handle from OS
IF DEFINED_NEED1bitsound
.snd_tick defb 0 ; Sound variable
ENDIF
defm "Small C+ PPS" ;Unnecessary file signature
.end defb 0
;-----------------------
; Floating point support
;-----------------------
IF NEED_floatpack
INCLUDE "#float.asm"
.fp_seed defb $80,$80,0,0,0,0 ;FP seed (unused ATM)
.extra defs 6 ;FP register
.fa defs 6 ;FP Accumulator
.fasign defb 0 ;FP register
ENDIF
|