/usr/share/unity8/Components/EdgeBarrier.qml is in unity8-common 8.12+16.04.20160401-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 | /*
* Copyright (C) 2015 Canonical, Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3
/*
An edge barrier for the mouse pointer
The further you push against it, the stronger the visual hint. Until it's
overcome, when passed() is emitted.
*/
Item {
id: root
// Supported values are: Qt.LeftEdge, Qt.RightEdge
property int edge: Qt.LeftEdge
property Item target: parent
function push(amount) { controller.push(amount); }
signal passed()
anchors.top: (edge == Qt.LeftEdge || edge == Qt.RightEdge) ? target.top : undefined
anchors.bottom: (edge == Qt.LeftEdge || edge == Qt.RightEdge) ? target.bottom : undefined
anchors.left: edge == Qt.LeftEdge ? target.left : undefined
anchors.right: edge == Qt.RightEdge ? target.right : undefined
width: units.gu(0.5)
property Component material
Loader {
id: materialContainer
sourceComponent: root.material
anchors.top: parent.top
anchors.bottom: parent.bottom
anchors.left: root.edge == Qt.LeftEdge ? root.left : undefined
anchors.right: root.edge == Qt.RightEdge ? root.right : undefined
anchors.leftMargin: root.edge == Qt.LeftEdge ? -width * (1 - positionProgress) : 0
anchors.rightMargin: root.edge == Qt.RightEdge ? -width * (1 - positionProgress) : 0
property real positionProgress
visible: positionProgress > 0
width: units.gu(2)
}
EdgeBarrierController {
id: controller
objectName: "edgeBarrierController"
anchors.fill: parent
onPassed: root.passed();
}
state: {
if (controller.progress === 0.0) {
return "";
} else if (controller.progress < 1.0) {
return "resisting";
} else { // controller.progress == 1.0
return "passed";
}
}
states: [
State {
name: ""
PropertyChanges { target: materialContainer; opacity: 0.0 }
PropertyChanges { target: materialContainer; positionProgress: 0.0 }
},
State {
name: "resisting"
PropertyChanges { target: materialContainer; opacity: controller.progress }
PropertyChanges { target: materialContainer; positionProgress: controller.progress }
},
State {
name: "passed"
PropertyChanges { target: materialContainer; opacity: 0.0 }
PropertyChanges { target: materialContainer; positionProgress: 1.0 }
}
]
transitions: [
Transition {
from: "passed"; to: ""
},
Transition {
from: "resisting"; to: ""
UbuntuNumberAnimation { target: materialContainer; properties: "opacity,positionProgress" }
},
Transition {
from: "resisting"; to: "passed"
UbuntuNumberAnimation { duration: UbuntuAnimation.BriskDuration; target: materialContainer; property: "opacity" }
}
]
}
|