/usr/share/perl5/Prophet/FilesystemReplica.pm is in libprophet-perl 0.750-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 | package Prophet::FilesystemReplica;
use Any::Moose;
extends 'Prophet::Replica';
use File::Spec;use Params::Validate qw(:all);
use JSON;
use Prophet::Util;
=head2 replica_exists
Returns true if the replica already exists / has been initialized.
Returns false otherwise.
=cut
sub replica_exists {
my $self = shift;
return $self->uuid ? 1 : 0;
}
sub can_initialize {
my $self = shift;
if ( $self->fs_root_parent && -w $self->fs_root_parent ) {
return 1;
}
return 0;
}
=head2 _file_exists PATH
Returns true if PATH is a file or directory in this replica's directory structure
=cut
sub _file_exists {
my $self = shift;
my ($file) = validate_pos( @_, 1 );
return $self->backend->file_exists($file);
}
sub read_file {
my $self = shift;
my ($file) = validate_pos( @_, 1 );
if ( $self->fs_root ) {
# make sure we don't try to read files outside the replica
my $qualified_file = Cwd::fast_abs_path(
Prophet::Util->catfile( $self->fs_root => $file ) );
return undef
if substr( $qualified_file, 0, length( $self->fs_root ) ) ne
$self->fs_root;
}
return $self->_read_file($file);
}
sub _read_file {
my $self = shift;
my ($file) = (@_); # validation is too heavy to be called here
#my ($file) = validate_pos( @_, 1 );
$self->backend->read_file($file);
}
sub _write_file {
my $self = shift;
my %args = (@_); # validate is too heavy to be called here
# my %args = validate( @_, { path => 1, content => 1 } );
$self->backend->write_file(%args);
}
sub read_changeset_index {
my $self= shift;
$self->log_debug( "Reading changeset index file '" .$self->changeset_index . "'" );
my $chgidx = $self->_read_file( $self->changeset_index );
return \$chgidx;
}
sub _write_changeset {
my $self = shift;
my %args = validate( @_,
{ changeset => { isa => 'Prophet::ChangeSet' } } );
my $changeset = $args{'changeset'};
my $hash_changeset = $changeset->as_hash;
# These two things should never actually get stored
my $seqno = delete $hash_changeset->{'sequence_no'};
my $uuid = delete $hash_changeset->{'source_uuid'};
my $cas_key = $self->changeset_cas->write( $hash_changeset );
my $changeset_index_line = pack( 'Na16NH40',
$seqno,
$self->uuid_generator->from_string( $changeset->original_source_uuid ),
$changeset->original_sequence_no,
$cas_key );
$self->backend->append_to_file($self->changeset_index => $changeset_index_line);
}
use constant CHG_RECORD_SIZE => ( 4 + 16 + 4 + 20 );
sub _changeset_index_size {
my $self = shift;
my %args = validate( @_, { index_file => 1 } );
return length(${$args{index_file}})/CHG_RECORD_SIZE;
}
=head2 traverse_changesets { after => SEQUENCE_NO, callback => sub { } }
Walks through all changesets from $after to $until, calling $callback on each.
If no $until is specified, the latest changeset is assumed.
=cut
# each record is : local-replica-seq-no : original-uuid : original-seq-no : cas key
# 4 16 4 20
sub traverse_changesets {
my $self = shift;
my %args = validate(
@_,
{ after => 1,
callback => { type => CODEREF },
before_load_changeset_callback => { type => CODEREF, optional => 1 },
reporting_callback => { type => CODEREF, optional => 1 },
until => 0,
reverse => 0,
load_changesets => { default => 1 }
}
);
my $first_rev = ( $args{'after'} + 1 ) || 1;
my $latest = $self->latest_sequence_no || 0;
if ( defined $args{until} && $args{until} < $latest ) {
$latest = $args{until};
}
#there's no need to iterate if we know there's nothing to read
return if ( $first_rev > $latest);
$self->log_debug("Traversing changesets between $first_rev and $latest");
my @range = ( $first_rev .. $latest );
@range = reverse @range if $args{reverse};
my $chgidx = $self->read_changeset_index;
for my $rev (@range) {
$self->log_debug("Fetching changeset $rev");
if ( $args{'before_load_changeset_callback'} ) {
my $continue = $args{'before_load_changeset_callback'}->(
changeset_metadata => $self->_changeset_index_entry(
sequence_no => $rev,
index_file => $chgidx
)
);
next unless $continue;
}
my $data;
if ( $args{load_changesets} ) {
$data = $self->_get_changeset_via_index(
sequence_no => $rev,
index_file => $chgidx
);
$args{callback}->( changeset => $data );
} else {
$data = $self->_changeset_index_entry(
sequence_no => $rev,
index_file => $chgidx
);
$args{callback}->( changeset_metadata => $data );
}
$args{reporting_callback}->($data) if ( $args{reporting_callback} );
}
}
sub _changeset_index_entry {
my $self = shift;
my %args = validate( @_, { sequence_no => 1, index_file => 1 } );
my $chgidx = $args{index_file};
my $rev = $args{'sequence_no'};
my $index_record = substr( $$chgidx, ( $rev - 1 ) * CHG_RECORD_SIZE, CHG_RECORD_SIZE );
my ( $seq, $orig_uuid, $orig_seq, $key ) = unpack( 'Na16NH40', $index_record );
$orig_uuid = $self->uuid_generator->to_string($orig_uuid);
$self->log_debug( "REV: $rev - seq $seq - originally $orig_seq from "
. substr( $orig_uuid, 0, 6 )
. " data key $key" );
return [ $seq, $orig_uuid, $orig_seq, $key];
}
sub _deserialize_changeset {
my $self = shift;
my %args = validate(
@_,
{ content => 1,
original_sequence_no => 1,
original_source_uuid => 1,
sequence_no => 1
}
);
require Prophet::ChangeSet;
my $content_struct = from_json( $args{content}, { utf8 => 1 } );
my $changeset = Prophet::ChangeSet->new_from_hashref($content_struct);
$changeset->source_uuid( $self->uuid );
$changeset->sequence_no( $args{'sequence_no'} );
$changeset->original_source_uuid( $args{'original_source_uuid'} );
$changeset->original_sequence_no( $args{'original_sequence_no'} );
return $changeset;
}
sub _get_changeset_via_index {
my $self = shift;
my %args = validate( @_, { sequence_no => 1, index_file => 1 } );
# XXX: deserialize the changeset content from the cas with $key
my ( $seq, $orig_uuid, $orig_seq, $key ) =@{ $self->_changeset_index_entry(%args)};
my $changeset = $self->_deserialize_changeset(
content => $self->fetch_serialized_changeset(sha1 => $key),
original_source_uuid => $orig_uuid,
original_sequence_no => $orig_seq,
sequence_no => $seq
);
return $changeset;
}
sub fetch_serialized_changeset {
my $self = shift;
my %args = validate(@_, { sha1 => 1 });
my $casfile = $self->changeset_cas->filename($args{sha1});
return $self->_read_file($casfile);
}
=head2 read_userdata_file
Returns the contents of the given file in this replica's userdata directory.
Returns C<undef> if the file does not exist.
=cut
sub read_userdata {
my $self = shift;
my %args = validate( @_, { path => 1 } );
$self->_read_file( Prophet::Util->catfile( $self->userdata_dir, $args{path} ) );
}
=head2 write_userdata
Writes the given string to the given file in this replica's userdata directory.
=cut
sub write_userdata {
my $self = shift;
my %args = validate( @_, { path => 1, content => 1 } );
$self->_write_file(
path => Prophet::Util->catfile( $self->userdata_dir, $args{path} ),
content => $args{content},
);
}
sub store_local_metadata {
my $self = shift;
my $key = shift;
my $value = shift;
$self->_write_file(
path =>Prophet::Util->catfile( $self->local_metadata_dir, lc($key)),
content => $value,
);
}
sub fetch_local_metadata {
my $self = shift;
my $key = shift;
# local metadata files used to (incorrectly) be treated as case sensitive.
# The code below tries to make sure that we don't lose historical data as we fix this
# If there's a new-style all-lowercase file, read that first. If there isn't,
# try to read an old-style sensitive file
my $insensitive_file = Prophet::Util->catfile($self->local_metadata_dir, lc($key));
my $sensitive_file = Prophet::Util->catfile($self->local_metadata_dir, $key);
return $self->_read_file($insensitive_file) || $self->_read_file($sensitive_file);
}
no Any::Moose;
1;
|