libncarg-data 6.3.0-6build1 / usr / share / ncarg / nclex / xyplot / xy04n.ncl

This file is indexed.

/usr/share/ncarg/nclex/xyplot/xy04n.ncl is in libncarg-data 6.3.0-6build1.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
;
;      $Id: xy04n.ncl,v 1.18 2010-03-15 22:49:25 haley Exp $
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;                                                                      ;
;                Copyright (C)  1995                                   ;
;        University Corporation for Atmospheric Research               ;
;                All Rights Reserved                                   ;
;                                                                      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;  File:       xy04n.ncl
;;
;;  Author:     Mary Haley
;;          National Center for Atmospheric Research
;;          PO 3000, Boulder, Colorado
;;
;;  Date:       Thu Feb  9 07:47:16 MST 1995
;;
;; Description:    This program shows one way on how to create an XyPlot
;;                 object with multiple lines in the plot using
;;                 the CoordArrays object.  Some of the XyPlot line
;;                 resources are tweaked in the resource file to
;;                 show how to change the appearance of these multiple
;;                 lines.
;;
;;                 The "CoordArrays" object is used to set up the data,
;;                 and the "DataDep" object is used to describe
;;                 attributes of the data being plotted, like the
;;                 line color and the dash patterns.
;;

;
; Begin NCL script.
;
begin

;
; Create variables to contain data.
;
npts = 500
ncurve = 4

;
; Initialize data for the XyPlot object.
; 
ii = new((/ncurve,npts/),float)
jj = new((/npts,ncurve/),float)
ii = onedtond(ispan(0,npts-1,1),(/ncurve,npts/))
jj = onedtond(ispan(0,ncurve-1,1),(/npts,ncurve/))
jj!0 = "x"
jj!1 = "y"

ydra = jj(y | :,x | :)*200.+ii*.9*sin(0.031415926535898*ii)

;
; Modify the color map.  Color indices '0' and '1' are the background
; and foreground colors respectively.
;
ncolors = 6
cmap = (/"black","white","red","green","blue","yellow"/)

;
; Create Application object.  The Application object name is used to
; determine the name of the resource file, which is "xy04.res" in this
; case.
; 
appid = create "xy04" appClass defaultapp 
    "appDefaultParent" : True
    "appUsrDir" : "./"
end create

;
; Default is to display output to an X workstation
;
wks_type = "x11"

if (str_lower(wks_type).eq."ncgm") then
;
; Create an ncgmWorkstation object.
;
  xworkid = create "xy04Work" ncgmWorkstationClass defaultapp
      "wkMetaName" : "xy04n.ncgm"
      "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."x11") then
;
; Create an X11 workstation.
;
  xworkid = create "xy04Work" windowWorkstationClass defaultapp
    "wkPause" : True
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."oldps") then
;
; Create an older-style PostScript workstation.
;
  xworkid = create "xy04Work" psWorkstationClass defaultapp
    "wkPSFileName" : "xy04n.ps"
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."oldpdf") then
;
; Create an older-style PDF workstation.
;
  xworkid = create "xy04Work" pdfWorkstationClass defaultapp
    "wkPDFFileName" : "xy04n.pdf"
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."pdf".or.str_lower(wks_type).eq."ps") then
;
; Create a cairo PS/PDF Workstation object.
;
  xworkid = create "xy04Work" documentWorkstationClass defaultapp
    "wkFileName" : "xy04n"
    "wkFormat" : wks_type
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."png") then
;
; Create a cairo PNG Workstation object.
;
  xworkid = create "xy04Work" imageWorkstationClass defaultapp
    "wkFileName" : "xy04n"
    "wkFormat" : wks_type
    "wkColorMap" : cmap
  end create
end if

;
; Define the data object.  The id for this object will later be used
; as the value for the XYPlot data resource, 'xyCoordData'.
; Since only the Y values are specified here, each Y value will be
; paired with its integer array index.
;
dataid = create "xyData" coordArraysClass defaultapp
    "caYArray": ydra
end create

;
; Create the XyPlot object which is created as a child of the
; XWorkstation object.  The resources that are being changed are done
; in the "xy04.res" file, and they will affect this XyPlot object.
; 
plotid = create "xyPlot" xyPlotClass xworkid
    "xyCoordData": dataid
end create

;
; Draw the plot.
; 
draw(plotid)
frame(xworkid)

;
; End NCL script.
;
end

APT Browse - Built by Thomas Orozco.