libncarg-data 6.3.0-6build1 / usr / share / ncarg / nclex / xyplot / xy01n.ncl

This file is indexed.

/usr/share/ncarg/nclex/xyplot/xy01n.ncl is in libncarg-data 6.3.0-6build1.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
;
;      $Id: xy01n.ncl,v 1.18 2010-03-15 22:49:25 haley Exp $
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;                                                                      ;
;                Copyright (C)  1995                                   ;
;        University Corporation for Atmospheric Research               ;
;                All Rights Reserved                                   ;
;                                                                      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;  File:       xy01n.ncl
;;
;;  Author:     Mary Haley
;;          National Center for Atmospheric Research
;;          PO 3000, Boulder, Colorado
;;
;;  Date:       Thu Feb  9 07:46:58 MST 1995
;;
;;  Description:    This program shows how to create an XyPlot object
;;                 with all the default resources being used, with the
;;                 exception of the data resource.  There's no "default
;;                 data", so we need to create some.  A resource file
;;                 is included with this example, but only to show what
;;                 all the XyPlot resources are and what their defaults
;;                 are set to. The whole resource file is commented out.
;;
;;                 The "CoordArrays" object is used to set up the data.
;;

;
; Begin NCL script.
;
begin

;
; Create variable to contain data.
;
npts = 500

;
; Initialize some data for the XyPlot object.
; 
ydra = 500.+.9*ispan(0,npts-1,1)*sin(0.031415926535898*ispan(0,npts-1,1))
;
; Create Application object.  The Application object name is used to
; determine the name of the resource file, which is "xy01.res" in this
; case.
; 
appid = create "xy01" appClass defaultapp
    "appDefaultParent" : True
    "appUsrDir" : "./"
end create

;
; Default is to display output to an X workstation
;
wks_type = "x11"

if (str_lower(wks_type).eq."ncgm") then
;
; Create an ncgmWorkstation object.
;
  xworkid = create "xy01Work" ncgmWorkstationClass defaultapp
      "wkMetaName" : "xy01n.ncgm"
  end create
end if

if (str_lower(wks_type).eq."x11") then
;
; Create an X11 workstation.
;
  xworkid = create "xy01Work" windowWorkstationClass defaultapp
    "wkPause" : True
  end create
end if

if (str_lower(wks_type).eq."oldps") then
;
; Create an older-style PostScript workstation.
;
  xworkid = create "xy01Work" psWorkstationClass defaultapp
    "wkPSFileName" : "xy01n.ps"
  end create
end if

if (str_lower(wks_type).eq."oldpdf") then
;
; Create an older-style PDF workstation.
;
  xworkid = create "xy01Work" pdfWorkstationClass defaultapp
    "wkPDFFileName" : "xy01n.pdf"
  end create
end if

if (str_lower(wks_type).eq."pdf".or.str_lower(wks_type).eq."ps") then
;
; Create a cairo PS or PDF DocumentWorkstation object.
;
  xworkid = create "xy01Work" documentWorkstationClass defaultapp
    "wkFileName" : "xy01n"
    "wkFormat"   : str_lower(wks_type)
  end create
end if

if (str_lower(wks_type).eq."png")
;
; Create a cairo PNG imageWorkstation object.
;
  xworkid = create "xy01Work" imageWorkstationClass defaultapp
    "wkFileName" : "xy01n"
    "wkFormat"   : str_lower(wks_type)
  end create
end if

;
; Define the data object.  Since only the Y values are specified here,
; each Y value will be paired with its integer array index.  The id
; for this object will later be used as the value for the XyPlot
; object resource, "xyCoordData".
;
dataid = create "xyData" coordArraysClass defaultapp
    "caYArray": ydra
end create

;
; Create the XyPlot object which is created as a child of the
; XWorkstation object.
; 
plotid = create "xyPlot" xyPlotClass xworkid
    "xyCoordData": dataid
end create

;
; Draw the plot.
; 
draw(plotid)
frame(xworkid)

;
; End NCL script.
;
end

APT Browse - Built by Thomas Orozco.