/usr/share/gretl/scripts/misc/frontier.inp is in gretl-common 2016a-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 | # MLE estimation based on Lucchetti, R., Papi, L., and Zazzaro, A.
# (2001) "Banks' Inefficiency and Economic Growth: A Micro Macro
# Approach", Scottish Journal of Political Economy, 48, pp. 400–424.
set echo off
set messages off
open banks91.gdt
# descriptive statistics (Table 1, p. 409)
summary VC Q1 Q2 P1 P2 P3 --simple
# transformations
series cost = ln(VC)
series q1 = ln(Q1)
series q2 = ln(Q2)
series p1 = ln(P1)
series p2 = ln(P2)
series p3 = ln(P3)
# Cobb-Douglas cost function with homogeneity restrictions
# (unreported - used for initialization)
series rcost = cost - p1
series rp2 = p2 - p1
series rp3 = p3 - p1
list X = const q1 q2 rp2 rp3
ols rcost X --quiet
# Cobb-Douglas cost function with homogeneity restrictions
# and inefficiency (Table 2, p. 410)
matrix b = $coeff
scalar su = 0.1
scalar sv = 0.1
series e
mle logl = ln(cnorm(e*lambda)) - (ln(ss) + 0.5*e^2)
scalar ss = sqrt(su^2 + sv^2)
scalar lambda = su/sv
e = (rcost - lincomb(X, b)) / ss
params b su sv
end mle
scalar ss = sqrt(su^2 + sv^2)
scalar lambda = su/sv
series le = lambda * e
series eff = ss*lambda/(1 + lambda^2) * (invmills(-le) + le)
# Table 3, p. 411
summary eff
|