/usr/share/gnu-smalltalk/kernel/Association.st is in gnu-smalltalk-common 3.2.5-1build2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 | "======================================================================
|
| Association Method Definitions
|
|
======================================================================"
"======================================================================
|
| Copyright 1988,92,94,95,99,2000,2001,2002
| Free Software Foundation, Inc.
| Written by Steve Byrne.
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================"
LookupKey subclass: Association [
| value |
<category: 'Language-Data types'>
<comment: 'My instances represent a mapping between two objects. Typically, my
"key" object is a symbol, but I don''t require this. My "value" object has
no conventions associated with it; it can be any object at all.'>
Association class >> key: aKey value: aValue [
"Answer a new association with the given key and value"
<category: 'basic'>
^self new key: aKey value: aValue
]
environment [
"Answer nil. This is present to achieve polymorphism with
instances of VariableBinding."
<category: 'accessing'>
^nil
]
environment: aNamespace [
"Do nothing. This is present to achieve polymorphism with
instances of VariableBinding."
<category: 'accessing'>
]
value: aValue [
"Set the association's value to aValue"
<category: 'accessing'>
value := aValue
]
key: aKey value: aValue [
"Set the association's key to aKey, and its value to aValue"
<category: 'accessing'>
key := aKey.
value := aValue
]
value [
"Answer the association's value"
<category: 'accessing'>
^value
]
= anAssociation [
"Answer whether the association's key and value are the same as
anAssociation's, or false if anAssociation is not an Association.
As a special case, identical values are considered equal even if
#= returns false (as is the case for NaN floating-point values)."
<category: 'testing'>
self class == anAssociation class ifFalse: [^false].
self key = anAssociation key ifFalse: [^false].
self value == anAssociation value ifTrue: [^true].
^self value = anAssociation value
]
hash [
"Answer an hash value for the receiver"
<category: 'testing'>
^key hash bitXor: value hash
]
printOn: aStream [
"Put on aStream a representation of the receiver"
<category: 'printing'>
self key printOn: aStream.
aStream nextPutAll: '->'.
self value printOn: aStream
]
storeOn: aStream [
"Put on aStream some Smalltalk code compiling to the receiver"
<category: 'storing'>
aStream nextPut: $(.
aStream store: self class.
aStream nextPutAll: ' key: '.
self key storeOn: aStream.
aStream nextPutAll: ' value: '.
self value storeOn: aStream.
aStream nextPut: $)
]
mourn [
"Finalize the receiver"
<category: 'finalization'>
self key: nil value: nil
]
]
|