webapp-container 0.23+16.04.20160413-0ubuntu1 / usr / share / webbrowser-app / webcontainer / AccountsPage.qml

This file is indexed.

/usr/share/webbrowser-app/webcontainer/AccountsPage.qml is in webapp-container 0.23+16.04.20160413-0ubuntu1.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
/*
 * Copyright 2013-2015 Canonical Ltd.
 *
 * This file is part of webbrowser-app.
 *
 * webbrowser-app is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; version 3.
 *
 * webbrowser-app is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */

import QtQuick 2.4
import Ubuntu.Components 1.3
import Ubuntu.OnlineAccounts 0.1
import webcontainer.private 0.1

Item {
    id: root

    property alias providerId: accountsLogic.providerId
    property alias applicationId: accountsLogic.applicationId
    property alias accountSwitcher: accountsLogic.accountSwitcher
    property string webappName: ""
    property url webappIcon

    signal accountSelected(string accountDataLocation, bool willMoveCookies)
    signal contextReady()
    signal quitRequested()

    property string __providerName: providerId
    property string __lastAccountDataLocation: ""

    anchors.fill: parent

    AccountsLogic {
        id: accountsLogic

        onSplashScreenRequested: showSplashScreen()
        onAccountSelected: root.__emitAccountSelected(credentialsId, willMoveCookies)
        onContextReady: root.contextReady()
        onQuitRequested: root.quitRequested()
        onErrorScreenRequested: showErrorScreen(message)
    }

    AccountsSplashScreen {
        id: splashScreen

        visible: false
        providerName: root.__providerName
        applicationName: root.webappName
        iconSource: root.webappIcon

        onChooseAccount: root.showAccountSwitcher()
        onQuitRequested: root.quitRequested()
        onSkip: accountsLogic.proceedWithNoAccount()
    }

    // Only temporarily used for bug https://bugs.launchpad.net/bugs/1441873
    AccountErrorScreen {
        id: errorScreen

        visible: false
        onClosed: root.quitRequested()
    }

    Loader {
        id: accountChooserLoader
        anchors.fill: parent
    }

    Component {
        id: accountChooserComponent
        AccountChooserDialog {
            id: accountChooser
            applicationName: root.webappName
            iconSource: root.webappIcon
            providerId: root.providerId
            applicationId: root.applicationId
            accountsModel: accountsLogic.accountsModel
            onCancel: {
                accountChooserLoader.sourceComponent = null
                root.accountSelected(root.__lastAccountDataLocation, false)
            }
            onAccountSelected: {
                accountChooserLoader.sourceComponent = null
                accountsLogic.setupAccount(accountId)
            }
        }
    }

    ProviderModel {
        id: providerModel
        applicationId: root.applicationId
    }

    function __setupProviderData() {
        for (var i = 0; i < providerModel.count; i++) {
            if (providerModel.get(i, "providerId") === root.providerId) {
                root.__providerName = providerModel.get(i, "displayName")
                break
            }
        }
    }

    Component.onCompleted: {
        __setupProviderData()
    }

    function showErrorScreen(message) {
        errorScreen.message = message
        errorScreen.visible = true
    }

    function showSplashScreen() {
        splashScreen.visible = true
    }

    function showAccountSwitcher() {
        accountChooserLoader.sourceComponent = accountChooserComponent
    }

    function __emitAccountSelected(credentialsId, willMoveCookies) {
        __lastAccountDataLocation = credentialsId > 0 ? ("/id-" + credentialsId) : ""
        accountSelected(__lastAccountDataLocation, willMoveCookies)
    }

    function setupWebcontextForAccount(webcontext) {
        accountsLogic.setupWebcontextForAccount(webcontext)
    }
}

APT Browse - Built by Thomas Orozco.