/usr/share/ada/adainclude/xmlada/unicode-ces-utf8.adb is in libxmlada4.1-dev 4.1-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 | -----------------------------------------------------------------------
-- XML/Ada - An XML suite for Ada95 --
-- --
-- Copyright (C) 2001-2010, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public --
-- License as published by the Free Software Foundation; either --
-- version 2 of the License, or (at your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public --
-- License along with this library; if not, write to the --
-- Free Software Foundation, Inc., 59 Temple Place - Suite 330, --
-- Boston, MA 02111-1307, USA. --
-- --
-----------------------------------------------------------------------
with Unicode.CES.Utf32; use Unicode.CES.Utf32;
with Unicode.CCS; use Unicode.CCS;
package body Unicode.CES.Utf8 is
function Internal_Convert
(Str : Utf8_String;
Convert : Unicode.CCS.Conversion_Function := Identity'Access;
Order : Byte_Order := Default_Byte_Order) return Utf8_String;
-- Internal function used to convert character sets
-----------
-- Width --
-----------
function Width (Char : Unicode_Char) return Natural is
begin
if Char < 16#80# then
return 1;
elsif Char < 16#800# then
return 2;
elsif Char < 16#10000# then
return 3;
elsif Char < 16#200000# then
return 4;
elsif Char < 16#4000000# then
return 5;
else
return 6;
end if;
end Width;
------------
-- Encode --
------------
procedure Encode
(Char : Unicode_Char;
Output : in out Byte_Sequence;
Index : in out Natural)
is
Len : Natural;
Mask : Unicode_Char;
Val : Unicode_Char := Char;
First, Last : Natural;
begin
if Char < 16#80# then
Len := 1;
Mask := 16#0#;
elsif Char < 16#800# then
Len := 2;
Mask := 16#C0#;
elsif Char < 16#10000# then
Len := 3;
Mask := 16#E0#;
elsif Char < 16#200000# then
Len := 4;
Mask := 16#F0#;
elsif Char < 16#4000000# then
Len := 5;
Mask := 16#F8#;
else
Len := 6;
Mask := 16#FC#;
end if;
First := Index + 2;
Last := Index + Len;
for J in reverse First .. Last loop
Output (J) := Character'Val ((Val and 16#3f#) or 16#80#);
Val := Val / (2 ** 6);
end loop;
Output (Index + 1) := Character'Val (Val or Mask);
Index := Last;
end Encode;
----------
-- Read --
----------
procedure Read
(Str : Utf8_String;
Index : in out Positive;
Char : out Unicode_Char)
is
Len : Natural;
Val : Unicode_Char;
C : Unicode_Char := Character'Pos (Str (Index));
begin
-- Compute the length of the encoding given what was in the first byte
if C < 128 then
Len := Index;
Val := C and 16#7f#;
elsif (C and 16#E0#) = 16#C0# then
Len := Index + 1;
Val := C and 16#1f#;
elsif (C and 16#F0#) = 16#E0# then
Len := Index + 2;
Val := C and 16#0f#;
elsif (C and 16#F8#) = 16#F0# then
Len := Index + 3;
Val := C and 16#07#;
elsif (C and 16#FC#) = 16#F8# then
Len := Index + 4;
Val := C and 16#03#;
elsif (C and 16#FE#) = 16#FC# then
Len := Index + 5;
Val := C and 16#01#;
else
raise Invalid_Encoding;
end if;
for Count in Index + 1 .. Natural'Min (Len, Str'Last) loop
C := Character'Pos (Str (Count));
if (C and 16#C0#) /= 16#80# then
raise Invalid_Encoding;
end if;
Val := (Val * (2 ** 6)) or (C and 16#3f#);
end loop;
if Str'Last < Len then
raise Incomplete_Encoding;
end if;
Index := Len + 1;
Char := Val;
end Read;
------------
-- Length --
------------
function Length (Str : Utf8_String) return Natural is
Pos : Natural := Str'First;
Length : Natural := 0;
C : Unicode_Char;
begin
while Pos <= Str'Last loop
Read (Str, Pos, C);
Length := Length + 1;
end loop;
return Length;
end Length;
----------------
-- From_Utf32 --
----------------
function From_Utf32 (Str : Unicode.CES.Utf32.Utf32_String)
return Utf8_String
is
-- Allocate worst case
Result : Utf8_String (1 .. (Str'Length / Utf32_Char_Width) * 6);
J : Positive := Str'First;
R_Index : Natural := Result'First - 1;
C : Unicode_Char;
begin
while J <= Str'Last loop
Unicode.CES.Utf32.Read (Str, J, C);
Encode (C, Result, R_Index);
end loop;
return Result (1 .. R_Index);
end From_Utf32;
--------------
-- To_Utf32 --
--------------
function To_Utf32 (Str : Utf8_String)
return Unicode.CES.Utf32.Utf32_LE_String
is
-- Allocate worst case
Result : Utf32_LE_String (1 .. Str'Length * Utf32_Char_Width);
J : Positive := Str'First;
R_Index : Natural := Result'First - 1;
C : Unicode_Char;
begin
while J <= Str'Last loop
Read (Str, J, C);
Unicode.CES.Utf32.Encode (C, Result, R_Index);
end loop;
return Result (1 .. R_Index);
end To_Utf32;
----------------------
-- Internal_Convert --
----------------------
function Internal_Convert
(Str : Utf8_String;
Convert : Unicode.CCS.Conversion_Function := Identity'Access;
Order : Byte_Order := Default_Byte_Order) return Utf8_String
is
pragma Warnings (Off, Order);
Offset : Natural := 0;
BOM : Bom_Type;
C : Unicode_Char;
J : Natural;
begin
Read_Bom (Str, Offset, BOM);
case BOM is
when Utf8_All | Unknown => null;
when others => raise Invalid_Encoding;
end case;
if Convert = Identity'Access then
return Str (Str'First + Offset .. Str'Last);
else
declare
-- Allocate worst case for the string
Result : Utf8_String (1 .. Str'Length * 6);
R_Index : Natural := Result'First - 1;
begin
J := Str'First + Offset;
while J <= Str'Last loop
Read (Str, J, C);
Encode (Convert (C), Result, R_Index);
end loop;
return Result (1 .. R_Index);
end;
end if;
end Internal_Convert;
-------------------
-- To_Unicode_LE --
-------------------
function To_Unicode_LE
(Str : Utf8_String;
Cs : Unicode.CCS.Character_Set := Unicode.CCS.Unicode_Character_Set;
Order : Byte_Order := Default_Byte_Order) return Utf8_String is
begin
return Internal_Convert (Str, Cs.To_Unicode, Order);
end To_Unicode_LE;
-----------
-- To_CS --
-----------
function To_CS
(Str : Utf8_String;
Cs : Unicode.CCS.Character_Set := Unicode.CCS.Unicode_Character_Set;
Order : Byte_Order := Default_Byte_Order) return Utf8_String is
begin
return Internal_Convert (Str, Cs.To_CS, Order);
end To_CS;
end Unicode.CES.Utf8;
|