/usr/share/ada/adainclude/aws/aws-smtp-server.adb is in libaws2.10.2-dev 2.10.2-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- S M T P - Simple Mail Transfer Protocol --
-- --
-- Copyright (C) 2008-2009, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
------------------------------------------------------------------------------
with Ada.Exceptions;
with Ada.Strings.Fixed;
with Ada.Text_IO;
with AWS.Headers.Set;
with AWS.Net.Buffered;
with AWS.SMTP.Messages.Set;
package body AWS.SMTP.Server is
use Ada;
-- Messages definitions
DATA : constant String := "DATA";
HELO : constant String := "HELO";
MAIL : constant String := "MAIL";
QUIT : constant String := "QUIT";
RCPT : constant String := "RCPT";
function Get_Message (Sock : Net.Socket_Type'Class) return Messages.Data;
-- Get an incoming message from the server
------------------
-- Mail_Handler --
------------------
task body Mail_Handler is
Message : Messages.Data;
Sock : Net.Socket_Type'Class := Net.Socket (Security => False);
begin
accept Start;
loop
Net.Accept_Socket (Server.Host.Sock.all, Sock);
Message := Get_Message (Sock);
Server.Action (Message);
Sock.Shutdown;
end loop;
exception
when E : others =>
if not Server.Shutdown then
-- When server is shutdown we do not want to report errors. In
-- some cases the socket layer won't end silently as the server
-- socket is shutdown. See Shutdown routine below.
Text_IO.Put_Line ("SMTP Server Fatal error");
Text_IO.Put_Line (Exceptions.Exception_Information (E));
raise;
end if;
end Mail_Handler;
-----------------
-- Get_Message --
-----------------
function Get_Message
(Sock : Net.Socket_Type'Class) return Messages.Data
is
Empty_Line : constant String := "";
CRLF : constant String := ASCII.CR & ASCII.LF;
procedure Read_Message_Body;
-- Read message body from the current socket and set the Message_Body
-- Unbounded String below. A message body is terminated by the sequence
-- CRLF & '.' & CRLF.
Message : Messages.Data;
Message_Body : Unbounded_String;
Headers : AWS.Headers.List;
-----------------------
-- Read_Message_Body --
-----------------------
procedure Read_Message_Body is
State : Natural range 0 .. 2 := 0;
-- State = 1 when first CRLF (empty line) has been read, 2 when a
-- dot ('.' & CRLF) has been read. When state = 2 we have reach the
-- end of the message.
begin
Read_Message_Header : loop
declare
Line : constant String := Net.Buffered.Get_Line (Sock);
Split_Point : Natural;
begin
exit Read_Message_Header when Line = Empty_Line;
Split_Point := Strings.Fixed.Index (Line, ":");
AWS.Headers.Set.Add
(Headers,
Name => Line (Line'First .. Split_Point - 1),
Value => Line (Split_Point + 2 .. Line'Last));
end;
end loop Read_Message_Header;
Read_Message : loop
declare
Line : constant String := Net.Buffered.Get_Line (Sock);
begin
if State = 0 and then Line = Empty_Line then
State := State + 1;
elsif State = 1 and then Line = "." then
exit Read_Message;
else
case State is
when 0 => null;
when 1 => Append (Message_Body, CRLF);
when others => raise Constraint_Error;
end case;
State := 0;
end if;
Append (Message_Body, Line & CRLF);
end;
end loop Read_Message;
end Read_Message_Body;
begin
Net.Buffered.Put_Line (Sock, "220 AdaSC Service ready");
-- ok, service is ready
Read_Message : loop
declare
Line : constant String := Net.Buffered.Get_Line (Sock);
Cmd : constant String := Line (Line'First .. Line'First + 3);
begin
if Cmd = DATA then
Net.Buffered.Put_Line (Sock, SMTP.Message (Start_Mail_Input));
Read_Message_Body;
Net.Buffered.Put_Line
(Sock, SMTP.Message (Requested_Action_Ok));
elsif Cmd = HELO then
Net.Buffered.Put_Line
(Sock, SMTP.Message (Requested_Action_Ok));
elsif Cmd = MAIL then
Net.Buffered.Put_Line
(Sock, SMTP.Message (Requested_Action_Ok));
elsif Cmd = RCPT then
Net.Buffered.Put_Line
(Sock, SMTP.Message (Requested_Action_Ok));
elsif Cmd = QUIT then
Net.Buffered.Put_Line (Sock, SMTP.Message (Service_Closing));
exit Read_Message;
else
-- Command is not known
Net.Buffered.Put_Line (Sock, SMTP.Message (Syntax_Error));
end if;
end;
end loop Read_Message;
Net.Buffered.Flush (Sock);
Messages.Set.Set_Body (Message, To_String (Message_Body));
Messages.Set.Headers (Message, Headers);
return Message;
end Get_Message;
--------------
-- Shutdown --
--------------
procedure Shutdown (Server : in out Handle) is
Try : Natural := 5;
begin
-- Shutdown the socket, this should raise socket error on the
-- Mail_Handler task.
Server.Shutdown := True;
Net.Shutdown (Server.Host.Sock.all);
-- Now wait for the task to terminate
while not Server.Server_Handler'Terminated and then Try > 0 loop
delay 1.0;
Try := Try - 1;
end loop;
-- If not yet terminated abort
if not Server.Server_Handler'Terminated then
abort Server.Server_Handler;
end if;
Net.Free (Server.Host.Sock);
end Shutdown;
-----------
-- Start --
-----------
procedure Start
(Server : in out Handle;
Host : Receiver;
Action : Callback) is
begin
-- Initialize server listening port
Server.Host := Host;
Server.Host.Sock := Net.Socket (Security => False);
Net.Bind (Server.Host.Sock.all, Host.Port);
Net.Listen (Server.Host.Sock.all);
Server.Action := Action;
Server.Server_Handler.Start;
end Start;
end AWS.SMTP.Server;
|