/usr/share/ada/adainclude/aws/aws-net-ssl.ads is in libaws2.10.2-dev 2.10.2-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2002-2011, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
------------------------------------------------------------------------------
-- This is the SSL based implementation of the Net package. The implementation
-- should depend only on AWS.Net.Std and the SSL library. It is important to
-- not call directly a socket binding here to ease porting.
with AWS.Net.Std;
with SSL.Thin;
package AWS.Net.SSL is
Socket_Error : exception renames Net.Socket_Error;
type Socket_Type is new Net.Std.Socket_Type with private;
Is_Supported : constant Boolean;
-- True if SSL supported in the current runtime
----------------
-- Initialize --
----------------
overriding procedure Accept_Socket
(Socket : Net.Socket_Type'Class; New_Socket : in out Socket_Type);
-- Accept a connection on a socket
overriding procedure Connect
(Socket : in out Socket_Type;
Host : String;
Port : Positive;
Wait : Boolean := True);
-- Connect a socket on a given host/port. If Wait is True Connect will wait
-- for the connection to be established for timeout seconds, specified by
-- Set_Timeout routine. If Wait is False Connect will return immediately,
-- not waiting for the connection to be establised and it does not make the
-- SSL handshake. It is possible to wait for the Connection completion by
-- calling Wait routine with Output set to True in Events parameter.
overriding procedure Socket_Pair (S1, S2 : out Socket_Type);
-- Create 2 sockets and connect them together
overriding procedure Shutdown
(Socket : Socket_Type; How : Shutmode_Type := Shut_Read_Write);
-- Shutdown the read, write or both side of the socket.
-- If How is Both, close it. Does not raise Socket_Error if the socket is
-- not connected or already shutdown.
--------
-- IO --
--------
overriding procedure Send
(Socket : Socket_Type;
Data : Stream_Element_Array;
Last : out Stream_Element_Offset);
overriding procedure Receive
(Socket : Socket_Type;
Data : out Stream_Element_Array;
Last : out Stream_Element_Offset);
pragma Inline (Receive);
overriding function Pending
(Socket : Socket_Type) return Stream_Element_Count;
-- Returns the number of bytes which are available inside socket
-- for immediate read.
--------------------
-- Initialization --
--------------------
type Method is
(SSLv23, SSLv23_Server, SSLv23_Client,
TLSv1, TLSv1_Server, TLSv1_Client,
SSLv3, SSLv3_Server, SSLv3_Client);
type Config is private;
Null_Config : constant Config;
procedure Initialize
(Config : in out SSL.Config;
Certificate_Filename : String;
Security_Mode : Method := SSLv23;
Key_Filename : String := "";
Exchange_Certificate : Boolean := False;
Session_Cache_Size : Positive := 16#4000#);
-- Initialize the SSL layer into Config. Certificate_Filename must point
-- to a valid certificate. Security mode can be used to change the
-- security method used by AWS. Key_Filename must be specified if the key
-- is not in the same file as the certificate. The Config object can be
-- associated with all secure sockets sharing the same options. If
-- Exchange_Certificate is True the client will send it's certificate to
-- the server, if False only the server will send its certificate.
procedure Release (Config : in out SSL.Config);
-- Release memory associated with the Config object
procedure Set_Config
(Socket : in out Socket_Type; Config : SSL.Config);
-- Set the SSL configuration object for the secure socket
function Secure_Client
(Socket : Net.Socket_Type'Class;
Config : SSL.Config := Null_Config) return Socket_Type;
-- Make client side SSL connection from plain socket.
-- SSL handshake does not performed. SSL handshake would be made
-- automatically on first Read/Write, or explicitly by the Do_Handshake
-- call. Do not free or close source socket after this call.
function Secure_Server
(Socket : Net.Socket_Type'Class;
Config : SSL.Config := Null_Config) return Socket_Type;
-- Make server side SSL connection from plain socket.
-- SSL handshake does not performed. SSL handshake would be made
-- automatically on first Read/Write, or explicitly by the Do_Handshake
-- call. Do not free or close source socket after this call.
procedure Do_Handshake (Socket : in out Socket_Type);
-- Wait for a SSL/TLS handshake to take place. You need to call this
-- routine if you have converted a standard socket to secure one and need
-- to get the peer certificate.
function Version (Build_Info : Boolean := False) return String;
-- Returns version information
procedure Clear_Session_Cache (Config : SSL.Config := Null_Config);
-- Remove all sessions from SSL session cache from the SSL context.
-- Null_Config mean default context.
procedure Set_Session_Cache_Size
(Size : Natural; Config : SSL.Config := Null_Config);
-- Set session cache size in the SSL context.
-- Null_Config mean default context.
private
package TSSL renames Standard.SSL.Thin;
Is_Supported : constant Boolean := Integer (TSSL.SSLeay) /= 0;
subtype SSL_Handle is TSSL.SSL_Handle;
type TS_SSL;
type Config is access all TS_SSL;
Null_Config : constant Config := null;
type Socket_Type is new Net.Std.Socket_Type with record
Config : SSL.Config := Null_Config;
SSL : SSL_Handle := TSSL.Null_Handle;
-- IO : TSSL.BIO_Access;
end record;
overriding procedure Free (Socket : in out Socket_Type);
-- Release memory associated with the socket object
overriding procedure Set_Timeout
(Socket : in out Socket_Type; Timeout : Duration);
-- Overriden to change the status of the internal SSL data
overriding procedure Finalize (Socket : in out Socket_Type);
-- Finalize overriden for GNUTLS implementation.
-- for OpenSSL implementation, it have to call inherited routine.
end AWS.Net.SSL;
|