/usr/lib/kde4/imports/org/kde/kwin/decoration/MenuButton.qml is in kde-window-manager-common 4:4.11.8-0ubuntu6.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 | /********************************************************************
Copyright (C) 2012 Martin Gräßlin <mgraesslin@kde.org>
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
*********************************************************************/
import QtQuick 1.1
import org.kde.qtextracomponents 0.1 as QtExtra
DecorationButton {
property bool closeOnDoubleClick: true
id: menuButton
buttonType: "M"
QtExtra.QIconItem {
icon: decoration.icon
anchors.fill: parent
}
Timer {
id: timer
interval: 150
repeat: false
onTriggered: decoration.menuClicked()
}
MouseArea {
anchors.fill: parent
acceptedButtons: Qt.LeftButton | Qt.RightButton
onPressed: {
parent.pressed = true;
// we need a timer to figure out whether there is a double click in progress or not
// if we have a "normal" click we want to open the context menu. This would eat our
// second click of the double click. To properly get the double click we have to wait
// the double click delay to ensure that it was only a single click.
if (timer.running) {
timer.stop();
} else if (menuButton.closeOnDoubleClick) {
timer.start();
}
}
onReleased: {
parent.pressed = false;
timer.stop();
}
onExited: {
if (!parent.pressed) {
return;
}
if (timer.running) {
timer.stop();
}
parent.pressed = false;
}
onClicked: {
// for right clicks we show the menu instantly
// and if the option is disabled we always show menu directly
if (!menuButton.closeOnDoubleClick || mouse.button == Qt.RightButton) {
decoration.menuClicked();
timer.stop();
}
}
onDoubleClicked: {
if (menuButton.closeOnDoubleClick) {
decoration.closeWindow();
}
}
}
Component.onCompleted: {
menuButton.closeOnDoubleClick = decoration.readConfig("CloseOnDoubleClickMenuButton", true);
}
Connections {
target: decoration
onConfigChanged: {
menuButton.closeOnDoubleClick = decoration.readConfig("CloseOnDoubleClickMenuButton", true);
}
}
}
|