libncarg-data 6.1.2-7 / usr / share / ncarg / nclex / contourplot / cn07n.ncl

This file is indexed.

/usr/share/ncarg/nclex/contourplot/cn07n.ncl is in libncarg-data 6.1.2-7.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;                                                                       ;
;                Copyright (C)  1995                                    ;
;        University Corporation for Atmospheric Research                ;
;                All Rights Reserved                                    ;
;                                                                       ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;   File:       cn07n.ncl
;
;   Author:     Ethan Alpert
;           National Center for Atmospheric Research
;           PO 3000, Boulder, Colorado
;
;           Converted to NCL by Ed Stautler
;
;   Date:       Fri Apr 28 11:43:39 MDT 1995
;
;   Description:    Reads a netCDF file and produces a series of
;                   contour plots.
;
begin

;
; Open NetCDF file containing Geo-Potential height forecast information
;
filedir = ncargpath("data")
filename = filedir + "/cdf/contour.cdf"
a = addfile(filename,"r")

;
; Set the color map.
;
cmap = (/ (/0.0, 0.0, 0.0/), \
	 (/1.0, 1.0, 1.0/), \
	 (/0.0, 0.0, 0.0/), \
	 (/1.0, 0.0, 0.0/), \
	 (/0.0, 1.0, 0.0/), \
	 (/0.0, 0.0, 1.0/), \
	 (/1.0, 1.0, 0.0/), \
	 (/0.0, 1.0, 1.0/), \
	 (/1.0, 0.0, 1.0/), \
	 (/0.5, 0.0, 0.0/), \
	 (/0.5, 1.0, 1.0/), \
	 (/0.0, 0.0, 0.5/), \
	 (/1.0, 1.0, 0.5/), \
	 (/0.5, 0.0, 1.0/), \
	 (/1.0, 0.5, 0.0/), \
	 (/0.0, 0.5, 1.0/), \
	 (/0.5, 1.0, 0.0/) /)

wks_type = "ncgm"

if (str_lower(wks_type).eq."ncgm")
;
; Open NCGM workstation.
;
    wks = create "cn07Work" ncgmWorkstationClass defaultapp
      "wkMetaName" : "cn07n.ncgm"
      "wkColorMap" : cmap
    end create
end if
if (str_lower(wks_type).eq."x11") then
;
; Create an X workstation.
;
  wks = create "cn07Work" windowWorkstationClass defaultapp
    "wkPause" : True
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."oldps") then
;
; Open PS workstation. 
;
  wks = create "cn07Work" psWorkstationClass defaultapp
    "wkPSFileName" : "cn07n.ps"
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."oldpdf") then
;
; Open PDF workstation. 
;
  wks = create "cn07Work" pdfWorkstationClass defaultapp
    "wkPDFFileName" : "cn07n.pdf"
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."pdf".or.str_lower(wks_type).eq."ps") then
;
; Open cairo PS/PDF workstation. 
;
  wks = create "cn07Work" documentWorkstationClass defaultapp
    "wkFileName" : "cn07n"
    "wkFormat" : wks_type
    "wkColorMap" : cmap
  end create
end if
if (str_lower(wks_type).eq."png") then
;
; Open cairo PNG workstation. 
;
  wks = create "cn07Work" imageWorkstationClass defaultapp
    "wkFileName" : "cn07n"
    "wkFormat" : wks_type
    "wkColorMap" : cmap
  end create
end if

;
; Create a scalar field object and configure the missing values and
; the start and end information.
;
field1 = create "field1" scalarFieldClass defaultapp
    "sfDataArray" : a->Z(0,3,:,:) 
    "sfMissingValueV": a->Z@_FillValue
    "sfXCStartV" : a->lon(0)
    "sfXCEndV": a->lon(filevardimsizes(a,"lon") - 1)
    "sfYCStartV" : a->lat(0)
    "sfYCEndV": a->lat(filevardimsizes(a,"lat") - 1)
end create

;
; Create a contour object 
;
con1 = create "con1" contourPlotClass wks 
    "vpXF": .2
    "vpYF": .8
    "vpWidthF" : .6
    "vpHeightF" : .6
    "cnScalarFieldData" : field1
    "cnLevelSelectionMode" : "ManualLevels"
    "cnMinLevelValF" : 5400.0
    "cnMaxLevelValF" : 5950.0
    "cnLevelSpacingF" : 50.0
    "cnLowLabelsOn" : True
    "cnHighLabelsOn" : True
    "cnFillOn" : True
    "trXMinF" : -140.0
    "trXMaxF" : -52.5
    "trYMinF" : 20.0
    "trYMaxF" : 60.0
    "tiMainString" : "Geo-potential height @500mb"
    "tiXAxisString" : "Lon"
    "tiYAxisString" : "Lat"
    "tmXBMode" : "EXPLICIT"
    "tmXBValues" : (/-60, -75, -90, -105, -120, -135 /)
    "tmXBLabels" : (/"60W", "75W", "90W", "105W", "120W", "135W"/)
    "tmYLMode" : "EXPLICIT"
    "tmYLValues" : (/60, 50, 40 , 30, 20/)
    "tmYLLabels" : (/"60N", "50N", "40N", "30N", "20N"/)
    "tmXMajorGrid" : True
    "tmYMajorGrid" : True
    "tmXBMinorOn" : False
    "tmYLMinorOn" : False
end create
draw(con1)
frame(wks)

;
; Loop on remaining time steps
;
do i = 1, filevardimsizes(a,"frtime") - 1
    setvalues field1
        "sfDataArray" : a->Z(i,3,:,:) 
    end setvalues
    draw(con1)
    frame(wks)
end do
end

APT Browse - Built by Thomas Orozco.