/usr/share/perl5/Data/FormValidator/ConstraintsFactory.pm is in libdata-formvalidator-perl 4.81-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 | #
# ConstraintsFactory.pm - Module to create constraints for Data::FormValidator.
#
# This file is part of Data::FormValidator.
#
# Author: Francis J. Lacoste <francis.lacoste@iNsu.COM>
# Maintainer: Mark Stosberg <mark@summersault.com>
#
# Copyright (C) 2000 iNsu Innovations Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms as perl itself.
#
use strict;
package Data::FormValidator::ConstraintsFactory;
use Exporter 'import';
=pod
=head1 NAME
Data::FormValidator::ConstraintsFactory - Module to create constraints for HTML::FormValidator.
=head1 DESCRIPTION
This module contains functions to help generate complex constraints.
If you are writing new code, take a look at L<Data::FormValidator::Constraints::MethodsFactory>
instead. It's a modern alternative to what's here, offering improved names and syntax.
=head1 SYNOPSIS
use Data::FormValidator::ConstraintsFactory qw( :set :bool );
constraints => {
param1 => make_or_constraint(
make_num_set_constraint( -1, ( 1 .. 10 ) ),
make_set_constraint( 1, ( 20 .. 30 ) ),
),
province => make_word_set_constraint( 1, "AB QC ON TN NU" ),
bid => make_range_constraint( 1, 1, 10 ),
}
=cut
BEGIN {
our $VERSION = 4.81;
our @EXPORT = ();
our @EXPORT_OK = (qw/make_length_constraint/);
our %EXPORT_TAGS =
(
bool => [ qw( make_not_constraint make_or_constraint
make_and_constraint ) ],
set => [ qw( make_set_constraint make_num_set_constraint
make_word_set_constraint make_cmp_set_constraint ) ],
num => [ qw( make_clamp_constraint make_lt_constraint
make_le_constraint make_gt_constraint
make_ge_constraint ) ],
);
Exporter::export_ok_tags( 'bool' );
Exporter::export_ok_tags( 'set' );
Exporter::export_ok_tags( 'num' );
}
=pod
=head1 BOOLEAN CONSTRAINTS
Those constraints are available by using the C<:bool> tag.
=head2 make_not_constraint( $c1 )
This will create a constraint that will return the negation of the
result of constraint $c1.
=cut
sub make_not_constraint {
my $c1 = $_[0];
# Closure
return sub { ! $c1->( @_ ) };
}
=head2 make_or_constraint( @constraints )
This will create a constraint that will return the result of the first
constraint that return an non false result.
=cut
sub make_or_constraint {
my @c = @_;
# Closure
return sub {
my $res;
for my $c ( @c ) {
$res = $c->( @_ );
return $res if $res;
}
return $res;
};
}
=head2 make_and_constraint( @constraints )
This will create a constraint that will return the result of the first
constraint that return an non false result only if all constraints
returns a non-false results.
=cut
sub make_and_constraint {
my @c = @_;
# Closure
return sub {
my $res;
for my $c ( @c ) {
$res = $c->( @_ );
return $res if ! $res;
$res ||= $res;
}
return $res;
};
}
=pod
=head1 SET CONSTRAINTS
Those constraints are available by using the C<:set> tag.
=head2 make_set_constraint( $res, @elements )
This will create a constraint that will return $res if the value
is one of the @elements set, or the negation of $res otherwise.
The C<eq> operator is used for comparison.
=cut
sub make_set_constraint {
my $res = shift;
my @values = @_;
# Closure
return sub {
my $v = $_[0];
for my $t ( @values ) {
return $res if $t eq $v;
}
return ! $res;
}
}
=head2 make_num_set_constraint( $res, @elements )
This will create a constraint that will return $res if the value
is one of the @elements set, or the negation of $res otherwise.
The C<==> operator is used for comparison.
=cut
sub make_num_set_constraint {
my $res = shift;
my @values = @_;
# Closure
return sub {
my $v = $_[0];
for my $t ( @values ) {
return $res if $t == $v;
}
return ! $res;
}
}
=head2 make_word_set_constraint( $res, $set )
This will create a constraint that will return $res if the value is
a word in $set, or the negation of $res otherwise.
=cut
sub make_word_set_constraint {
my ($res,$set) = @_;
# Closure
return sub {
my $v = $_[0];
if ( $set =~ /\b$v\b/i ) {
return $res;
} else {
return ! $res;
}
}
}
=head2 make_cmp_set_constraint( $res, $cmp, @elements )
This will create a constraint that will return $res if the value
is one of the @elements set, or the negation of $res otherwise.
$cmp is a function which takes two argument and should return true or false depending if the two elements are equal.
=cut
sub make_match_set_constraint {
my $res = shift;
my $cmp = shift;
my @values = @_;
# Closure
return sub {
my $v = $_[0];
for my $t ( @values ) {
return $res if $cmp->($v, $t );
}
return ! $res;
}
}
=pod
=head1 NUMERICAL LOGICAL CONSTRAINTS
Those constraints are available by using the C<:num> tag.
=head2 make_clamp_constraint( $res, $low, $high )
This will create a constraint that will return $res if the value
is between $low and $high bounds included or its negation otherwise.
=cut
sub make_clamp_constraint {
my ( $res, $low, $high ) = @_;
return sub {
my $v = $_[0];
$v < $low || $v > $high ? ! $res : $res;
}
}
=head2 make_lt_constraint( $res, $bound )
This will create a constraint that will return $res if the value
is lower than $bound, or the negation of $res otherwise.
=cut
sub make_lt_constraint {
my ( $res, $bound ) = @_;
return sub {
$_[0] < $bound ? $res : ! $res;
}
}
=head2 make_le_constraint( $res, $bound )
This will create a constraint that will return $res if the value
is lower or equal than $bound, or the negation of $res otherwise.
=cut
sub make_le_constraint {
my ( $res, $bound ) = @_;
return sub {
$_[0] <= $bound ? $res : ! $res;
}
}
=head2 make_gt_constraint( $res, $bound )
This will create a constraint that will return $res if the value
is greater than $bound, or the negation of $res otherwise.
=cut
sub make_gt_constraint {
my ( $res, $bound ) = @_;
return sub {
$_[0] >= $bound ? $res : ! $res;
}
}
=head2 make_ge_constraint( $res, $bound )
This will create a constraint that will return $res if the value
is greater or equal than $bound, or the negation of $res otherwise.
=cut
sub make_ge_constraint {
my ( $res, $bound ) = @_;
return sub {
$_[0] >= $bound ? $res : ! $res;
}
}
=head1 OTHER CONSTRAINTS
=head2 make_length_constraint($max_length)
This will create a constraint that will return true if the value
has a length of less than or equal to $max_length
=cut
sub make_length_constraint {
my $max_length = shift;
return sub { length(shift) <= $max_length };
}
1;
__END__
=pod
=head1 SEE ALSO
Data::FormValidator(3)
=head1 AUTHOR
Author: Francis J. Lacoste <francis.lacoste@iNsu.COM>
Maintainer: Mark Stosberg <mark@summersault.com>
=head1 COPYRIGHT
Copyright (c) 2000 iNsu Innovations Inc.
All rights reserved.
This program is free software; you can redistribute it and/or modify
it under the terms as perl itself.
=cut
|