/usr/share/perl5/CGI/Compile.pm is in libcgi-compile-perl 0.16-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 | package CGI::Compile;
use strict;
use 5.008_001;
our $VERSION = '0.16';
use Cwd;
use File::Basename;
use File::Spec::Functions;
use File::pushd;
sub new {
my ($class, %opts) = @_;
$opts{namespace_root} ||= 'CGI::Compile::ROOT';
bless \%opts, $class;
}
our $USE_REAL_EXIT;
BEGIN {
$USE_REAL_EXIT = 1;
my $orig = *CORE::GLOBAL::exit{CODE};
my $proto = $orig ? prototype $orig : prototype 'CORE::exit';
$proto = $proto ? "($proto)" : '';
$orig ||= sub {
my $exit_code = shift;
CORE::exit(defined $exit_code ? $exit_code : 0);
};
no warnings 'redefine';
*CORE::GLOBAL::exit = eval qq{
sub $proto {
my \$exit_code = shift;
\$orig->(\$exit_code) if \$USE_REAL_EXIT;
die [ "EXIT\n", \$exit_code || 0 ]
};
};
die $@ if $@;
}
sub compile {
my($class, $script, $package) = @_;
my $self = ref $class ? $class : $class->new;
my $code = $self->_read_source($script);
my $path = Cwd::abs_path($script);
my $dir = File::Basename::dirname($path);
$package ||= $self->_build_package($path);
my $warnings = $code =~ /^#!.*\s-w\b/ ? 1 : 0;
$code =~ s/^__END__\r?\n.*//ms;
$code =~ s/^__DATA__\r?\n(.*)//ms;
my $data = $1;
# TODO handle nph and command line switches?
my $eval = join '',
"package $package;",
"sub {",
'local $CGI::Compile::USE_REAL_EXIT = 0;',
"\nCGI::initialize_globals() if defined &CGI::initialize_globals;",
"local \$0 = '$path';",
"my \$_dir = File::pushd::pushd '$dir';",
'local *DATA;',
q{open DATA, '<', \$data;},
'local *SIG = +{ %SIG };',
'no warnings;',
('local $^W = '.$warnings.';'),
'my $rv = eval {',
"\n#line 1 $path\n",
$code,
"\n};",
q{
return $rv unless $@;
die $@ if $@ and not (
ref($@) eq 'ARRAY' and
$@->[0] eq "EXIT\n"
);
die "exited nonzero: $@->[1]" if $@->[1] != 0;
return $rv;
},
'};';
my $sub = do {
no strict;
no warnings;
my %orig_sig = %SIG;
local $USE_REAL_EXIT = 0;
my $code = eval $eval;
my $exception = $@;
%SIG = %orig_sig;
die "Could not compile $script: $exception" if $exception;
$code;
};
return $sub;
}
sub _read_source {
my($self, $file) = @_;
open my $fh, "<", $file or die "$file: $!";
return do { local $/; <$fh> };
}
sub _build_package {
my($self, $path) = @_;
my ($volume, $dirs, $file) = File::Spec::Functions::splitpath($path);
my @dirs = File::Spec::Functions::splitdir($dirs);
my $package = join '_', grep { defined && length } $volume, @dirs, $file;
# Escape everything into valid perl identifiers
$package =~ s/([^A-Za-z0-9_])/sprintf("_%2x", unpack("C", $1))/eg;
# make sure that the sub-package doesn't start with a digit
$package =~ s/^(\d)/_$1/;
$package = $self->{namespace_root} . "::$package";
return $package;
}
1;
__END__
=encoding utf-8
=for stopwords
=head1 NAME
CGI::Compile - Compile .cgi scripts to a code reference like ModPerl::Registry
=head1 SYNOPSIS
use CGI::Compile;
my $sub = CGI::Compile->compile("/path/to/script.cgi");
=head1 DESCRIPTION
CGI::Compile is an utility to compile CGI scripts into a code
reference that can run many times on its own namespace, as long as the
script is ready to run on a persistent environment.
B<NOTE:> for best results, load L<CGI::Compile> before any modules used by your
CGIs.
=head1 RUN ON PSGI
Combined with L<CGI::Emulate::PSGI>, your CGI script can be turned
into a persistent PSGI application like:
use CGI::Emulate::PSGI;
use CGI::Compile;
my $cgi_script = "/path/to/foo.cgi";
my $sub = CGI::Compile->compile($cgi_script);
my $app = CGI::Emulate::PSGI->handler($sub);
# $app is a PSGI application
=head1 CAVEATS
If your CGI script has a subroutine that references the lexical scope
variable outside the subroutine, you'll see warnings such as:
Variable "$q" is not available at ...
Variable "$counter" will not stay shared at ...
This is due to the way this module compiles the whole script into a
big C<sub>. To solve this, you have to update your code to pass around
the lexical variables, or replace C<my> with C<our>. See also
L<http://perl.apache.org/docs/1.0/guide/porting.html#The_First_Mystery>
for more details.
=head1 AUTHOR
Tatsuhiko Miyagawa E<lt>miyagawa@bulknews.netE<gt>
=head1 CONTRIBUTORS
Rafael Kitover E<lt>rkitover@cpan.orgE<gt>
Hans Dieter Pearcey E<lt>hdp@cpan.orgE<gt>
=head1 COPYRIGHT & LICENSE
Copyright (c) 2009 Tatsuhiko Miyagawa E<lt>miyagawa@bulknews.netE<gt>
This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.
=head1 SEE ALSO
L<ModPerl::RegistryCooker> L<CGI::Emulate::PSGI>
=cut
|