/usr/share/augeas/lenses/dist/postfix_transport.aug is in augeas-lenses 1.2.0-0ubuntu1.3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 | (*
Module: Postfix_Transport
Parses /etc/postfix/transport
Author: Raphael Pinson <raphael.pinson@camptocamp.com>
About: Reference
This lens tries to keep as close as possible to `man 5 transport` where possible.
About: License
This file is licenced under the LGPL v2+, like the rest of Augeas.
About: Lens Usage
To be documented
About: Configuration files
This lens applies to /etc/postfix/transport. See <filter>.
About: Examples
The <Test_Postfix_Transport> file contains various examples and tests.
*)
module Postfix_Transport =
autoload xfm
(* View: space_or_eol *)
let space_or_eol = del /([ \t]*\n)?[ \t]+/ " "
(* View: colon *)
let colon = Sep.colon
(* View: nexthop *)
let nexthop =
let host_re = "[" . Rx.word . "]" | /[A-Za-z]([^\n]*[^ \t\n])?/
in [ label "nexthop" . (store host_re)? ]
(* View: transport *)
let transport = [ label "transport" . (store Rx.word)? ]
. colon . nexthop
(* View: nexthop_smtp *)
let nexthop_smtp =
let host_re = "[" . Rx.word . "]" | Rx.word
in [ label "host" . store host_re ]
. colon
. [ label "port" . store Rx.integer ]
(* View: record *)
let record = [ label "pattern" . store /[A-Za-z0-9@\*.-]+/
. space_or_eol . (transport | nexthop_smtp)
. Util.eol ]
(* View: lns *)
let lns = (Util.empty | Util.comment | record)*
(* Variable: filter *)
let filter = incl "/etc/postfix/transport"
let xfm = transform lns filter
|