libplplot-dev 5.9.9-2ubuntu2 / usr / share / doc / libplplot11 / examples / f77 / x16af.f

This file is indexed.

/usr/share/doc/libplplot11/examples/f77/x16af.f is in libplplot-dev 5.9.9-2ubuntu2.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
c      $Id: x16af.fm4 11680 2011-03-27 17:57:51Z airwin $
c      Demonstration of plshade plotting
c      Reduce colors in cmap 0 so that cmap 1 is useful on a 16-color display
c
c      Copyright (C) 2004  Alan W. Irwin
c
c      This file is part of PLplot.
c
c      PLplot is free software; you can redistribute it and/or modify
c      it under the terms of the GNU Library General Public License as
c      published by the Free Software Foundation; either version 2 of the
c      License, or (at your option) any later version.
c
c      PLplot is distributed in the hope that it will be useful,
c      but WITHOUT ANY WARRANTY; without even the implied warranty of
c      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
c      GNU Library General Public License for more details.
c
c      You should have received a copy of the GNU Library General Public
c      License along with PLplot; if not, write to the Free Software
c      Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

      implicit none

      include 'plplot_parameters.h'
c      Process command-line arguments
      call plparseopts(PL_PARSE_FULL)

      call plscmap0n(3)

c      Initialize plplot

      call plinit()

c      Rectangular coordinate plot

      call rect()

c      Polar coordinate plot

      call polar()

      call plend
      end

c      Plot function using the identity transform

      subroutine rect()

      implicit none
      integer   xdim, ydim, NX, NY, NCONTR
c      xdim and ydim are the static dimensions of the 2D arrays while
c      NX and NY are the defined area.
      parameter (xdim = 99, NX = 35, ydim = 100, NY = 46, NCONTR = 14)

      real*8    z(xdim, ydim), w(xdim, ydim), clevel(NCONTR)
      real*8    xmin, xmax, ymin, ymax, zmin, zmax, x, y
      real*8    shade_min, shade_max, sh_color
      integer   i, j, sh_cmap, sh_width
      integer   min_color, min_width, max_color, max_width

      xmin = -1.d0
      ymin = -1.d0
      xmax =  1.d0
      ymax =  1.d0

c      Set up for plshade call

      sh_cmap   = 1
      min_color = 1
      min_width = 0
      max_color = 0
      max_width = 0

c      Set up data arrays

      do i = 1, NX
        x = (i - 1 - (NX/2)) / dble (NX/2)
        do j = 1, NY
          y = (j - 1 - (NY/2)) / dble (NY/2) - 1.0d0
          z(i,j) = x*x - y*y + (x - y) / (x*x + y*y + 0.1d0)
          w(i,j) = 2*x*y
        enddo
      enddo

      call a2mnmx(z, NX, NY, zmin, zmax, xdim)
      do  i = 1, NCONTR
        clevel(i) = zmin + (zmax - zmin) * (i + 0.5d0) /
     &    dble (NCONTR)
      enddo

c      Plot using identity transform

      call pladv(0)
      call plvpor(0.1d0, 0.9d0, 0.1d0, 0.9d0)
      call plwind(-1.0d0, 1.0d0, -1.0d0, 1.0d0)

      do i = 1, NCONTR
        shade_min = zmin + (zmax - zmin) * dble (i - 1) /
     &    dble (NCONTR)
        shade_max = zmin + (zmax - zmin) * dble (i)     /
     &    dble (NCONTR)
        sh_color = dble (i - 1) / dble (NCONTR - 1)
        sh_width = 2
        call plpsty(0)
        call plshade0(z, NX, NY, ' ',
     &    dble ( -1.d0), 1.0d0, -1.0d0, 1.0d0,
     &    shade_min, shade_max,
     &    sh_cmap, sh_color, sh_width,
     &    min_color, min_width, max_color, max_width, xdim)
      enddo

      call plcol0(1)
      call plbox('bcnst', 0.0d0, 0, 'bcnstv', 0.0d0, 0)
      call plcol0(2)
      call pllab('distance', 'altitude', 'Bogon flux')

      end

c      Routine for demonstrating use_ of transformation arrays in contour plots.

      subroutine polar()

      implicit none
      integer   xdim, ydim, NX, NY, NCONTR, NBDRY
c      xdim and ydim are the static dimensions of the 2D arrays while
c      NX and NY are the defined area.
      parameter (xdim = 99, NX = 40, ydim = 100, NY = 64)
      parameter (NCONTR = 14, NBDRY=200)
      include 'plplot_parameters.h'

      real*8    z(xdim, ydim), ztmp(xdim, ydim+1)
      real*8    xg(xdim, ydim+1), yg(xdim, ydim+1),
     &   xtm(NBDRY), ytm(NBDRY)
      real*8    clevel(NCONTR)
      real*8    xmin, xmax, ymin, ymax, zmin, zmax
      real*8    xpmin, xpmax, ypmin, ypmax
      real*8    r, theta, rmax, x0, y0
      real*8    eps, q1, d1, q1i, d1i, q2, d2, q2i, d2i
      real*8    div1, div1i, div2, div2i

      real*8    shade_min, shade_max, sh_color
      real*8    xtick, ytick
      integer   nxsub, nysub
      integer   ncolbox, ncollab
      integer   i, j, kx, lx, ky, ly
      integer   sh_cmap, sh_width
      integer   min_color, min_width, max_color, max_width
      character*8 xopt, yopt

c      Set up for plshade call

      sh_cmap = 1
      min_color = 1
      min_width = 0
      max_color = 0
      max_width = 0

      kx = 1
      lx = NX
      ky = 1
      ly = NY

c      Set up r-theta grids
c      Tack on extra cell in theta to handle periodicity.

      do i = 1, NX
        r = i - 0.5d0
        do j = 1, NY
          theta = TWOPI/dble(NY) * (j-0.5d0)
          xg(i,j) = r * cos(theta)
          yg(i,j) = r * sin(theta)
        enddo
        xg(i, NY+1) = xg(i, 1)
        yg(i, NY+1) = yg(i, 1)
      enddo
      call a2mnmx(xg, NX, NY, xmin, xmax, xdim)
      call a2mnmx(yg, NX, NY, ymin, ymax, xdim)

      rmax = r
      x0 = (xmin + xmax)/2.d0
      y0 = (ymin + ymax)/2.d0

c      Potential inside a conducting cylinder (or sphere) by method of images.
c      Charge 1 is placed at (d1, d1), with image charge at (d2, d2).
c      Charge 2 is placed at (d1, -d1), with image charge at (d2, -d2).
c      Also put in smoothing term at small distances.

      eps = 2.d0

      q1 = 1.d0
      d1 = r/4.d0

      q1i = - q1*r/d1
      d1i = r**2/d1

      q2 = -1.d0
      d2 = r/4.d0

      q2i = - q2*r/d2
      d2i = r**2/d2

      do i = 1, NX
        do j = 1, NY
          div1 = sqrt((xg(i,j)-d1)**2 + (yg(i,j)-d1)**2 + eps**2)
          div1i = sqrt((xg(i,j)-d1i)**2 + (yg(i,j)-d1i)**2 + eps**2)

          div2 = sqrt((xg(i,j)-d2)**2 + (yg(i,j)+d2)**2 + eps**2)
          div2i = sqrt((xg(i,j)-d2i)**2 + (yg(i,j)+d2i)**2 + eps**2)

          z(i,j) = q1/div1 + q1i/div1i + q2/div2 + q2i/div2i
        enddo
      enddo

c      Tack on extra cell in theta to handle periodicity.

      do i = 1, NX
        do j = 1, NY
          ztmp(i,j) = z(i,j)
        enddo
        ztmp(i, NY+1) = z(i, 1)
      enddo
      call a2mnmx(z, NX, NY, zmin, zmax, xdim)

c      Set up contour levels.

      do i = 1, NCONTR
        clevel(i) = zmin + (i-0.5d0)*abs(zmax - zmin)/dble(NCONTR)
      enddo

c      Advance graphics frame and get ready to plot.

      ncolbox = 1
      ncollab = 2

      call pladv(0)
      call plcol0(ncolbox)

c      Scale window to user coordinates.
c      Make a bit larger so the boundary does not get clipped.

      eps = 0.05d0
      xpmin = xmin - abs(xmin)*eps
      xpmax = xmax + abs(xmax)*eps
      ypmin = ymin - abs(ymin)*eps
      ypmax = ymax + abs(ymax)*eps

      call plvpas(0.1d0, 0.9d0, 0.1d0, 0.9d0, 1.0d0)
      call plwind(xpmin, xpmax, ypmin, ypmax)

      xopt = ' '
      yopt = ' '
      xtick = 0.d0
      nxsub = 0
      ytick = 0.d0
      nysub = 0

      call plbox(xopt, xtick, nxsub, yopt, ytick, nysub)

c      Call plotter once for z < 0 (dashed), once for z > 0 (solid lines).

      do i = 1, NCONTR
        shade_min = zmin + (zmax - zmin) * dble (i - 1) /
     &    dble (NCONTR)
        shade_max = zmin + (zmax - zmin) * dble (i)     /
     &    dble (NCONTR)
        sh_color = dble (i - 1) / dble (NCONTR - 1)
        sh_width = 2
        call plpsty(0)

        call plshade2(z, NX, NY, ' ',
     &    -1.0d0, 1.0d0, -1.0d0, 1.0d0,
     &    shade_min, shade_max,
     &    sh_cmap, sh_color, sh_width,
     &    min_color, min_width, max_color, max_width, xg, yg, xdim)
      enddo

c      Draw boundary.

      do i = 1, NBDRY
        theta = (TWOPI)/(NBDRY-1) * dble(i-1)
        xtm(i) = x0 + rmax * cos(theta)
        ytm(i) = y0 + rmax * sin(theta)
      enddo
      call plcol0(ncolbox)
      call plline(NBDRY, xtm, ytm)

      call plcol0(ncollab)
      call pllab(' ', ' ',
     &'Shielded potential of charges in a conducting sphere')

      end

c----------------------------------------------------------------------------
c      Subroutine a2mnmx
c      Minimum and the maximum elements of a 2-d array.

      subroutine a2mnmx(f, nx, ny, fmin, fmax, xdim)
      implicit none

      integer   i, j, nx, ny, xdim
      real*8    f(xdim, ny), fmin, fmax

      fmax = f(1, 1)
      fmin = fmax
      do j = 1, ny
        do  i = 1, nx
          fmax = max(fmax, f(i, j))
          fmin = min(fmin, f(i, j))
        enddo
      enddo
      end

APT Browse - Built by Thomas Orozco.