/usr/share/perl5/perl5i/2/ARRAY.pm is in libperl5i-perl 2.8.0-1ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 | # vi: set ts=4 sw=4 ht=4 et :
package perl5i::2::ARRAY;
use 5.010;
use strict;
use warnings;
use Carp;
use perl5i::2::Signatures;
use perl5i::2::autobox;
# A foreach which honors the number of parameters in the signature
func foreach($array, $code) {
my $n = 1;
if( my $sig = $code->signature ) {
$n = $sig->num_positional_params;
croak "Function passed to foreach takes no arguments" unless $n;
}
my $idx = 0;
do {
$code->(@{$array}[$idx..($idx+$n-1)]);
$idx += $n;
} while $idx <= $#{$array};
return;
}
func first($array, $filter) {
# Deep recursion and segfault (lines 90 and 91 in first.t) if we use
# the same elegant approach as in grep().
if ( ref $filter eq 'Regexp' ) {
return List::Util::first( sub { $_ ~~ $filter }, @$array );
}
return List::Util::first( sub { $filter->() }, @$array );
}
func map( $array, $code ) {
my @result = CORE::map { $code->($_) } @$array;
return wantarray ? @result : \@result;
}
func grep($array, $filter) {
my @result = CORE::grep { $_ ~~ $filter } @$array;
return wantarray ? @result : \@result;
}
sub all {
require List::MoreUtils;
return &List::MoreUtils::all($_[1], @{$_[0]});
}
sub any {
require List::MoreUtils;
return &List::MoreUtils::any($_[1], @{$_[0]});
}
sub none {
require List::MoreUtils;
return &List::MoreUtils::none($_[1], @{$_[0]});
}
sub true {
require List::MoreUtils;
return &List::MoreUtils::true($_[1], @{$_[0]});
}
sub false {
require List::MoreUtils;
return &List::MoreUtils::false($_[1], @{$_[0]});
}
sub uniq {
require List::MoreUtils;
my @uniq = List::MoreUtils::uniq(@{$_[0]});
return wantarray ? @uniq : \@uniq;
}
sub minmax {
require List::MoreUtils;
my @minmax = List::MoreUtils::minmax(@{$_[0]});
return wantarray ? @minmax : \@minmax;
}
sub mesh {
require List::MoreUtils;
my @mesh = &List::MoreUtils::zip(@_);
return wantarray ? @mesh : \@mesh;
}
# Compare differences between two arrays.
my $diff_two_deeply = func($c, $d) {
my $diff = [];
# For each element of $c, try to find if it is equal to any of the
# elements of $d. If not, it's unique, and has to be pushed into
# $diff.
require perl5i::2::equal;
require List::MoreUtils;
foreach my $item (@$c) {
unless (
List::MoreUtils::any( sub { perl5i::2::equal::are_equal( $item, $_ ) }, @$d )
)
{
push @$diff, $item;
}
}
return $diff;
};
my $diff_two_simply = func($c, $d) {
no warnings 'uninitialized';
my %seen = map { $_ => 1 } @$d;
my @diff = grep { not $seen{$_} } @$c;
return \@diff;
};
func diff($base, @rest) {
unless (@rest) {
return wantarray ? @$base : $base;
}
require List::MoreUtils;
my $has_refs = List::MoreUtils::any(sub { ref $_ }, @$base);
my $diff_two = $has_refs ? $diff_two_deeply : $diff_two_simply;
# XXX If I use carp here, the exception is "bizarre copy of ARRAY in
# ssasign ... "
die "Arguments must be array references" if grep { ref $_ ne 'ARRAY' } @rest;
foreach my $array (@rest) {
$base = $diff_two->($base, $array);
}
return wantarray ? @$base : $base;
}
my $intersect_two_simply = func($c, $d) {
no warnings 'uninitialized';
my %seen = map { $_ => 1 } @$d;
my @intersect = grep { $seen{$_} } @$c;
return \@intersect;
};
# Compare differences between two arrays.
my $intersect_two_deeply = func($c, $d) {
require perl5i::2::equal;
my $intersect = [];
# For each element of $c, try to find if it is equal to any of the
# elements of $d. If it is, it's shared, and has to be pushed into
# $intersect.
require List::MoreUtils;
foreach my $item (@$c) {
if (
List::MoreUtils::any( sub { perl5i::2::equal::are_equal( $item, $_ ) }, @$d )
)
{
push @$intersect, $item;
}
}
return $intersect;
};
func intersect($base, @rest) {
unless (@rest) {
return wantarray ? @$base : $base;
}
require List::MoreUtils;
my $has_refs = List::MoreUtils::any(sub { ref $_ }, @$base);
my $intersect_two = $has_refs ? $intersect_two_deeply : $intersect_two_simply;
# XXX If I use carp here, the exception is "bizarre copy of ARRAY in
# ssasign ... "
die "Arguments must be array references" if grep { ref $_ ne 'ARRAY' } @rest;
foreach my $array (@rest) {
$base = $intersect_two->($base, $array);
}
return wantarray ? @$base : $base;
}
func ltrim($array, $charset) {
my @result = CORE::map { $_->ltrim($charset) } @$array;
return wantarray ? @result : \@result;
}
func rtrim($array, $charset) {
my @result = CORE::map { $_->rtrim($charset) } @$array;
return wantarray ? @result : \@result;
}
func trim($array, $charset) {
my @result = CORE::map { $_->trim($charset) } @$array;
return wantarray ? @result : \@result;
}
1;
|