/usr/share/radiance/sun.cal is in radiance-materials 4R0+20110410-1build1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 | {*
* SOLAR CALCULATIONS
*
* 7/25/84
* 10/10/86
*
*}
RLAT = 0.66; {* Site latitude (radians) *}
RLON = 2.13; {* Site longitude (radians) *}
RSM = 120 * PI/180; {* Standard meridian (radians) *}
stadj(jd) {* solar time adjustment (hours) *}
{ jd is days into year }
=
0.170 * sin( 4*PI/373 * (jd - 80) ) -
0.129 * sin( 2*PI/355 * (jd - 8 ) ) +
12*(RSM-RLON)/PI
;
sdec(jd) {* solar declination angle (radians) *}
{ jd is days into year }
=
0.4093 * sin( 2*PI/368 * (jd - 81) )
;
salt(sd, st) {* solar altitude (radians) *}
{ sd is solar declination, st is solar time (hours) }
=
asin( sin(RLAT) * sin(sd) - cos(RLAT) * cos(sd) *
cos(st*PI/12) )
;
sazi(sd, st) {* the solar azimuth (radians) *}
{ sd is solar declination, st is solar time (hours) }
=
-atan2( cos(sd) * sin(st*PI/12),
-cos(RLAT)*sin(sd) -
sin(RLAT)*cos(sd)*cos(st*PI/12) )
;
SAZI = sazi(SDEC, STIME) * 180/PI;
SALT = salt(SDEC, STIME) * 180/PI;
SDEC = sdec(JDATE);
STIME = TIME + stadj(JDATE);
JDATE = DAY + select(MONTH,0,31,59,90,120,151,181,212,243,273,304,334);
|