/usr/share/perl5/Mojo/Message/Response.pm is in libmojolicious-perl 2.23-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 | package Mojo::Message::Response;
use Mojo::Base 'Mojo::Message';
use Mojo::Cookie::Response;
use Mojo::Date;
use Mojo::Util 'get_line';
has [qw/code message/];
my $START_LINE_RE = qr|
^\s*
HTTP/(?<version>\d\.\d) # Version
\s+
(?<code>\d\d\d) # Code
\s*
(?<message>[\w\'\s]+)? # Message (with "I'm a teapot" support)
$
|x;
# Umarked codes are from RFC 2616
my %MESSAGES = (
100 => 'Continue',
101 => 'Switching Protocols',
102 => 'Processing', # RFC 2518 (WebDAV)
200 => 'OK',
201 => 'Created',
202 => 'Accepted',
203 => 'Non-Authoritative Information',
204 => 'No Content',
205 => 'Reset Content',
206 => 'Partial Content',
207 => 'Multi-Status', # RFC 2518 (WebDAV)
300 => 'Multiple Choices',
301 => 'Moved Permanently',
302 => 'Found',
303 => 'See Other',
304 => 'Not Modified',
305 => 'Use Proxy',
307 => 'Temporary Redirect',
400 => 'Bad Request',
401 => 'Unauthorized',
402 => 'Payment Required',
403 => 'Forbidden',
404 => 'Not Found',
405 => 'Method Not Allowed',
406 => 'Not Acceptable',
407 => 'Proxy Authentication Required',
408 => 'Request Timeout',
409 => 'Conflict',
410 => 'Gone',
411 => 'Length Required',
412 => 'Precondition Failed',
413 => 'Request Entity Too Large',
414 => 'Request-URI Too Large',
415 => 'Unsupported Media Type',
416 => 'Request Range Not Satisfiable',
417 => 'Expectation Failed',
418 => "I'm a teapot", # :)
422 => 'Unprocessable Entity', # RFC 2518 (WebDAV)
423 => 'Locked', # RFC 2518 (WebDAV)
424 => 'Failed Dependency', # RFC 2518 (WebDAV)
425 => 'Unordered Colection', # RFC 3648 (WebDav)
426 => 'Upgrade Required', # RFC 2817
428 => 'Precondition Required', # draft-nottingham-http-new-status
429 => 'Too Many Requests', # draft-nottingham-http-new-status
431 => 'Request Header Fields Too Large', # draft-nottingham-http-new-status
449 => 'Retry With', # unofficial Microsoft
500 => 'Internal Server Error',
501 => 'Not Implemented',
502 => 'Bad Gateway',
503 => 'Service Unavailable',
504 => 'Gateway Timeout',
505 => 'HTTP Version Not Supported',
506 => 'Variant Also Negotiates', # RFC 2295
507 => 'Insufficient Storage', # RFC 2518 (WebDAV)
509 => 'Bandwidth Limit Exceeded', # unofficial
510 => 'Not Extended', # RFC 2774
511 => 'Network Authentication Required', # draft-nottingham-http-new-status
);
sub cookies {
my $self = shift;
# Add cookies
if (@_) {
for my $cookie (@_) {
$cookie = Mojo::Cookie::Response->new($cookie)
if ref $cookie eq 'HASH';
$self->headers->add('Set-Cookie', "$cookie");
}
return $self;
}
# Set-Cookie2
my @cookies;
my $headers = $self->headers;
push @cookies, @{Mojo::Cookie::Response->parse($_)}
for $headers->set_cookie2;
# Set-Cookie
push @cookies, @{Mojo::Cookie::Response->parse($_)}
for $headers->set_cookie;
return \@cookies;
}
sub default_message { $MESSAGES{$_[1] || $_[0]->code || 404} || '' }
sub fix_headers {
my $self = shift;
$self->SUPER::fix_headers(@_);
# Date header is required in responses
my $headers = $self->headers;
$headers->date(Mojo::Date->new->to_string) unless $headers->date;
return $self;
}
sub is_status_class {
my ($self, $class) = @_;
return unless my $code = $self->code;
return $code >= $class && $code < ($class + 100);
}
sub _build_start_line {
my $self = shift;
# HTTP 0.9 has no start line
my $version = $self->version;
return '' if $version eq '0.9';
# HTTP 1.0 and above
my $code = $self->code || 404;
my $message = $self->message || $self->default_message;
return "HTTP/$version $code $message\x0d\x0a";
}
# "Weaseling out of things is important to learn.
# It's what separates us from the animals... except the weasel."
sub _parse_start_line {
my $self = shift;
# Try to detect HTTP 0.9
if ($self->{buffer} =~ /^\s*(\S.{4})/ && $1 !~ m#^HTTP/#) {
$self->version('0.9');
$self->content->relaxed(1);
return $self->{state} = 'content';
}
# We have a full HTTP 1.0+ response line
return unless defined(my $line = get_line \$self->{buffer});
return $self->error('Bad response start line.')
unless $line =~ $START_LINE_RE;
$self->version($+{version});
$self->code($+{code});
$self->message($+{message});
$self->content->auto_relax(1);
$self->{state} = 'content';
}
1;
__END__
=head1 NAME
Mojo::Message::Response - HTTP 1.1 response container
=head1 SYNOPSIS
use Mojo::Message::Response;
# Parse
my $res = Mojo::Message::Reponse->new;
$res->parse("HTTP/1.0 200 OK\x0a\x0d");
$res->parse("Content-Length: 12\x0a\x0d\x0a\x0d");
$res->parse("Content-Type: text/plain\x0a\x0d\x0a\x0d");
$res->parse('Hello World!');
say $res->body;
# Build
my $res = Mojo::Message::Response->new;
$res->code(200);
$res->headers->content_type('text/plain');
$res->body('Hello World!');
say $res->to_string;
=head1 DESCRIPTION
L<Mojo::Message::Response> is a container for HTTP 1.1 responses as described
in RFC 2616.
=head1 EVENTS
L<Mojo::Message::Response> inherits all events from L<Mojo::Message>.
=head1 ATTRIBUTES
L<Mojo::Message::Response> inherits all attributes from L<Mojo::Message>
and implements the following new ones.
=head2 C<code>
my $code = $res->code;
$res = $res->code(200);
HTTP response code.
=head2 C<message>
my $message = $res->message;
$res = $res->message('OK');
HTTP response message.
=head1 METHODS
L<Mojo::Message::Response> inherits all methods from L<Mojo::Message> and
implements the following new ones.
=head2 C<cookies>
my $cookies = $res->cookies;
$res = $res->cookies(Mojo::Cookie::Response->new);
$req = $req->cookies({name => 'foo', value => 'bar'});
Access response cookies, usually L<Mojo::Cookie::Response> objects.
=head2 C<default_message>
my $message = $res->default_message;
Generate default response message for code.
=head2 C<fix_headers>
$res = $res->fix_headers;
Make sure message has all required headers for the current HTTP version.
=head2 C<is_status_class>
my $success = $res->is_status_class(200);
Check response status class.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|