/usr/share/perl5/Config/Model/HashId.pm is in libconfig-model-perl 2.005-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 | #
# This file is part of Config-Model
#
# This software is Copyright (c) 2012 by Dominique Dumont, Krzysztof Tyszecki.
#
# This is free software, licensed under:
#
# The GNU Lesser General Public License, Version 2.1, February 1999
#
package Config::Model::HashId ;
{
$Config::Model::HashId::VERSION = '2.005';
}
use Any::Moose ;
use namespace::autoclean;
use Config::Model::Exception ;
use Carp;
use Log::Log4perl qw(get_logger :levels);
my $logger = get_logger("Tree::Element::Id::Hash");
extends qw/Config::Model::AnyId/ ;
has data => ( is => 'rw', isa => 'HashRef' , default => sub { {} ;} ) ;
has list => ( is => 'rw', isa => 'ArrayRef', default => sub { [] ;} ) ;
has [qw/default_keys auto_create_keys/] => ( is => 'rw', isa => 'ArrayRef', default => sub { [] ;} ) ;
has [qw/morph ordered/] => (is => 'ro', isa => 'Bool' ) ;
sub BUILD {
my $self = shift;
# could use "required", but we'd get a Moose error instead of a Config::Model
# error
Config::Model::Exception::Model->throw
(
object => $self,
error => "Undefined index_type"
) unless defined $self->index_type ;
return $self;
}
sub set_properties {
my $self = shift ;
$self->SUPER::set_properties(@_) ;
my $idx_type = $self->{index_type} ;
# remove unwanted items
my $data = $self->{data} ;
my $idx = 1 ;
my $wrong = sub {
my $k = shift ;
if ($idx_type eq 'integer') {
return 1 if defined $self->{max_index} and $k > $self->{max_index} ;
return 1 if defined $self->{min_index} and $k < $self->{min_index} ;
}
return 1 if defined $self->{max_nb} and $idx++ > $self->{max_nb};
return 0 ;
} ;
# delete entries that no longer fit the constraints imposed by the
# warp mechanism
foreach my $k (sort keys %$data) {
next unless $wrong->($k) ;
$logger->debug("set_properties: ",$self->name," deleting id $k");
delete $data->{$k} ;
}
}
sub get_type {
my $self = shift;
return 'hash' ;
}
sub fetch_size {
my $self = shift;
return scalar keys %{$self->{data}} ;
}
sub _get_all_indexes {
my $self = shift;
return $self->{ordered} ? @{$self->{list}}
: sort keys %{$self->{data}} ;
}
# fetch without any check
sub _fetch_with_id {
my ($self,$key) = @_ ;
my $i = $self->instance ;
return $self->{data}{$key};
}
# store without any check
sub _store {
my ($self, $key, $value) = @_ ;
push @{$self->{list}}, $key
unless exists $self->{data}{$key};
return $self->{data}{$key} = $value ;
}
sub _exists {
my ($self,$key) = @_ ;
return exists $self->{data}{$key};
}
sub _defined {
my ($self,$key) = @_ ;
return defined $self->{data}{$key} ? 1 : 0;
}
#internal
sub auto_create_elements {
my $self = shift ;
my $auto_p = $self->auto_create_keys ;
return unless defined $auto_p ;
# create empty slots
map {
$self->_store($_, undef) unless exists $self->{data}{$_};
} (ref $auto_p ? @$auto_p : ($auto_p)) ;
}
# internal
sub create_default {
my $self = shift ;
my @temp = keys %{$self->{data}} ;
return if @temp ;
# hash is empty so create empty element for default keys
my $def = $self->get_default_keys ;
map {$self->_store($_,undef) } @$def ;
$self->create_default_with_init ;
}
sub _delete {
my ($self,$key) = @_ ;
# remove key in ordered list
@{$self->{list}} = grep { $_ ne $key } @{ $self->{list}} ;
return delete $self->{data}{$key};
}
sub remove {
my $self = shift ;
$self->delete(@_) ;
}
sub _clear {
my ($self) = @_ ;
$self->{list} = [];
$self->{data} = {};
}
# hash only method
sub firstkey {
my $self = shift ;
$self->warp
if ($self->{warp} and @{$self->{warp_info}{computed_master}});
$self->create_default if defined $self->{default};
# reset "each" iterator (to be sure, map is also an iterator)
my @list = $self->_get_all_indexes ;
$self->{each_list} = \@list ;
return shift @list ;
}
# hash only method
sub nextkey {
my $self = shift ;
$self->warp
if ($self->{warp} and @{$self->{warp_info}{computed_master}});
my $res = shift @{$self->{each_list}} ;
return $res if defined $res ;
# reset list for next call to next_keys
$self->{each_list} = [ $self->_get_all_indexes ] ;
return ;
}
sub swap {
my $self = shift ;
my ($key1,$key2) = @_ ;
foreach my $k (@_) {
Config::Model::Exception::User
-> throw (
object => $self,
message => "swap: unknow key $k"
)
unless exists $self->{data}{$k} ;
}
my @copy = @{$self->{list}} ;
for (my $idx = 0; $idx <= $#copy; $idx ++ ) {
if ($copy[$idx] eq $key1) {
$self->{list}[$idx] = $key2 ;
}
if ($copy[$idx] eq $key2) {
$self->{list}[$idx] = $key1 ;
}
}
}
sub move {
my $self = shift ;
my ($from,$to) = @_ ;
Config::Model::Exception::User
-> throw (
object => $self,
message => "move: unknow key $from"
)
unless exists $self->{data}{$from} ;
my $ok = $self->check_idx($to) ;
if ($ok) {
# this may clobber the old content of $self->{data}{$to}
$self->{data}{$to} = delete $self->{data}{$from} ;
delete $self->{warning_hash}{$from} ;
# update index_value attribute in moved objects
$self->{data}{$to}->index_value($to) ;
# data_mode is preset or layered or user. Actually only user
# mode makes sense here
my $imode = $self->instance->get_data_mode ;
$self->set_data_mode( $to, $imode ) ;
my ($to_idx,$from_idx);
my $idx = 0 ;
my $list = $self->{list} ;
map { $to_idx = $idx if $list->[$idx] eq $to;
$from_idx = $idx if $list->[$idx] eq $from;
$idx ++ ;
} @$list ;
if (defined $to_idx) {
# Since $to is clobbered, $from takes its place in the list
$list->[$from_idx] = $to ;
# and the $from entry is removed from the list
splice @$list,$to_idx,1;
} else {
# $to is moved in the place of from in the list
$list->[$from_idx] = $to ;
}
} else {
Config::Model::Exception::WrongValue
-> throw (
error => join("\n\t",@{$self->{error}}),
object => $self
) ;
}
}
sub move_after {
my $self = shift ;
my ($key_to_move,$ref_key) = @_ ;
foreach my $k (@_) {
Config::Model::Exception::User
-> throw (
object => $self,
message => "swap: unknow key $k"
)
unless exists $self->{data}{$k} ;
}
# remove the key to move in ordered list
@{$self->{list}} = grep { $_ ne $key_to_move } @{ $self->{list}} ;
my $list = $self->{list} ;
if (defined $ref_key) {
for (my $idx = 0; $idx <= $#$list; $idx ++ ) {
if ($list->[$idx] eq $ref_key) {
splice @$list ,$idx+1,0, $key_to_move ;
last;
}
}
} else {
unshift @$list , $key_to_move ;
}
}
sub move_up {
my $self = shift ;
my ($key) = @_ ;
Config::Model::Exception::User
-> throw (
object => $self,
message => "move_up: unknow key $key"
)
unless exists $self->{data}{$key} ;
my $list = $self->{list} ;
# we start from 1 as we can't move up idx 0
for (my $idx = 1; $idx < scalar @$list; $idx ++ ) {
if ($list->[$idx] eq $key) {
$list->[$idx] = $list->[$idx-1];
$list->[$idx-1] = $key ;
last ;
}
}
}
sub move_down {
my $self = shift ;
my ($key) = @_ ;
Config::Model::Exception::User
-> throw (
object => $self,
message => "move_down: unknown key $key"
)
unless exists $self->{data}{$key} ;
my $list = $self->{list} ;
# we end at $#$list -1 as we can't move down last idx
for (my $idx = 0; $idx < scalar @$list - 1 ; $idx ++ ) {
if ($list->[$idx] eq $key) {
$list->[$idx] = $list->[$idx+1];
$list->[$idx+1] = $key ;
last ;
}
}
}
sub load_data {
my $self = shift ;
my $data = shift ;
if (ref ($data) eq 'HASH') {
my @load_keys ;
my $from = ''; ;
if ($self->{ordered} and defined $data->{__order}) {
@load_keys = @{ delete $data->{__order} };
$from = ' with __order' ;
} elsif ($self->{ordered}) {
$logger->warn("HashId ".$self->location.": loading ordered "
."hash from hash ref without special key '__order'. Element "
."order is not defined");
$from = ' without __order' ;
}
@load_keys = sort keys %$data unless @load_keys;
$logger->info("HashId load_data (".$self->location.
") will load idx @load_keys from hash ref".$from);
foreach my $elt (@load_keys) {
my $obj = $self->fetch_with_id($elt) ;
$obj -> load_data($data->{$elt}) ;
}
}
elsif ( $self->{ordered} and ref ($data) eq 'ARRAY') {
$logger->info("HashId load_data (".$self->location
.") will load idx 0..$#$data from array ref") ;
my $idx = 0 ;
while ( $idx < @$data ) {
my $elt = $data->[$idx++];
my $obj = $self->fetch_with_id($elt) ;
$obj -> load_data($data->[$idx++]) ;
}
}
elsif (defined $data) {
# we can skip undefined data
my $expected = $self->{ordered} ? 'array' : 'hash' ;
Config::Model::Exception::LoadData
-> throw (
object => $self,
message => "load_data called with non $expected ref arg",
wrong_data => $data ,
) ;
}
}
__PACKAGE__->meta->make_immutable;
1;
__END__
=pod
=head1 NAME
Config::Model::HashId - Handle hash element for configuration model
=head1 VERSION
version 2.005
=head1 SYNOPSIS
See L<Config::Model::AnyId/SYNOPSIS>
=head1 DESCRIPTION
This class provides hash elements for a L<Config::Model::Node>.
The hash index can either be en enumerated type, a boolean, an integer
or a string.
=head1 CONSTRUCTOR
HashId object should not be created directly.
=head1 Hash model declaration
See
L<model declaration section|Config::Model::AnyId/"Hash or list model declaration">
from L<Config::Model::AnyId>.
=head1 Methods
=head2 get_type
Returns C<hash>.
=head2 fetch_size
Returns the number of elements of the hash.
=head2 firstkey
Returns the first key of the hash. Behaves like C<each> core perl
function.
=head2 nextkey
Returns the next key of the hash. Behaves like C<each> core perl
function.
=head2 swap ( key1 , key2 )
Swap the order of the 2 keys. Ignored for non ordered hash.
=head2 move ( key1 , key2 )
Rename key1 in key2.
=head2 move_after ( key_to_move [ , after_this_key ] )
Move the first key after the second one. If the second parameter is
omitted, the first key is placed in first position. Ignored for non
ordered hash.
=head2 move_up ( key )
Move the key up in a ordered hash. Attempt to move up the first key of
an ordered hash will be ignored. Ignored for non ordered hash.
=head2 move_down ( key )
Move the key down in a ordered hash. Attempt to move up the last key of
an ordered hash will be ignored. Ignored for non ordered hash.
=head2 load_data ( hash_ref | array_ref )
Load check_list as a hash ref for standard hash.
Ordered hash should be loaded with an array ref or with a hash
containing a special C<__order> element. E.g. loaded with either:
[ a => 'foo', b => 'bar' ]
or
{ __order => ['a','b'], b => 'bar', a => 'foo' }
=head1 AUTHOR
Dominique Dumont, (ddumont at cpan dot org)
=head1 SEE ALSO
L<Config::Model>,
L<Config::Model::Instance>,
L<Config::Model::AnyId>,
L<Config::Model::ListId>,
L<Config::Model::Value>
=cut
|