/usr/share/perl5/Catalyst/EngineLoader.pm is in libcatalyst-perl 5.90007-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 | package Catalyst::EngineLoader;
use Moose;
use Catalyst::Exception;
use Catalyst::Utils;
use namespace::autoclean;
extends 'Plack::Loader';
has application_name => (
isa => 'Str',
is => 'ro',
required => 1,
);
has requested_engine => (
is => 'ro',
isa => 'Str',
predicate => 'has_requested_engine',
);
sub needs_psgi_engine_compat_hack {
my ($self) = @_;
return $self->has_requested_engine
&& $self->requested_engine eq 'PSGI';
}
has catalyst_engine_class => (
isa => 'Str',
is => 'rw',
lazy => 1,
builder => '_guess_catalyst_engine_class',
);
sub _guess_catalyst_engine_class {
my $self = shift;
my $old_engine = $self->has_requested_engine
? $self->requested_engine
: Catalyst::Utils::env_value($self->application_name, 'ENGINE');
if (!defined $old_engine) {
return 'Catalyst::Engine';
}
elsif ($old_engine eq 'PSGI') {
## If we are running under plackup let the Catalyst::Engine::PSGI
## continue to run, but warn.
warn <<"EOW";
You are running Catalyst::Engine::PSGI, which is considered a legacy engine for
this version of Catalyst. We will continue running and use your existing psgi
file, but it is recommended to perform the trivial upgrade process, which will
leave you with less code and a forward path.
Please review Catalyst::Upgrading
EOW
return 'Catalyst::Engine::' . $old_engine;
}
elsif ($old_engine =~ /^(CGI|FastCGI|HTTP|Apache.*)$/) {
return 'Catalyst::Engine';
}
else {
return 'Catalyst::Engine::' . $old_engine;
}
}
around guess => sub {
my ($orig, $self) = (shift, shift);
my $engine = $self->$orig(@_);
if ( $ENV{MOD_PERL} ) {
my ( $software, $version ) =
$ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
$version =~ s/_//g;
$version =~ s/(\.[^.]+)\./$1/g;
if ( $software eq 'mod_perl' ) {
if ( $version >= 1.99922 ) {
$engine = 'Apache2';
}
elsif ( $version >= 1.9901 ) {
Catalyst::Exception->throw( message => 'Plack does not have a mod_perl 1.99 handler' );
$engine = 'Apache2::MP19';
}
elsif ( $version >= 1.24 ) {
$engine = 'Apache1';
}
else {
Catalyst::Exception->throw( message =>
qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
}
}
}
my $old_engine = Catalyst::Utils::env_value($self->application_name, 'ENGINE');
if (!defined $old_engine) { # Not overridden
}
elsif ($old_engine =~ /^(PSGI|CGI|Apache.*)$/) {
# Trust autodetect
}
elsif ($old_engine eq 'HTTP') {
$engine = 'Standalone';
}
elsif ($old_engine eq 'FastCGI') {
$engine = 'FCGI';
}
elsif ($old_engine eq "HTTP::Prefork") { # Too bad if you're customising, we don't handle options
# write yourself a script to collect and pass in the options
$engine = "Starman";
}
elsif ($old_engine eq "HTTP::POE") {
Catalyst::Exception->throw("HTTP::POE engine no longer works, recommend you use Twiggy instead");
}
elsif ($old_engine eq "Zeus") {
Catalyst::Exception->throw("Zeus engine no longer works");
}
else {
warn("You asked for an unrecognised engine '$old_engine' which is no longer supported, this has been ignored.\n");
}
return $engine;
};
# Force constructor inlining
__PACKAGE__->meta->make_immutable( replace_constructor => 1 );
1;
__END__
=head1 NAME
Catalyst::EngineLoader - The Catalyst Engine Loader
=head1 SYNOPSIS
See L<Catalyst>.
=head1 DESCRIPTION
Wrapper on L<Plack::Loader> which resets the ::Engine if you are using some
version of mod_perl.
=head1 AUTHORS
Catalyst Contributors, see Catalyst.pm
=head1 COPYRIGHT
This library is free software. You can redistribute it and/or modify it under
the same terms as Perl itself.
=begin Pod::Coverage
needs_psgi_engine_compat_hack
=end Pod::Coverage
=cut
|