/usr/share/perl5/Authen/Simple/Password.pm is in libauthen-simple-perl 0.4-5.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 | package Authen::Simple::Password;
use strict;
use warnings;
use Crypt::PasswdMD5 qw[];
use Digest::MD5 qw[];
use Digest::SHA qw[];
use MIME::Base64 qw[];
sub check {
my ( $class, $password, $encrypted ) = @_;
# Plain
return 1 if $password eq $encrypted;
# L S
# Des 13 2
# Extended DES 20 9
# $1$ MD5 34 12
# $2$ Blowfish 34 16
# $3$ NT-Hash ? ?
# Crypt
return 1 if crypt( $password, $encrypted ) eq $encrypted;
# Crypt Modular Format
if ( $encrypted =~ /^\$(\w+)\$/ ) {
return 1 if $class->_check_modular( $password, $encrypted, lc($1) );
}
# LDAP Format
if ( $encrypted =~ /^\{(\w+)\}/ ) {
return 1 if $class->_check_ldap( $password, $encrypted, lc($1) );
}
# MD5
if ( length($encrypted) == 16 ) {
return 1 if Digest::MD5::md5($password) eq $encrypted;
}
if ( length($encrypted) == 22 ) {
return 1 if Digest::MD5::md5_base64($password) eq $encrypted;
}
if ( length($encrypted) == 32 ) {
return 1 if Digest::MD5::md5_hex($password) eq $encrypted;
}
# SHA-1
if ( length($encrypted) == 20 ) {
return 1 if Digest::SHA::sha1($password) eq $encrypted;
}
if ( length($encrypted) == 27 ) {
return 1 if Digest::SHA::sha1_base64($password) eq $encrypted;
}
if ( length($encrypted) == 40 ) {
return 1 if Digest::SHA::sha1_hex($password) eq $encrypted;
}
# SHA-2 256
if ( length($encrypted) == 32 ) {
return 1 if Digest::SHA::sha256($password) eq $encrypted;
}
if ( length($encrypted) == 43 ) {
return 1 if Digest::SHA::sha256_base64($password) eq $encrypted;
}
if ( length($encrypted) == 64 ) {
return 1 if Digest::SHA::sha256_hex($password) eq $encrypted;
}
return 0;
}
sub _check_ldap {
my ( $class, $password, $encrypted, $scheme ) = @_;
if ( $scheme eq 'cleartext' ) {
my $hash = substr( $encrypted, 11 );
return 1 if $password eq $hash;
}
if ( $scheme eq 'crypt' ) {
my $hash = substr( $encrypted, 7 );
return 1 if crypt( $password, $hash ) eq $hash;
}
if ( $scheme eq 'md5' ) {
my $hash = MIME::Base64::decode( substr( $encrypted, 5 ) );
return 1 if Digest::MD5::md5($password) eq $hash;
}
if ( $scheme eq 'smd5' ) {
my $hash = MIME::Base64::decode( substr( $encrypted, 6 ) );
my $salt = substr( $hash, 16 );
return 1 if Digest::MD5::md5( $password, $salt ) . $salt eq $hash;
}
if ( $scheme eq 'sha' ) {
my $hash = MIME::Base64::decode( substr( $encrypted, 5 ) );
return 1 if Digest::SHA::sha1($password) eq $hash;
}
if ( $scheme eq 'ssha' ) {
my $hash = MIME::Base64::decode( substr( $encrypted, 6 ) );
my $salt = substr( $hash, 20 );
return 1 if Digest::SHA::sha1( $password, $salt ) . $salt eq $hash;
}
return 0;
}
sub _check_modular {
my ( $class, $password, $encrypted, $format ) = @_;
if ( $format eq '1' ) {
return 1 if Crypt::PasswdMD5::unix_md5_crypt( $password, $encrypted ) eq $encrypted;
}
if ( $format eq 'apr1' ) {
return 1 if Crypt::PasswdMD5::apache_md5_crypt( $password, $encrypted ) eq $encrypted;
}
return 0;
}
1;
__END__
=head1 NAME
Authen::Simple::Password - Simple password checking
=head1 SYNOPSIS
if ( Authen::Simple::Password->check( $password, $encrypted ) ) {
# OK
}
=head1 DESCRIPTION
Provides a simple way to verify passwords.
=head1 METHODS
=over 4
=item * check( $password, $encrypted )
Returns true on success and false on failure.
=back
=head1 SUPPORTED PASSWORD FORMATS
=over 4
=item * Plain
Plaintext
=item * Crypt
L<crypt(3)>
=item * Crypt Modular
=over 8
=item * $1$
MD5-based password algorithm
=item * $apr$
MD5-based password algorithm, Apache variant
=back
=item * LDAP
=over 8
=item * {CLEARTEXT}
Plaintext.
=item * {CRYPT}
Uses L<crypt(3)>
=item * {MD5}
MD5 algorithm
=item * {SMD5}
Seeded MD5 algorithm
=item * {SHA}
SHA-1 algorithm
=item * {SSHA}
Seeded SHA-1 algorithm
=back
=item * MD5 algorithm
Encoded as binary, Base64 or hexadecimal.
=item * SHA-1 algorithm
Encoded as binary, Base64 or hexadecimal.
=item * SHA-2 256 algorithm
Encoded as binary, Base64 or hexadecimal.
=back
=head1 SEE ALSO
L<Authen::Simple>
L<crypt(3)>.
=head1 AUTHOR
Christian Hansen C<ch@ngmedia.com>
=head1 COPYRIGHT
This program is free software, you can redistribute it and/or modify
it under the same terms as Perl itself.
=cut
|