/usr/share/nrn/demo/release/cachan1.mod is in neuron 7.5-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 | TITLE ca channel
: Ca channel used by Augustine (1990) J. Physiol. 431
: 341-364 should use at celsius = 16
NEURON {
SUFFIX cachan1
USEION ca READ cao,cai WRITE ica
RANGE K, ica, imax
GLOBAL inf, tau, rfac
THREADSAFE
}
UNITS {
(mA) = (milliamp)
(mV) = (millivolt)
(M) = (1/liter)
(mM) = (milliM)
k = (k) (joule/degC)
e = (e) (coulombs)
}
PARAMETER {
rfac = 1 <.01, 1e5>
K = 140 (/M) <1e-6, 1e6>
imax = 1 (mA/cm2) <0, 1e9>
}
STATE {
S
}
ASSIGNED {
v (mV)
cao (mM)
cai (mM)
celsius (degC) : 16
ica (mA/cm2)
inf
tau (ms)
}
INITIAL {
rate(v)
S = inf
}
BREAKPOINT {LOCAL kca
SOLVE states METHOD cnexp
kca = K*cao*exp(-.08(/mV)*(v+70))
ica = -imax * S^5 * (kca - K*cai)/(1 + kca)
}
DERIVATIVE states { : exact when v held constant
rate(v)
S' = (inf - S)/tau
}
FUNCTION alp(v(mV))(/ms) {
alp = rfac * 1.1(/ms)*exp(.85*(.001)*e/k/(273+celsius)*v)
}
FUNCTION bet(v(mV))(/ms) {
bet = rfac * .168(/ms)*exp(-.38*(.001)*e/k/(273+celsius)*v)
}
PROCEDURE rate(v(mV)) {LOCAL a, b
TABLE inf, tau DEPEND celsius, rfac FROM -100 TO 100 WITH 200
a = alp(v) b=bet(v)
tau = 1/(a + b)
inf = a/(a + b)
}
|