/usr/share/qt4/mkspecs/features/kqoauth.prf is in libkqoauth0 0.98-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 | KQOAUTH_INCDIR = /usr/include
KQOAUTH_LIBDIR = /usr/lib
KQOAUTH_INCDIR ~= s!/qt4*!!
KQOAUTH_LIBDIR ~= s!/qt4*!!
CONFIG *= qt
CONFIG += crypto
# if we are including koauth.prf from the kqoauth tree (and not utilizing it as
# an installed qmake CONFIG feature), then point to the tree. this allows our
# kqoauth tree apps to build before kqoauth itself is installed.
exists($$PWD/kqoauth.pro) {
KQOAUTH_INCDIR = $$PWD/include
KQOAUTH_LIBDIR = $$PWD/lib
}
LINKAGE =
# on mac, if kqoauth was built as a framework, link against it
mac: {
framework_dir = $$[QT_INSTALL_LIBS]
KQOAUTH_INCDIR = $$[QT_INSTALL_HEADERS]
exists($$framework_dir/kqoauth.framework) {
LIBS += -F$$framework_dir
exists($$PWD/kqoauth.pro): INCLUDEPATH += $$KQOAUTH_INCDIR
else: INCLUDEPATH += $$framework_dir/kqoauth.framework/Headers
LINKAGE = -framework kqoauth
}
}
windows: {
KQOAUTH_INCDIR = $$[QT_INSTALL_HEADERS]
KQOAUTH_LIBDIR = $$[QT_INSTALL_LIBS]
exists($$PWD/kqoauth.pro): {
KQOAUTH_INCDIR = $$PWD/include
KQOAUTH_LIBDIR = $$PWD/lib
}
INCLUDEPATH += $$KQOAUTH_INCDIR/QtKOAuth
LIBS += -L$$KQOAUTH_LIBDIR
LINKAGE = -lkqoauth0
}
# else, link normally
isEmpty(LINKAGE) {
exists($$PWD/kqoauth.pro): INCLUDEPATH += $$KQOAUTH_INCDIR
else: INCLUDEPATH += $$KQOAUTH_INCDIR/QtKOAuth
LIBS += -L$$KQOAUTH_LIBDIR
LINKAGE = -lkqoauth
CONFIG(debug, debug|release) {
mac:LINKAGE = -lkqoauth_debug
}
}
LIBS += $$LINKAGE
|