/usr/share/ada/adainclude/gnatcoll/gnatcoll-scripts-files.adb is in libgnatcoll16.1.0-dev 17.0.2017-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 | ------------------------------------------------------------------------------
-- G N A T C O L L --
-- --
-- Copyright (C) 2003-2017, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- --
-- --
-- --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with GNATCOLL.Projects;
with GNATCOLL.VFS; use GNATCOLL.VFS;
with GNATCOLL.VFS_Utils; use GNATCOLL.VFS_Utils;
with GNATCOLL.Scripts.Projects; use GNATCOLL.Scripts.Projects;
package body GNATCOLL.Scripts.Files is
type File_Properties_Record is new Instance_Property_Record with record
File : Virtual_File;
end record;
procedure File_Command_Handler
(Data : in out Callback_Data'Class; Command : String);
-- Handler for the "File" commands
File_Class_Name : constant String := "File";
Default_Cst : aliased constant String := "default_to_root";
Name_Cst : aliased constant String := "name";
Local_Cst : aliased constant String := "local";
Server_Cst : aliased constant String := "remote_server";
File_Cmd_Parameters : constant Cst_Argument_List :=
(1 => Name_Cst'Access,
2 => Local_Cst'Access);
File_Name_Parameters : constant Cst_Argument_List :=
(1 => Server_Cst'Access);
File_Project_Parameters : constant Cst_Argument_List :=
(1 => Default_Cst'Access);
-----------------
-- Create_File --
-----------------
function Create_File
(Script : access Scripting_Language_Record'Class;
File : GNATCOLL.VFS.Virtual_File) return Class_Instance
is
Instance : constant Class_Instance := New_Instance
(Script, New_Class (Get_Repository (Script), File_Class_Name));
begin
Set_Data (Instance, File);
return Instance;
end Create_File;
--------------
-- Get_Data --
--------------
function Get_Data
(Instance : Class_Instance) return GNATCOLL.VFS.Virtual_File
is
Data : Instance_Property;
begin
if Instance /= No_Class_Instance then
Data := Get_Data (Instance, File_Class_Name);
end if;
if Data = null then
return GNATCOLL.VFS.No_File;
else
return File_Properties_Record (Data.all).File;
end if;
end Get_Data;
--------------------
-- Get_File_Class --
--------------------
function Get_File_Class
(Data : Callback_Data'Class)
return Class_Type is
begin
return New_Class (Data.Get_Repository, File_Class_Name);
end Get_File_Class;
--------------------------
-- File_Command_Handler --
--------------------------
procedure File_Command_Handler
(Data : in out Callback_Data'Class; Command : String)
is
use type GNATCOLL.Projects.Project_Type;
use type GNATCOLL.Projects.Project_Tree_Access;
Info : Virtual_File;
P : GNATCOLL.Projects.Project_Tree_Access;
function Get_Project (File : Virtual_File;
Default_To_Root : Boolean := False)
return GNATCOLL.Projects.Project_Type;
-- Return the project to which File belongs. If File does not belong to
-- any project, return the root project if Default_To_Root is True.
-----------------
-- Get_Project --
-----------------
function Get_Project (File : Virtual_File;
Default_To_Root : Boolean := False)
return GNATCOLL.Projects.Project_Type
is
File_Info : constant GNATCOLL.Projects.File_Info'Class :=
GNATCOLL.Projects.File_Info'Class
(P.Info_Set (File).First_Element);
Project : GNATCOLL.Projects.Project_Type;
begin
-- Return the first possible project, we have nothing else to base
-- our guess on.
Project := File_Info.Project;
if Project = GNATCOLL.Projects.No_Project
and then Default_To_Root
then
Project := P.Root_Project;
end if;
return Project;
end Get_Project;
begin
if Command = Constructor_Method then
Name_Parameters (Data, File_Cmd_Parameters);
declare
Instance : constant Class_Instance :=
Nth_Arg (Data, 1, Get_File_Class (Data));
Name : constant Filesystem_String := Nth_Arg (Data, 2);
begin
if Is_Absolute_Path (Name) then
Set_Data (Instance, Create (Name));
return;
end if;
-- Base name case. Find full name using the following rules:
-- 1) If third argument is set to true, create from current dir
-- else
-- 2) If Base Name can be found in project, use it
-- else
-- 3) Create from current dir
-- If we really want to create from current directory
if Number_Of_Arguments (Data) > 2 then
declare
From_Current : constant Boolean := Nth_Arg (Data, 3);
begin
if From_Current then
Set_Data
(Instance,
Create_From_Dir (Get_Current_Dir, Name));
return;
end if;
end;
end if;
if Project_Tree /= null then
declare
File : constant Virtual_File :=
Project_Tree.Create
(Base_Name (Create_From_Base (Name)));
begin
if File /= No_File then
Set_Data (Instance, File);
return;
end if;
end;
end if;
Set_Data (Instance, Create_From_Base (Name));
end;
elsif Command = "name" then
Name_Parameters (Data, File_Name_Parameters);
Info := Nth_Arg (Data, 1);
-- Ignore server argument here
Set_Return_Value (Data, Full_Name (Info));
elsif Command = "path" then
Info := Nth_Arg (Data, 1);
Data.Set_Return_Value (Full_Name (Info));
elsif Command = "directory" then
Info := Nth_Arg (Data, 1);
Set_Return_Value (Data, Dir_Name (Info));
elsif Command = "other_file" then
P := GNATCOLL.Scripts.Projects.Project_Tree;
if P = null then
Set_Error_Msg (Data, "Project not set");
else
Info := Nth_Arg (Data, 1);
Data.Set_Return_Value
(Create_File (Data.Get_Script, P.Other_File (Info)));
end if;
elsif Command = "unit" then
P := GNATCOLL.Scripts.Projects.Project_Tree;
if P = null then
Set_Error_Msg (Data, "Project not set");
return;
end if;
Info := Nth_Arg (Data, 1);
-- Return the first possible project, we have nothing else to base
-- our guess on.
declare
F_Info : constant GNATCOLL.Projects.File_Info'Class :=
GNATCOLL.Projects.File_Info'Class
(P.Info_Set (Info).First_Element);
begin
Data.Set_Return_Value (F_Info.Unit_Name);
end;
elsif Command = "project" then
P := GNATCOLL.Scripts.Projects.Project_Tree;
if P = null then
Set_Error_Msg (Data, "Project not set");
return;
end if;
Name_Parameters (Data, File_Project_Parameters);
Info := Nth_Arg (Data, 1);
Data.Set_Return_Value
(GNATCOLL.Scripts.Projects.Create_Project
(Data.Get_Script,
Get_Project
(Info,
Default_To_Root => Nth_Arg (Data, 2, True))));
elsif Command = "executable_path" then
P := GNATCOLL.Scripts.Projects.Project_Tree;
if P = null then
Set_Error_Msg (Data, "Project not set");
return;
end if;
Info := Nth_Arg (Data, 1);
declare
use GNATCOLL.Projects;
Project : constant GNATCOLL.Projects.Project_Type :=
Get_Project (Info, Default_To_Root => True);
Is_Native : constant Boolean := Project.Get_Target = "native"
or else Project.Get_Target = "";
Include_Suffix : constant Boolean := Is_Native
or else Project.Attribute_Value
(Attribute => Build ("Builder", "Executable_Suffix")) /= "";
begin
-- Don't include the suffix for non-native targets, unless if the
-- Builder'Executable_Suffix has been explicitly set in the
-- project.
-- This is a temporary workaround for Q304-013.
Data.Set_Return_Value
(Create_File
(Script => Data.Get_Script,
File => Project.Executables_Directory
/ Project.Executable_Name
(Info.Base_Name, Include_Suffix => Include_Suffix)));
end;
end if;
end File_Command_Handler;
--------------------
-- Get_File_Class --
--------------------
function Get_File_Class
(Repo : access Scripts_Repository_Record'Class)
return Class_Type is
begin
return New_Class (Repo, File_Class_Name);
end Get_File_Class;
-------------
-- Nth_Arg --
-------------
function Nth_Arg
(Data : Callback_Data'Class; N : Positive)
return GNATCOLL.VFS.Virtual_File
is
Class : constant Class_Type := Get_File_Class (Data);
Inst : constant Class_Instance := Nth_Arg (Data, N, Class);
begin
return Get_Data (Inst);
end Nth_Arg;
-----------------------
-- Register_Commands --
-----------------------
procedure Register_Commands
(Repo : access Scripts_Repository_Record'Class)
is
begin
Register_Property
(Repo, "executable_path",
Class => Get_File_Class (Repo),
Getter => File_Command_Handler'Access);
Register_Command
(Repo, Constructor_Method,
Minimum_Args => 1,
Maximum_Args => 2,
Class => Get_File_Class (Repo),
Handler => File_Command_Handler'Access);
Register_Command
(Repo, "name",
Minimum_Args => 0,
Maximum_Args => 1,
Class => Get_File_Class (Repo),
Handler => File_Command_Handler'Access);
Repo.Register_Property
("path",
Class => Get_File_Class (Repo),
Getter => File_Command_Handler'Access);
Register_Command
(Repo, "directory",
Class => Get_File_Class (Repo),
Handler => File_Command_Handler'Access);
Register_Command
(Repo, "unit",
Class => Get_File_Class (Repo),
Handler => File_Command_Handler'Access);
Register_Command
(Repo, "other_file",
Class => Get_File_Class (Repo),
Handler => File_Command_Handler'Access);
Register_Command
(Repo, "project",
Minimum_Args => 0,
Maximum_Args => 1,
Class => Get_File_Class (Repo),
Handler => File_Command_Handler'Access);
end Register_Commands;
--------------
-- Set_Data --
--------------
procedure Set_Data (Instance : Class_Instance; File : Virtual_File) is
begin
if not Is_Subclass (Instance, File_Class_Name) then
raise Invalid_Data;
end if;
Set_Data
(Instance, File_Class_Name,
File_Properties_Record'(File => File));
end Set_Data;
-----------------
-- Set_Nth_Arg --
-----------------
procedure Set_Nth_Arg
(Data : in out Callback_Data'Class;
N : Positive;
File : GNATCOLL.VFS.Virtual_File)
is
Inst : constant Class_Instance := Create_File (Get_Script (Data), File);
begin
Set_Nth_Arg (Data, N, Inst);
end Set_Nth_Arg;
end GNATCOLL.Scripts.Files;
|