/usr/share/perl5/Rex/Commands/Sysctl.pm is in rex 1.6.0-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 | #
# (c) Jan Gehring <jan.gehring@gmail.com>
#
# vim: set ts=2 sw=2 tw=0:
# vim: set expandtab:
=head1 NAME
Rex::Commands::Sysctl - Manipulate sysctl
=head1 DESCRIPTION
With this module you can set and get sysctl parameters.
Version <= 1.0: All these functions will not be reported.
All these functions are not idempotent.
=head1 SYNOPSIS
use Rex::Commands::Sysctl;
my $data = sysctl "net.ipv4.tcp_keepalive_time";
sysctl "net.ipv4.tcp_keepalive_time" => 1800;
=head1 EXPORTED FUNCTIONS
=cut
package Rex::Commands::Sysctl;
use strict;
use warnings;
our $VERSION = '1.6.0'; # VERSION
use Rex::Logger;
use Rex::Commands::Run;
use Rex::Helper::Run;
use Rex::Commands::File;
require Rex::Exporter;
use base qw(Rex::Exporter);
use vars qw(@EXPORT);
@EXPORT = qw(sysctl);
=head2 sysctl($key [, $val [, %options]])
This function will read the sysctl key $key.
If $val is given, then this function will set the sysctl key $key.
task "tune", "server01", sub {
if( sysctl("net.ipv4.ip_forward") == 0 ) {
sysctl "net.ipv4.ip_forward" => 1;
}
};
If both $val and ensure option are used, the sysctl key is modified and the value may persist in /etc/sysctl.conf depending if ensure option is "present" or "absent".
With ensure => "present", if the key already exists in the file, it will be updated to the new value.
task "forwarding", "server01", sub {
sysctl "net.ipv4.ip_forward" => 1, ensure => "present";
}
=cut
sub sysctl_save {
my ( $key, $value ) = @_;
append_or_amend_line "/etc/sysctl.conf",
line => "$key=$value",
regexp => qr{\Q$key=},
on_change => sub { i_run '/sbin/sysctl -p' };
}
sub sysctl_remove {
my ( $key, $value ) = @_;
delete_lines_according_to "$key=$value", "/etc/sysctl.conf",
on_change => sub { i_run '/sbin/sysctl -p' };
}
sub sysctl {
my ( $key, $val, %options ) = @_;
if ($val) {
Rex::Logger::debug("Setting sysctl key $key to $val");
my $ret = i_run "/sbin/sysctl -n $key";
if ( $ret ne $val ) {
i_run "/sbin/sysctl -w $key=$val", fail_ok => 1;
if ( $? != 0 ) {
die("Sysctl failed $key -> $val");
}
}
else {
Rex::Logger::debug("$key has already value $val");
}
if ( $options{ensure} || $options{persistent} ) {
if ( $options{ensure} eq "present" ) {
Rex::Logger::debug("Writing $key=$val to sysctl.conf");
sysctl_save $key, $val;
}
elsif ( $options{ensure} eq "absent" ) {
Rex::Logger::debug("Removing $key=$val of sysctl.conf");
sysctl_remove $key, $val;
}
else {
Rex::Logger::info(
"Error : " . $options{ensure} . " is not a known ensure parameter" );
}
}
}
else {
my $ret = i_run "/sbin/sysctl -n $key", fail_ok => 1;
if ( $? == 0 ) {
return $ret;
}
else {
Rex::Logger::info( "Error getting sysctl key: $key", "warn" );
die("Error getting sysctl key: $key");
}
}
}
1;
|