/usr/share/doc/gri/examples/example6histogram.gri is in gri-html-doc 2.12.26-1build1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 | # Example 6 -- Plot IR image of Gulf of Maine
# define characteristics of norda images
\0val = "5" # 0 in image
\255val = "30.5" # 255 in image
.rows. = 128
.cols. = 128
.pixel_width. = 2
.km. = {rpn .cols. .pixel_width. *}
# get filenames
query \filename "Name image file" ("example6image.dat")
query \maskname "Name mask file" ("example6mask.dat")
# get data
open \filename binary uchar
set image range \0val \255val
read image .rows. .cols. box 0 0 .km. .km.
close
open \maskname binary uchar
read image mask .rows. .cols.
close
# find out what grayscale method to use
query \histo "Do histogram enhancement? (yes|no)" ("yes")
query \minT "T/deg for white on page? " ("10")
query \maxT "T/deg for black on page? " ("15")
\incT = "1"
# set up scales.
set x size 12.8
set y size 12.8
set x name "km"
set y name "km"
set x axis 0 .km. 32
set y axis 0 .km. 32
# plot image, grayscale, and histogram
if {"\histo" == "yes"}
set image grayscale using histogram black \maxT white \minT
else
set image grayscale black \maxT white \minT
end if
draw image
draw image palette left \minT right \maxT increment \incT
draw image histogram
if {"\histo" == "yes"}
draw title "Example 6: grayscale histogram enhanced"
else
draw title "Example 6: grayscale linear \minT to \maxT"
end if
|