/usr/share/perl5/Test2/Compare/OrderedSubset.pm is in libtest2-suite-perl 0.000063-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 | package Test2::Compare::OrderedSubset;
use strict;
use warnings;
use base 'Test2::Compare::Base';
our $VERSION = '0.000063';
use Test2::Util::HashBase qw/inref items/;
use Carp qw/croak/;
use Scalar::Util qw/reftype/;
sub init {
my $self = shift;
if(my $ref = $self->{+INREF}) {
croak "Cannot specify both 'inref' and 'items'" if $self->{+ITEMS};
croak "'inref' must be an array reference, got '$ref'" unless reftype($ref) eq 'ARRAY';
$self->{+ITEMS} = [@{$self->{+INREF}}];
}
$self->{+ITEMS} ||= [];
$self->SUPER::init();
}
sub name { '<ORDERED SUBSET>' }
sub verify {
my $self = shift;
my %params = @_;
return 0 unless $params{exists};
my $got = $params{got} || return 0;
return 0 unless ref($got);
return 0 unless reftype($got) eq 'ARRAY';
return 1;
}
sub add_item {
my $self = shift;
my $check = pop;
push @{$self->{+ITEMS}} => $check;
}
sub deltas {
my $self = shift;
my %params = @_;
my ($got, $convert, $seen) = @params{qw/got convert seen/};
my @deltas;
my $state = 0;
my $items = $self->{+ITEMS};
my $idx = 0;
for my $item (@$items) {
my $check = $convert->($item);
my $i = $idx;
my $found;
while($i < @$got) {
my $val = $got->[$i++];
next if $check->run(
id => [ARRAY => $i],
convert => $convert,
seen => $seen,
exists => 1,
got => $val,
);
$idx = $i;
$found++;
last;
}
next if $found;
push @deltas => Test2::Compare::Delta->new(
verified => 0,
id => ['ARRAY', '?'],
check => $check,
dne => 'got',
);
}
return @deltas;
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Test2::Compare::OrderedSubset - Internal representation of an ordered subset.
=head1 DESCRIPTION
This module is used to ensure an array has all the expected items int he
expected order. It ignores any unexpected items mixed into the array. It only
cares that all the expected values are present, and in order, everything else
is noise.
=head1 METHODS
=over 4
=item $ref = $arr->inref()
If the instance was constructed from an actual array, this will have the
reference to that array.
=item $arrayref = $arr->items()
=item $arr->set_items($arrayref)
All the expected items, in order.
=item $name = $arr->name()
Always returns the string C<< "<ORDERED SUBSET>" >>.
=item $bool = $arr->verify(got => $got, exists => $bool)
Check if C<$got> is an array reference or not.
=item $arr->add_item($item)
Add an item to the list of values to check.
=item @deltas = $arr->deltas(got => $got, convert => \&convert, seen => \%seen)
Find the differences between the expected array values and those in the C<$got>
arrayref.
=back
=head1 SOURCE
The source code repository for Test2-Suite can be found at
F<http://github.com/Test-More/Test2-Suite/>.
=head1 MAINTAINERS
=over 4
=item Chad Granum E<lt>exodist@cpan.orgE<gt>
=back
=head1 AUTHORS
=over 4
=item Chad Granum E<lt>exodist@cpan.orgE<gt>
=back
=head1 COPYRIGHT
Copyright 2016 Chad Granum E<lt>exodist@cpan.orgE<gt>.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
See F<http://dev.perl.org/licenses/>
=cut
|