/usr/share/java/Jaxe/config/XMLSchema.xsl is in libjaxe-java 3.5-8.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 | <?xml version="1.0" encoding='ISO-8859-1' ?>
<xsl:stylesheet version="1.0"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
exclude-result-prefixes="xs">
<xsl:output method="html" indent="yes"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"/>
<xsl:template match="xs:schema">
<html>
<head>
<title>Schéma XML</title>
<style type="text/css">
body { color: #000000; background: #FFFFFF }
pre { color: #005500 }
.grandlien { font-size: 120%; font-weight: bold }
.nomtitre { color: #550000 }
.nomattribut { color: #000055; font-weight: bold }
.indentation { margin-left: 2em; margin-top: 1em; margin-bottom: 1em }
</style>
</head>
<body>
<div align="center">
<h1>Schéma XML</h1>
</div>
<br/>
<span class="grandlien">
<a href="#index">Aller à l'index</a><br/>
</span>
<hr/>
<xsl:apply-templates/>
<br/>
<a name="index"/>
<h3>Index</h3>
<xsl:for-each select="*[@name]">
<xsl:sort select="@name"/>
<a href="#{@name}"><xsl:value-of select="@name"/></a><br/>
</xsl:for-each>
</body>
</html>
</xsl:template>
<xsl:template name="print-ref">
<xsl:choose>
<xsl:when test="contains(@ref,':')">
<a href="#{substring-after(@ref,':')}"><xsl:value-of select="@ref"/></a>
</xsl:when>
<xsl:otherwise>
<a href="#{@ref}"><xsl:value-of select="@ref"/></a>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="xs:element">
<xsl:choose>
<xsl:when test="@ref">
* <xsl:call-template name="print-ref"/><br/>
</xsl:when>
<xsl:otherwise>
<a name="{@name}"/>
<h3>Elément <span class="nomtitre"><xsl:value-of select="@name"/></span></h3>
<xsl:if test="@type">
type: <xsl:call-template name="nomtype"/><br/>
</xsl:if>
<xsl:apply-templates/>
<br/>
<xsl:for-each select="//xs:element[.//xs:element[@ref=current()/@name or substring-after(@ref,':')=current()/@name]] | //xs:group[.//xs:element[@ref=current()/@name or substring-after(@ref,':')=current()/@name]]">
<xsl:if test="position() = 1">
Parents:
</xsl:if>
<xsl:if test="position() != 1">, </xsl:if>
<a href="#{@name}"><xsl:value-of select="@name"/></a>
</xsl:for-each>
<br/>
<hr/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="xs:group">
<xsl:choose>
<xsl:when test="@ref">
* <xsl:call-template name="print-ref"/>
<br/>
</xsl:when>
<xsl:otherwise>
<a name="{@name}"/>
<h3>Groupe <span class="nomtitre"><xsl:value-of select="@name"/></span></h3>
<xsl:apply-templates/>
<br/>
<xsl:for-each select="//xs:element[.//xs:group[@ref=current()/@name or substring-after(@ref,':')=current()/@name]] | //xs:group[.//xs:group[@ref=current()/@name or substring-after(@ref,':')=current()/@name]]">
<xsl:if test="position() = 1">
Parents:
</xsl:if>
<xsl:if test="position() != 1">, </xsl:if>
<a href="#{@name}"><xsl:value-of select="@name"/></a>
</xsl:for-each>
<br/>
<hr/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="xs:documentation">
<pre><xsl:value-of select="."/></pre>
<br/>
</xsl:template>
<xsl:template match="xs:choice">
Choix parmi:
<div class="indentation">
<xsl:apply-templates/>
</div>
</xsl:template>
<xsl:template match="xs:sequence">
Séquence parmi:
<div class="indentation">
<xsl:apply-templates/>
</div>
</xsl:template>
<xsl:template match="xs:complexType">
<!--Type complexe-->
<xsl:if test="@name">
<a name="type_{@name}"/>
<h3>Type complexe <span class="nomtitre"><xsl:value-of select="@name"/></span></h3>
</xsl:if>
<xsl:if test="@ref">
<a href="{@ref}"><xsl:value-of select="@ref"/></a><br/>
</xsl:if>
<xsl:if test="@mixed='true'">
Peut contenir du texte<br/>
</xsl:if>
<div class="indentation">
<xsl:apply-templates/>
</div>
<xsl:if test="@name">
<hr/>
</xsl:if>
</xsl:template>
<xsl:template match="xs:attribute">
Attribut <span class="nomattribut"><xsl:value-of select="@name"/></span>:
<div class="indentation">
<xsl:choose>
<xsl:when test="@use='required'">
obligatoire<br/>
</xsl:when>
<xsl:otherwise>
facultatif<br/>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="@type">
type: <xsl:call-template name="nomtype"/><br/>
</xsl:if>
<xsl:apply-templates/>
</div>
</xsl:template>
<xsl:template match="xs:simpleType">
<xsl:choose>
<xsl:when test="@name!=''">
<a name="type_{@name}"/>
<h3>Type simple <span class="nomtitre"><xsl:value-of select="@name"/></span></h3>
<xsl:apply-templates/>
<hr/>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="xs:restriction">
Restriction des valeurs:
<ul>
<xsl:apply-templates/>
</ul>
</xsl:template>
<xsl:template match="xs:enumeration">
<li><tt><xsl:value-of select="@value"/></tt></li>
</xsl:template>
<xsl:template match="xs:pattern">
<li><tt><xsl:value-of select="@value"/></tt></li>
</xsl:template>
<xsl:template match="xs:attributeGroup">
<xsl:choose>
<xsl:when test="@ref">
* <xsl:call-template name="print-ref"/>
<br/>
</xsl:when>
<xsl:otherwise>
<a name="{@name}"/>
<h3>Groupe d'attributs <span class="nomtitre"><xsl:value-of select="@name"/></span></h3>
<xsl:apply-templates/>
<br/>
<xsl:for-each select="//xs:element[.//xs:attributeGroup[@ref=current()/@name or substring-after(@ref,':')=current()/@name]] | //xs:attributeGroup[.//xs:attributeGroup[@ref=current()/@name or substring-after(@ref,':')=current()/@name]] | //xs:complexType[.//xs:attributeGroup[@ref=current()/@name or substring-after(@ref,':')=current()/@name] and @name]">
<xsl:if test="position() = 1">
Parents:
</xsl:if>
<xsl:if test="position() != 1">, </xsl:if>
<a href="#{@name}"><xsl:value-of select="@name"/></a>
</xsl:for-each>
<br/>
<hr/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="nomtype">
<xsl:choose>
<xsl:when test="/xs:schema/xs:simpleType[@name=current()/@type]|/xs:schema/xs:complexType[@name=current()/@type]">
<a href="#type_{@type}"><xsl:value-of select="@type"/></a>
</xsl:when>
<xsl:otherwise>
<tt><xsl:value-of select="@type"/></tt>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
|