/usr/share/perl5/Code/TidyAll/Git/Util.pm is in libcode-tidyall-perl 0.55~dfsg-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 | package Code::TidyAll::Git::Util;
use strict;
use warnings;
use Code::TidyAll::Util qw(pushd);
use IPC::System::Simple qw(capturex);
use List::SomeUtils qw(uniq);
use Path::Tiny qw(path);
use Exporter qw(import);
our $VERSION = '0.55';
our @EXPORT_OK = qw(git_files_to_commit git_modified_files);
sub git_files_to_commit {
my ($dir) = @_;
return _relevant_files_from_status( $dir, 1 );
}
sub git_modified_files {
my ($dir) = @_;
return _relevant_files_from_status( $dir, 0 );
}
sub _relevant_files_from_status {
my ( $dir, $index_only ) = @_;
$dir = path($dir);
my $pushed = pushd( $dir->absolute );
my $status = capturex(qw( git status --porcelain -z -uno ));
return unless $status;
return map { $dir->child($_) } _parse_status( $status, $index_only );
}
sub _parse_status {
my ( $status, $index_only ) = @_;
local $_ = $status;
# There can't possibly be more records than nuls plus one, so we use this
# as an upper bound on passes.
my $times = tr/\0/\0/;
my @files;
for my $i ( 0 .. $times ) {
last if /\G\Z/gc;
/\G(..) /g;
my $mode = $1;
/\G([^\0]+)\0/g;
my $name = $1;
# on renames, parse but throw away the "renamed from" filename
if ( $mode =~ /R/ ) {
/\G([^\0]+)\0/g;
}
# deletions and renames don't cause tidying
next unless $mode =~ /[MAC]/;
next if $index_only && $mode =~ /^ /;
push @files, $name;
}
return @files;
}
1;
|