/usr/share/perl5/AtteanX/Store/Memory.pm is in libattean-perl 0.017-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 | =head1 NAME
AtteanX::Store::Memory - Simple in-memory RDF store
=head1 VERSION
This document describes AtteanX::Store::Memory version 0.017
=head1 SYNOPSIS
use AtteanX::Store::Memory;
=head1 DESCRIPTION
AtteanX::Store::Memory provides an in-memory quad-store.
=cut
use v5.14;
use warnings;
package AtteanX::Store::Memory 0.017 {
use Moo;
use Type::Tiny::Role;
use Types::Standard qw(Int ArrayRef HashRef ConsumerOf InstanceOf);
use Encode;
use Set::Scalar;
use Digest::SHA;
use List::Util qw(first);
use Scalar::Util qw(refaddr reftype blessed);
use Math::Cartesian::Product;
use namespace::clean;
with 'Attean::API::MutableQuadStore';
with 'Attean::API::QuadStore';
with 'Attean::API::ETagCacheableQuadStore';
with 'Attean::API::TimeCacheableQuadStore';
with 'Attean::API::CostPlanner';
my @pos_names = Attean::API::Quad->variables;
=head1 ATTRIBUTES
=over 4
=item C<< subject >>
=item C<< predicate >>
=item C<< object >>
=item C<< graph >>
=back
=head1 METHODS
Beyond the methods documented below, this class inherits methods from the
L<Attean::API::QuadStore> class.
=over 4
=item C<< new () >>
Returns a new memory-backed storage object.
=cut
has _size => (is => 'rw', isa => Int, init_arg => undef, default => 0);
has statements => (is => 'rw', isa => ArrayRef[ConsumerOf['Attean::API::Quad']], init_arg => undef, default => sub { [] });
has subject => (is => 'ro', isa => HashRef[InstanceOf['Set::Scalar']], init_arg => undef, default => sub { +{} });
has predicate => (is => 'ro', isa => HashRef[InstanceOf['Set::Scalar']], init_arg => undef, default => sub { +{} });
has object => (is => 'ro', isa => HashRef[InstanceOf['Set::Scalar']], init_arg => undef, default => sub { +{} });
has graph => (is => 'ro', isa => HashRef[InstanceOf['Set::Scalar']], init_arg => undef, default => sub { +{} });
has graph_nodes => (is => 'rw', isa => HashRef[ConsumerOf['Attean::API::IRI']], init_arg => undef, default => sub { +{} });
has hash => (is => 'rw', isa => InstanceOf['Digest::SHA'], default => sub { Digest::SHA->new });
has mtime => (is => 'rw', isa => Int, default => sub { return time() });
=item C<< size >>
Returns the number of quads in the store.
=cut
sub size {
shift->_size()
}
=item C<< get_quads ( $subject, $predicate, $object, $graph ) >>
Returns a stream object of all statements matching the specified subject,
predicate and objects. Any of the arguments may be undef to match any value.
=cut
sub get_quads {
my $self = shift;
my @nodes = map { ref($_) eq 'ARRAY' ? $_ : [$_] } @_;
my @iters;
cartesian { push(@iters, $self->_get_quads(@_)) } @nodes;
return Attean::IteratorSequence->new( iterators => \@iters, item_type => 'Attean::API::Quad' );
}
sub _get_quads {
my $self = shift;
my @nodes = @_;
my $bound = 0;
my %bound;
foreach my $pos (0 .. 3) {
my $n = $nodes[ $pos ];
if (blessed($n) and $n->does('Attean::API::Variable')) {
$n = undef;
$nodes[$pos] = undef;
}
if (blessed($n)) {
$bound++;
$bound{ $pos } = $n;
}
}
if ($bound == 0) {
my $i = 0;
my $sub = sub {
return unless ($i <= $#{ $self->statements });
my $st = $self->statements->[ $i ];
while (not(blessed($st)) and ($i <= $#{ $self->statements })) {
$i++;
$st = $self->statements->[ $i ];
}
$i++;
return $st;
};
return Attean::CodeIterator->new( generator => $sub, item_type => 'Attean::API::Quad' );
}
my $match_set;
if ($bound == 1) {
my ($pos) = keys %bound;
my $name = $pos_names[ $pos ];
my $node = $bound{ $pos };
my $string = $node->as_string;
$match_set = $self->$name()->{ $string };
unless (blessed($match_set)) {
return Attean::ListIterator->new( values => [], item_type => 'Attean::API::Quad' );
}
} else {
my @pos = keys %bound;
my @names = @pos_names[ @pos ];
my @sets;
foreach my $i (0 .. $#pos) {
my $pos = $pos[ $i ];
my $node = $bound{ $pos };
Carp::confess unless ($node->can('as_string'));
my $string = $node->as_string;
my $name = $names[$i];
my $hash = $self->$name();
my $set = $hash->{ $string };
push(@sets, $set);
}
foreach my $s (@sets) {
unless (blessed($s)) {
return Attean::ListIterator->new( values => [], item_type => 'Attean::API::Quad' );
}
}
my $i = shift(@sets);
while (@sets) {
my $s = shift(@sets);
$i = $i->intersection($s);
}
$match_set = $i;
}
my @e = $match_set->elements;
my $sub = sub {
return unless (scalar(@e));
my $e = shift(@e);
my $st = $self->statements->[ $e ];
return $st;
};
return Attean::CodeIterator->new( generator => $sub, item_type => 'Attean::API::Quad' );
}
=item C<< get_graphs >>
Returns an iterator over the Attean::API::Term objects comprising
the set of graphs of the stored quads.
=cut
sub get_graphs {
my $self = shift;
my @ctx = values %{ $self->graph_nodes() };
return Attean::ListIterator->new( values => \@ctx, item_type => 'Attean::API::Term' );
}
=item C<< add_quad ( $quad ) >>
Adds the specified C<$quad> to the underlying model.
=cut
sub add_quad {
my $self = shift;
my $st = shift;
my $count = $self->count_quads( $st->values );
if ($count == 0) {
$self->_size($self->_size + 1);
my $id = scalar(@{ $self->statements });
$self->hash->add('+' . encode_utf8($st->as_string));
$self->mtime(time());
push( @{ $self->statements }, $st );
foreach my $pos (0 .. $#pos_names) {
my $name = $pos_names[ $pos ];
my $node = $st->$name();
my $string = $node->as_string;
my $set = $self->$name()->{ $string };
unless (blessed($set)) {
$set = Set::Scalar->new();
$self->$name()->{ $string } = $set;
}
$set->insert( $id );
}
my $ctx = $st->graph;
my $str = $ctx->as_string;
unless (exists $self->graph_nodes->{ $str }) {
$self->graph_nodes->{ $str } = $ctx;
}
}
return;
}
=item C<< remove_quad ( $statement ) >>
Removes the specified C<$statement> from the underlying model.
=cut
sub remove_quad {
my $self = shift;
my $st = shift;
my @nodes = $st->values;
my $count = $self->count_quads( @nodes[ 0..3 ] );
if ($count > 0) {
$self->_size( $self->_size - 1 );
my $id = $self->_statement_id( $st->values );
$self->hash->add('-' . encode_utf8($st->as_string));
$self->mtime(time());
$self->statements->[ $id ] = undef;
foreach my $pos (0 .. 3) {
my $name = $pos_names[ $pos ];
my $node = $st->$name();
my $str = $node->as_string;
my $set = $self->$name()->{ $str };
$set->delete( $id );
if ($set->size == 0) {
if ($pos == 3) {
delete $self->graph_nodes->{ $str };
}
delete $self->$name()->{ $str };
}
}
}
return;
}
=item C<< remove_quads ( $subject, $predicate, $object, $graph ) >>
Removes the specified C<$statement> from the underlying model.
=cut
sub remove_quads {
my $self = shift;
my @nodes = map { ref($_) eq 'ARRAY' ? $_ : [$_] } @_;
my @iters;
cartesian { $self->_remove_quads(@_) } @nodes;
}
sub _remove_quads {
my $self = shift;
my $subj = shift;
my $pred = shift;
my $obj = shift;
my $graph = shift;
my $iter = $self->get_quads( $subj, $pred, $obj, $graph );
while (my $st = $iter->next) {
$self->remove_quad( $st );
}
}
=item C<< create_graph( $graph ) >>
This is a no-op function for the memory quad-store.
=cut
sub create_graph {
# no-op on a quad-store
}
=item C<< drop_graph( $graph ) >>
Removes all quads with the given C<< $graph >>.
=cut
sub drop_graph {
my $self = shift;
return $self->clear_graph(@_);
}
=item C<< clear_graph( $graph ) >>
Removes all quads with the given C<< $graph >>.
=cut
sub clear_graph {
my $self = shift;
my $g = shift;
my $string = $g->as_string;
my $set = $self->graph()->{ $string };
return unless (blessed($set));
my @quads = @{ $self->statements}[ $set->elements ];
foreach my $q (@quads) {
$self->remove_quad($q);
}
}
=item C<< count_quads ( $subject, $predicate, $object, $graph ) >>
Returns a count of all the statements matching the specified subject,
predicate, object, and graph. Any of the arguments may be undef to match any
value.
=cut
sub count_quads {
my $self = shift;
my @nodes = map { ref($_) eq 'ARRAY' ? $_ : [$_] } @_;
my $count = 0;
cartesian { $count += $self->_count_quads(@_) } @nodes;
return $count;
}
sub _count_quads {
my $self = shift;
my @nodes = @_[0..3];
my $bound = 0;
my %bound;
foreach my $pos (0 .. 3) {
my $n = $nodes[ $pos ];
if (ref($n)) {
Carp::confess "Non-Attean node?" unless (ref($n) =~ /Attean/);
}
if (blessed($n) and not($n->does('Attean::API::Variable'))) {
$bound++;
$bound{ $pos } = $n;
}
}
if ($bound == 0) {
return $self->_size;
} elsif ($bound == 1) {
my ($pos) = keys %bound;
my $name = $pos_names[ $pos ];
my $set = $self->$name()->{ $bound{ $pos }->as_string };
unless (blessed($set)) {
return 0;
}
return $set->size;
} else {
my @pos = keys %bound;
my @names = @pos_names[ @pos ];
my @sets;
foreach my $i (0 .. $#names) {
my $pos = $pos[ $i ];
my $setname = $names[ $i ];
my $data = $self->$setname();
my $node = $bound{ $pos };
my $str = $node->as_string;
my $set = $data->{ $str };
push( @sets, $set );
}
foreach my $s (@sets) {
unless (blessed($s)) {
return 0;
}
}
my $i = shift(@sets);
while (@sets) {
my $s = shift(@sets);
$i = $i->intersection($s);
}
return $i->size;
}
}
=item C<< etag_value_for_quads >>
If the store has the capability and knowledge to support caching, returns a
persistent token that will remain consistent as long as the store's data doesn't
change. This token is acceptable for use as an HTTP ETag.
=cut
sub etag_value_for_quads {
my $self = shift;
return $self->hash->b64digest;
}
=item C<< mtime_for_quads >>
=cut
sub mtime_for_quads {
my $self = shift;
return $self->mtime;
}
sub _statement_id {
my $self = shift;
my @nodes = @_;
my ($subj, $pred, $obj, $graph) = @nodes;
my @pos = (0 .. 3);
my @names = @pos_names[ @pos ];
my @sets;
foreach my $i (0 .. $#names) {
my $pos = $pos[ $i ];
my $setname = $names[ $i ];
my $data = $self->$setname();
my $node = $nodes[ $pos ];
my $str = $node->as_string;
my $set = $data->{ $str };
push( @sets, $set );
}
foreach my $s (@sets) {
unless (blessed($s)) {
return -1;
}
}
my $i = shift(@sets);
while (@sets) {
my $s = shift(@sets);
$i = $i->intersection($s);
}
if ($i->size == 1) {
my ($id) = $i->elements;
return $id;
} else {
return -1;
}
}
=item C<< plans_for_algebra >>
The store implements a cost-based query planner, but this method is
reimplemented to hand the overall control of the planning process to
an external planner by returning C<undef>.
=cut
sub plans_for_algebra {
my $self = shift;
my $algebra = shift;
return;
}
=item C<< cost_for_plan >>
This store provides a cost estimate only for retrieving individual
quad patterns in this method. It will allow other planners to estimate
the cost for any other parts of the plan by returning C<undef> for
those parts.
=cut
sub cost_for_plan {
my $self = shift;
my $plan = shift;
if ($plan->isa('Attean::Plan::Quad')) {
my @values = $plan->values;
my $count = $self->count_quads(@values);
return $count;
}
return;
}
}
1;
__END__
=back
=head1 BUGS
Please report any bugs or feature requests to through the GitHub web interface
at L<https://github.com/kasei/perlrdf2/issues>.
=head1 AUTHOR
Gregory Todd Williams C<< <gwilliams@cpan.org> >>
=head1 COPYRIGHT
Copyright (c) 2014--2016 Gregory Todd Williams. This
program is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.
=cut
|