/usr/share/xml/docbook/custom/website/2.5.0/xsl/tabular.xsl is in docbook-website 2.5.0.0-8.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 | <?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:html='http://www.w3.org/1999/xhtml'
xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
exclude-result-prefixes="html doc"
version="1.0">
<xsl:import href="website-common.xsl"/>
<xsl:include href="toc-tabular.xsl"/>
<xsl:output method="html"
indent="no"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
/>
<xsl:param name="autolayout" select="document($autolayout-file, /*)"/>
<!-- ==================================================================== -->
<!-- Netscape gets badly confused if it sees a CSS style... -->
<xsl:param name="admon.style" select="''"/>
<xsl:param name="admon.graphics" select="1"/>
<xsl:param name="admon.graphics.path">graphics/</xsl:param>
<xsl:param name="admon.graphics.extension">.gif</xsl:param>
<xsl:attribute-set name="table.properties">
<xsl:attribute name="border">0</xsl:attribute>
<xsl:attribute name="cellpadding">0</xsl:attribute>
<xsl:attribute name="cellspacing">0</xsl:attribute>
<xsl:attribute name="width">100%</xsl:attribute>
</xsl:attribute-set>
<xsl:attribute-set name="table.navigation.cell.properties">
<xsl:attribute name="valign">top</xsl:attribute>
<xsl:attribute name="align">left</xsl:attribute>
<!-- width is set with $navotocwidth -->
<xsl:attribute name="bgcolor">
<xsl:choose>
<xsl:when test="/webpage/config[@param='navbgcolor']/@value[. != '']">
<xsl:value-of select="/webpage/config[@param='navbgcolor']/@value"/>
</xsl:when>
<xsl:when test="$autolayout/autolayout/config[@param='navbgcolor']/@value[. != '']">
<xsl:value-of select="$autolayout/autolayout/config[@param='navbgcolor']/@value"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$navbgcolor"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</xsl:attribute-set>
<xsl:attribute-set name="table.body.cell.properties">
<xsl:attribute name="valign">top</xsl:attribute>
<xsl:attribute name="align">left</xsl:attribute>
<!-- width is set with $navobodywidth -->
<xsl:attribute name="bgcolor">
<xsl:value-of select="$textbgcolor"/>
</xsl:attribute>
</xsl:attribute-set>
<xsl:param name="body.columns" select="2"/>
<!-- ==================================================================== -->
<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>
<xsl:template name="home.navhead">
<xsl:text>Navhead</xsl:text>
</xsl:template>
<xsl:template name="home.navhead.upperright">
<xsl:text>Upper-right</xsl:text>
</xsl:template>
<xsl:template name="home.navhead.cell">
<td width="50%" valign="middle" align="left">
<xsl:call-template name="home.navhead"/>
</td>
</xsl:template>
<xsl:template name="home.navhead.upperright.cell">
<td width="50%" valign="middle" align="right">
<xsl:call-template name="home.navhead.upperright"/>
</td>
</xsl:template>
<xsl:template name="home.navhead.separator">
<hr/>
</xsl:template>
<xsl:template match="webpage">
<xsl:variable name="id">
<xsl:call-template name="object.id"/>
</xsl:variable>
<xsl:variable name="relpath">
<xsl:call-template name="root-rel-path">
<xsl:with-param name="webpage" select="."/>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="filename">
<xsl:apply-templates select="." mode="filename"/>
</xsl:variable>
<xsl:variable name="tocentry" select="$autolayout/autolayout//*[$id=@id]"/>
<xsl:variable name="toc" select="($tocentry/ancestor-or-self::toc
|$autolayout/autolayout/toc[1])[last()]"/>
<html>
<xsl:apply-templates select="head" mode="head.mode"/>
<xsl:apply-templates select="config" mode="head.mode"/>
<body class="tabular">
<xsl:call-template name="body.attributes"/>
<div class="{name(.)}">
<a name="{$id}"/>
<xsl:call-template name="allpages.banner"/>
<table xsl:use-attribute-sets="table.properties" border="0">
<xsl:if test="$nav.table.summary!=''">
<xsl:attribute name="summary">
<xsl:value-of select="$nav.table.summary"/>
</xsl:attribute>
</xsl:if>
<tr>
<td><img src="{$table.spacer.image}" alt=" " width="1" height="1"/></td>
<xsl:call-template name="hspacer"/>
<td rowspan="2" xsl:use-attribute-sets="table.body.cell.properties">
<xsl:if test="$navbodywidth != ''">
<xsl:attribute name="width">
<xsl:value-of select="$navbodywidth"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="$autolayout/autolayout/toc[1]/@id = $id">
<table border="0" summary="home page extra headers"
cellpadding="0" cellspacing="0" width="100%">
<tr>
<xsl:call-template name="home.navhead.cell"/>
<xsl:call-template name="home.navhead.upperright.cell"/>
</tr>
</table>
<xsl:call-template name="home.navhead.separator"/>
</xsl:if>
<xsl:if test="$autolayout/autolayout/toc[1]/@id != $id
or $suppress.homepage.title = 0">
<xsl:apply-templates select="./head/title" mode="title.mode"/>
</xsl:if>
<xsl:apply-templates select="child::*[name(.) != 'webpage']"/>
<xsl:call-template name="process.footnotes"/>
<br/>
</td>
</tr>
<tr>
<td xsl:use-attribute-sets="table.navigation.cell.properties">
<xsl:if test="$navtocwidth != ''">
<xsl:attribute name="width">
<xsl:choose>
<xsl:when test="/webpage/config[@param='navtocwidth']/@value[. != '']">
<xsl:value-of select="/webpage/config[@param='navtocwidth']/@value"/>
</xsl:when>
<xsl:when test="$autolayout/autolayout/config[@param='navtocwidth']/@value[. != '']">
<xsl:value-of select="$autolayout/autolayout/config[@param='navtocwidth']/@value"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$navtocwidth"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</xsl:if>
<xsl:choose>
<xsl:when test="$toc">
<p class="navtoc">
<xsl:apply-templates select="$toc">
<xsl:with-param name="pageid" select="@id"/>
</xsl:apply-templates>
</p>
</xsl:when>
<xsl:otherwise> </xsl:otherwise>
</xsl:choose>
</td>
<xsl:call-template name="hspacer"/>
</tr>
<xsl:call-template name="webpage.table.footer"/>
</table>
<xsl:call-template name="webpage.footer"/>
</div>
</body>
</html>
</xsl:template>
<xsl:template name="hspacer">
<!-- nop -->
</xsl:template>
<xsl:template match="config[@param='filename']" mode="head.mode">
</xsl:template>
<xsl:template match="webtoc">
<!-- nop -->
</xsl:template>
</xsl:stylesheet>
|