/usr/lib/Tclxml3.3/xpath.tcl is in tclxml 3.3~svn11-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 | # xpath.tcl --
#
# Provides an XPath parser for Tcl,
# plus various support procedures
#
# Copyright (c) 2000-2003 Zveno Pty Ltd
#
# See the file "LICENSE" in this distribution for information on usage and
# redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
#
# $Id: xpath.tcl,v 1.8 2003/12/09 04:43:15 balls Exp $
package provide xpath 1.0
# We need the XML package for definition of Names
package require xml
namespace eval xpath {
namespace export split join createnode
variable axes {
ancestor
ancestor-or-self
attribute
child
descendant
descendant-or-self
following
following-sibling
namespace
parent
preceding
preceding-sibling
self
}
variable nodeTypes {
comment
text
processing-instruction
node
}
# NB. QName has parens for prefix
variable nodetestExpr ^(${::xml::QName})${::xml::allWsp}(\\(${::xml::allWsp}(("|')(.*?)\\5)?${::xml::allWsp}\\))?${::xml::allWsp}(.*)
variable nodetestExpr2 ((($::xml::QName)${::xml::allWsp}(\\(${::xml::allWsp}(("|')(.*?)\\7)?${::xml::allWsp}\\))?)|${::xml::allWsp}(\\*))${::xml::allWsp}(.*)
}
# xpath::split --
#
# Parse an XPath location path
#
# Arguments:
# locpath location path
#
# Results:
# A Tcl list representing the location path.
# The list has the form: {{axis node-test {predicate predicate ...}} ...}
# Where each list item is a location step.
proc xpath::split locpath {
set leftover {}
set result [InnerSplit $locpath leftover]
if {[string length [string trim $leftover]]} {
return -code error "unexpected text \"$leftover\""
}
return $result
}
proc xpath::InnerSplit {locpath leftoverVar} {
upvar $leftoverVar leftover
variable axes
variable nodetestExpr
variable nodetestExpr2
# First determine whether we have an absolute location path
if {[regexp {^/(.*)} $locpath discard locpath]} {
set path {{}}
} else {
set path {}
}
while {[string length [string trimleft $locpath]]} {
if {[regexp {^\.\.(.*)} $locpath discard locpath]} {
# .. abbreviation
set axis parent
set nodetest *
} elseif {[regexp {^/(.*)} $locpath discard locpath]} {
# // abbreviation
set axis descendant-or-self
if {[regexp ^$nodetestExpr2 [string trimleft $locpath] discard discard discard nodetest discard typetest discard discard literal wildcard locpath]} {
set nodetest [ResolveWildcard $nodetest $typetest $wildcard $literal]
} else {
set leftover $locpath
return $path
}
} elseif {[regexp ^\\.${::xml::allWsp}(.*) $locpath discard locpath]} {
# . abbreviation
set axis self
set nodetest *
} elseif {[regexp ^@($::xml::QName)${::xml::allWsp}=${::xml::allWsp}"(\[^"\])"(.*) $locpath discard attrName discard attrValue locpath]} {
# @ abbreviation
set axis attribute
set nodetest $attrName
} elseif {[regexp ^@($::xml::QName)${::xml::allWsp}=${::xml::allWsp}'(\[^'\])'(.*) $locpath discard attrName discard attrValue locpath]} {
# @ abbreviation
set axis attribute
set nodetest $attrName
} elseif {[regexp ^@($::xml::QName)(.*) $locpath discard attrName discard2 locpath]} {
# @ abbreviation
set axis attribute
set nodetest $attrName
} elseif {[regexp ^((${::xml::QName})${::xml::allWsp}::${::xml::allWsp})?\\*(.*) $locpath discard discard axis discard locpath]} {
# wildcard specified
set nodetest *
if {![string length $axis]} {
set axis child
}
} elseif {[regexp ^((${::xml::QName})${::xml::allWsp}::${::xml::allWsp})?$nodetestExpr2 $locpath discard discard axis discard discard discard nodetest discard typetest discard discard literal wildcard locpath]} {
# nodetest, with or without axis
if {![string length $axis]} {
set axis child
}
set nodetest [ResolveWildcard $nodetest $typetest $wildcard $literal]
} else {
set leftover $locpath
return $path
}
# ParsePredicates
set predicates {}
set locpath [string trimleft $locpath]
while {[regexp {^\[(.*)} $locpath discard locpath]} {
if {[regexp {^([0-9]+)(\].*)} [string trim $locpath] discard posn locpath]} {
set predicate [list = {function position {}} [list number $posn]]
} else {
set leftover2 {}
set predicate [ParseExpr $locpath leftover2]
set locpath $leftover2
unset leftover2
}
if {[regexp {^\](.*)} [string trimleft $locpath] discard locpath]} {
lappend predicates $predicate
} else {
return -code error "unexpected text in predicate \"$locpath\""
}
}
set axis [string trim $axis]
set nodetest [string trim $nodetest]
# This step completed
if {[lsearch $axes $axis] < 0} {
return -code error "invalid axis \"$axis\""
}
lappend path [list $axis $nodetest $predicates]
# Move to next step
if {[string length $locpath] && ![regexp ^/(.*) $locpath discard locpath]} {
set leftover $locpath
return $path
}
}
return $path
}
# xpath::ParseExpr --
#
# Parse one expression in a predicate
#
# Arguments:
# locpath location path to parse
# leftoverVar Name of variable in which to store remaining path
#
# Results:
# Returns parsed expression as a Tcl list
proc xpath::ParseExpr {locpath leftoverVar} {
upvar $leftoverVar leftover
variable nodeTypes
set expr {}
set mode expr
set stack {}
while {[string index [string trimleft $locpath] 0] != "\]"} {
set locpath [string trimleft $locpath]
switch $mode {
expr {
# We're looking for a term
if {[regexp ^-(.*) $locpath discard locpath]} {
# UnaryExpr
lappend stack "-"
} elseif {[regexp ^\\\$({$::xml::QName})(.*) $locpath discard varname discard locpath]} {
# VariableReference
lappend stack [list varRef $varname]
set mode term
} elseif {[regexp {^\((.*)} $locpath discard locpath]} {
# Start grouping
set leftover2 {}
lappend stack [list group [ParseExpr $locpath leftover2]]
set locpath $leftover2
unset leftover2
if {[regexp {^\)(.*)} [string trimleft $locpath] discard locpath]} {
set mode term
} else {
return -code error "unexpected text \"$locpath\", expected \")\""
}
} elseif {[regexp {^"([^"]*)"(.*)} $locpath discard literal locpath]} {
# Literal (" delimited)
lappend stack [list literal $literal]
set mode term
} elseif {[regexp {^'([^']*)'(.*)} $locpath discard literal locpath]} {
# Literal (' delimited)
lappend stack [list literal $literal]
set mode term
} elseif {[regexp {^([0-9]+(\.[0-9]+)?)(.*)} $locpath discard number discard locpath]} {
# Number
lappend stack [list number $number]
set mode term
} elseif {[regexp {^(\.[0-9]+)(.*)} $locpath discard number locpath]} {
# Number
lappend stack [list number $number]
set mode term
} elseif {[regexp ^(${::xml::QName})\\(${::xml::allWsp}(.*) $locpath discard functionName discard locpath]} {
# Function call start or abbreviated node-type test
if {[lsearch $nodeTypes $functionName] >= 0} {
# Looking like a node-type test
if {[regexp ^\\)${::xml::allWsp}(.*) $locpath discard locpath]} {
lappend stack [list path [list child [list $functionName ()] {}]]
set mode term
} else {
return -code error "invalid node-type test \"$functionName\""
}
} else {
if {[regexp ^\\)${::xml::allWsp}(.*) $locpath discard locpath]} {
set parameters {}
} else {
set leftover2 {}
set parameters [ParseExpr $locpath leftover2]
set locpath $leftover2
unset leftover2
while {[regexp {^,(.*)} $locpath discard locpath]} {
set leftover2 {}
lappend parameters [ParseExpr $locpath leftover2]
set locpath $leftover2
unset leftover2
}
if {![regexp ^\\)${::xml::allWsp}(.*) [string trimleft $locpath] discard locpath]} {
return -code error "unexpected text \"locpath\" - expected \")\""
}
}
lappend stack [list function $functionName $parameters]
set mode term
}
} else {
# LocationPath
set leftover2 {}
lappend stack [list path [InnerSplit $locpath leftover2]]
set locpath $leftover2
unset leftover2
set mode term
}
}
term {
# We're looking for an expression operator
if {[regexp ^-(.*) $locpath discard locpath]} {
# UnaryExpr
set stack [linsert $stack 0 expr "-"]
set mode expr
} elseif {[regexp ^(and|or|\\=|!\\=|<|>|<\\=|>\\=|\\||\\+|\\-|\\*|div|mod)(.*) $locpath discard exprtype locpath]} {
# AndExpr, OrExpr, EqualityExpr, RelationalExpr or UnionExpr
set stack [linsert $stack 0 $exprtype]
set mode expr
} else {
return -code error "unexpected text \"$locpath\", expecting operator"
}
}
default {
# Should never be here!
return -code error "internal error"
}
}
}
set leftover $locpath
return $stack
}
# xpath::ResolveWildcard --
proc xpath::ResolveWildcard {nodetest typetest wildcard literal} {
variable nodeTypes
switch -glob -- [string length $nodetest],[string length $typetest],[string length $wildcard],[string length $literal] {
0,0,0,* {
return -code error "bad location step (nothing parsed)"
}
0,0,* {
# Name wildcard specified
return *
}
*,0,0,* {
# Element type test - nothing to do
return $nodetest
}
*,0,*,* {
# Internal error?
return -code error "bad location step (found both nodetest and wildcard)"
}
*,*,0,0 {
# Node type test
if {[lsearch $nodeTypes $nodetest] < 0} {
return -code error "unknown node type \"$typetest\""
}
return [list $nodetest $typetest]
}
*,*,0,* {
# Node type test
if {[lsearch $nodeTypes $nodetest] < 0} {
return -code error "unknown node type \"$typetest\""
}
return [list $nodetest $literal]
}
default {
# Internal error?
return -code error "bad location step"
}
}
}
# xpath::join --
#
# Reconstitute an XPath location path from a
# Tcl list representation.
#
# Arguments:
# spath split path
#
# Results:
# Returns an Xpath location path
proc xpath::join spath {
return -code error "not yet implemented"
}
|