/usr/share/ada/adainclude/xmlada/unicode-ces-utf32.adb is in libxmlada5-dev 4.4.2014-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 | ------------------------------------------------------------------------------
-- XML/Ada - An XML suite for Ada95 --
-- --
-- Copyright (C) 2001-2014, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- You should have received a copy of the GNU General Public License along --
-- with this program; see the file COPYING3. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with Unicode.CCS; use Unicode.CCS;
package body Unicode.CES.Utf32 is
------------
-- Encode --
------------
procedure Encode
(Char : Unicode_Char;
Output : in out Byte_Sequence;
Index : in out Natural) is
begin
Output (Index + 1) := Character'Val (Char and 16#000000FF#);
Output (Index + 2) := Character'Val ((Char and 16#0000FF00#) / (2 ** 8));
Output (Index + 3) :=
Character'Val ((Char and 16#00FF0000#) / (2 ** 16));
Output (Index + 4) :=
Character'Val ((Char and 16#FF000000#) / (2 ** 24));
Index := Index + 4;
end Encode;
---------------
-- Encode_BE --
---------------
procedure Encode_BE
(Char : Unicode_Char;
Output : in out Byte_Sequence;
Index : in out Natural) is
begin
Output (Index + 1) :=
Character'Val ((Char and 16#FF000000#) / (2 ** 24));
Output (Index + 2) :=
Character'Val ((Char and 16#00FF0000#) / (2 ** 16));
Output (Index + 3) := Character'Val ((Char and 16#0000FF00#) / (2 ** 8));
Output (Index + 4) := Character'Val (Char and 16#000000FF#);
Index := Index + 4;
end Encode_BE;
----------
-- Read --
----------
procedure Read
(Str : Utf32_LE_String;
Index : in out Positive;
Char : out Unicode_Char) is
begin
if Index > Str'Last - 3 then
raise Incomplete_Encoding;
else
Char := Character'Pos (Str (Index))
+ Character'Pos (Str (Index + 1)) * (2 ** 8)
+ Character'Pos (Str (Index + 2)) * (2 ** 16)
+ Character'Pos (Str (Index + 3)) * (2 ** 24);
-- Overflow error here if Str'Last = Positive'Last and Index was
-- Positive'Last - 3 (thus reading the last character).
Index := Index + 4;
end if;
end Read;
-------------
-- Read_BE --
-------------
procedure Read_BE
(Str : Utf32_BE_String;
Index : in out Positive;
Char : out Unicode_Char) is
begin
if Index > Str'Last - 3 then
raise Incomplete_Encoding;
else
Char := Character'Pos (Str (Index + 3))
+ Character'Pos (Str (Index + 2)) * (2 ** 8)
+ Character'Pos (Str (Index + 1)) * (2 ** 16)
+ Character'Pos (Str (Index)) * (2 ** 24);
Index := Index + 4;
end if;
end Read_BE;
-----------
-- Width --
-----------
function Width (Char : Unicode_Char) return Natural is
pragma Warnings (Off, Char);
begin
return 4;
end Width;
------------
-- Length --
------------
function Length (Str : Utf32_String) return Natural is
begin
return Str'Length / 4;
end Length;
-----------------
-- To_Utf32_LE --
-----------------
function To_Unicode_LE
(Str : Utf32_String;
Cs : Unicode.CCS.Character_Set := Unicode.CCS.Unicode_Character_Set;
Order : Byte_Order := Default_Byte_Order) return Utf32_LE_String
is
Offset : Natural;
O : Byte_Order := Order;
J : Natural := Str'First;
J_Out : Natural;
S : Utf32_LE_String (1 .. Str'Length);
C : Unicode_Char;
BOM : Bom_Type;
begin
Read_Bom (Str, Offset, BOM);
case BOM is
when Utf32_LE => O := Low_Byte_First;
when Utf32_BE => O := High_Byte_First;
when Unknown => null;
when others => raise Invalid_Encoding;
end case;
if O = Low_Byte_First then
if Cs.To_Unicode = Identity'Access then
return Str (Str'First + Offset .. Str'Last);
else
J := J + Offset;
J_Out := S'First - 1;
while J <= Str'Last loop
Read (Str, J, C);
Encode (Cs.To_Unicode (C), S, J_Out);
end loop;
return S (S'First + Offset .. S'Last);
end if;
else
J := J + Offset;
if Cs.To_Unicode = Identity'Access then
while J <= Str'Last loop
S (J + 3) := Str (J);
S (J + 2) := Str (J + 1);
S (J + 1) := Str (J + 2);
S (J) := Str (J + 3);
J := J + 4;
end loop;
else
J_Out := S'First - 1;
while J <= Str'Last loop
Read_BE (Str, J, C);
Encode (Cs.To_Unicode (C), S, J_Out);
end loop;
end if;
return S (S'First + Offset .. S'Last);
end if;
end To_Unicode_LE;
-----------
-- To_CS --
-----------
function To_CS
(Str : Utf32_LE_String;
Cs : Unicode.CCS.Character_Set := Unicode.CCS.Unicode_Character_Set;
Order : Byte_Order := Default_Byte_Order) return Utf32_String
is
J : Natural := Str'First;
S : Utf32_LE_String (1 .. Str'Length);
C : Unicode_Char;
begin
if Order = Low_Byte_First then
if Cs.To_CS = Identity'Access then
return Str;
else
J := J - 1;
while J <= Str'Last loop
Read (Str, J, C);
Encode (Cs.To_CS (C), S, J);
end loop;
return S;
end if;
else
if Cs.To_CS = Identity'Access then
while J <= Str'Last loop
S (J + 3) := Str (J);
S (J + 2) := Str (J + 1);
S (J + 1) := Str (J + 2);
S (J) := Str (J + 3);
J := J + 4;
end loop;
else
J := J - 1;
while J <= Str'Last loop
Read_BE (Str, J, C);
Encode (Cs.To_CS (C), S, J);
end loop;
end if;
return S;
end if;
end To_CS;
end Unicode.CES.Utf32;
|