/usr/share/ada/adainclude/xmlada/dom-readers.adb is in libxmlada5-dev 4.4.2014-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 | ------------------------------------------------------------------------------
-- XML/Ada - An XML suite for Ada95 --
-- --
-- Copyright (C) 2001-2014, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- You should have received a copy of the GNU General Public License along --
-- with this program; see the file COPYING3. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
pragma Ada_05;
with Sax.Attributes; use Sax.Attributes;
with Sax.Symbols; use Sax.Symbols;
with Sax.Utils; use Sax.Utils;
with Unicode; use Unicode;
with Unicode.CES; use Unicode.CES;
with DOM.Core.Attrs; use DOM.Core.Attrs;
with DOM.Core.Nodes; use DOM.Core.Nodes;
with DOM.Core.Documents; use DOM.Core.Documents;
with DOM.Core.Elements; use DOM.Core.Elements;
with DOM.Core.Character_Datas; use DOM.Core.Character_Datas;
package body DOM.Readers is
--------------------
-- Start_Document --
--------------------
procedure Start_Document (Handler : in out Tree_Reader) is
Implementation : DOM_Implementation;
begin
Handler.Tree := Create_Document
(Implementation, Symbols => Get_Symbol_Table (Handler));
Handler.Current_Node := Handler.Tree;
end Start_Document;
-------------------
-- Start_Element --
-------------------
procedure Start_Element
(Handler : in out Tree_Reader;
NS : Sax.Utils.XML_NS;
Local_Name : Sax.Symbols.Symbol;
Atts : Sax_Attribute_List)
is
Att, Att2 : Attr;
pragma Warnings (Off, Local_Name);
pragma Warnings (Off, Att2);
Name : Qualified_Name;
begin
Handler.Current_Node := Append_Child
(Handler.Current_Node,
Create_Element_NS
(Handler.Tree,
Symbols => Get_Symbol_Table (Handler),
Namespace_URI => Get_URI (NS),
Prefix => Get_Prefix (NS),
Local_Name => Local_Name));
-- Insert the attributes in the right order.
for J in 1 .. Get_Length (Atts) loop
Name := Get_Name (Atts, J);
Att := Create_Attribute_NS
(Handler.Tree,
Symbols => Get_Symbol_Table (Handler),
Namespace_URI => Name.NS,
Prefix => Get_Prefix (Atts, J),
Local_Name => Name.Local);
Set_Value (Att, Get_Value (Atts, J));
Att2 := Set_Attribute_Node (Handler.Current_Node, Att);
if Get_Type (Atts, J) = Sax.Attributes.Id then
Set_Id_Attribute_Node (Handler.Current_Node, Att, Is_Id => True);
end if;
end loop;
end Start_Element;
-----------------
-- End_Element --
-----------------
procedure End_Element
(Handler : in out Tree_Reader;
NS : Sax.Utils.XML_NS;
Local_Name : Sax.Symbols.Symbol)
is
pragma Warnings (Off, NS);
pragma Warnings (Off, Local_Name);
begin
Handler.Current_Node := Parent_Node (Handler.Current_Node);
end End_Element;
----------------
-- Characters --
----------------
procedure Characters
(Handler : in out Tree_Reader; Ch : Unicode.CES.Byte_Sequence)
is
pragma Unmodified (Handler);
Tmp : Node;
pragma Unreferenced (Tmp);
begin
-- If previous child is already a text node, we should just concatenate
-- the two, as required in DOM specifications (in Text node description)
if Last_Child (Handler.Current_Node) /= null
and then Node_Type (Last_Child (Handler.Current_Node)) = Text_Node
then
Append_Data (Last_Child (Handler.Current_Node), Ch);
else
Tmp := Append_Child
(Handler.Current_Node, Create_Text_Node (Handler.Tree, Ch));
end if;
end Characters;
-------------
-- Comment --
-------------
procedure Comment
(Handler : in out Tree_Reader;
Comment : Unicode.CES.Byte_Sequence)
is
pragma Unmodified (Handler);
Tmp : Node;
pragma Unreferenced (Tmp);
begin
Tmp := Append_Child
(Handler.Current_Node, Create_Comment (Handler.Tree, Comment));
end Comment;
--------------------------
-- Ignorable_Whitespace --
--------------------------
procedure Ignorable_Whitespace
(Handler : in out Tree_Reader; Ch : Unicode.CES.Byte_Sequence)
is
pragma Unmodified (Handler);
Tmp : Node;
pragma Unreferenced (Tmp);
begin
-- Ignore these white spaces at the toplevel
if Handler.Current_Node /= Handler.Tree then
Tmp := Append_Child
(Handler.Current_Node, Create_Text_Node (Handler.Tree, Ch));
end if;
end Ignorable_Whitespace;
----------------------------
-- Processing_Instruction --
----------------------------
procedure Processing_Instruction
(Handler : in out Tree_Reader;
Target : Unicode.CES.Byte_Sequence;
Data : Unicode.CES.Byte_Sequence)
is
pragma Unmodified (Handler);
Tmp : Node;
pragma Unreferenced (Tmp);
begin
if not Handler.In_DTD then
Tmp := Append_Child
(Handler.Current_Node,
Create_Processing_Instruction (Handler.Tree, Target, Data));
end if;
end Processing_Instruction;
--------------
-- Get_Tree --
--------------
function Get_Tree (Read : Tree_Reader) return Document is
begin
return Read.Tree;
end Get_Tree;
---------------
-- Start_DTD --
---------------
procedure Start_DTD
(Handler : in out Tree_Reader;
Name : Unicode.CES.Byte_Sequence;
Public_Id : Unicode.CES.Byte_Sequence := "";
System_Id : Unicode.CES.Byte_Sequence := "")
is
pragma Unreferenced (Name, Public_Id, System_Id);
begin
Handler.In_DTD := True;
end Start_DTD;
-------------
-- End_DTD --
-------------
procedure End_DTD (Handler : in out Tree_Reader) is
begin
Handler.In_DTD := False;
end End_DTD;
-----------
-- Error --
-----------
procedure Error
(Handler : in out Tree_Reader;
Except : Sax.Exceptions.Sax_Parse_Exception'Class) is
begin
Fatal_Error (Handler, Except);
end Error;
-------------
-- Warning --
-------------
procedure Warning
(Handler : in out Tree_Reader;
Except : Sax.Exceptions.Sax_Parse_Exception'Class) is
begin
if Handler.Warnings_As_Error then
Fatal_Error (Handler, Except);
end if;
end Warning;
----------
-- Free --
----------
procedure Free (Read : in out Tree_Reader) is
begin
Free (Read.Tree);
Read.Tree := null;
end Free;
----------------------------
-- Set_Warnings_As_Errors --
----------------------------
procedure Set_Warnings_As_Errors
(Read : in out Tree_Reader; Warnings_As_Error : Boolean) is
begin
Read.Warnings_As_Error := Warnings_As_Error;
end Set_Warnings_As_Errors;
------------------
-- Current_Node --
------------------
function Current_Node (Read : Tree_Reader) return Node is
begin
return Read.Current_Node;
end Current_Node;
end DOM.Readers;
|