/usr/share/ada/adainclude/gnatcoll/gnatcoll-json.adb is in libgnatcoll1.6-dev 1.6gpl2014-6.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116 1117 1118 1119 1120 1121 1122 1123 1124 1125 1126 1127 1128 1129 1130 1131 1132 1133 1134 1135 1136 1137 1138 1139 1140 1141 1142 1143 1144 1145 1146 1147 1148 1149 1150 | ------------------------------------------------------------------------------
-- G N A T C O L L --
-- --
-- Copyright (C) 2011-2014, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- --
-- --
-- --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with Ada.Characters.Handling; use Ada.Characters.Handling;
with Ada.Strings.Unbounded; use Ada.Strings.Unbounded;
with Ada.Text_IO;
with GNATCOLL.JSON.Utility;
-------------------
-- GNATCOLL.JSON --
-------------------
package body GNATCOLL.JSON is
procedure Report_Error (File : String; Line, Col : Natural; Msg : String);
pragma No_Return (Report_Error);
procedure Write
(Item : JSON_Value;
Compact : Boolean;
Indent : Natural;
Ret : in out Unbounded_String);
-- Auxiliary write function
function Read
(Strm : Unbounded_String;
Idx : access Natural;
Col : access Natural;
Line : access Natural;
Filename : String) return JSON_Value;
-- ???
------------------
-- Report_Error --
------------------
procedure Report_Error (File : String; Line, Col : Natural; Msg : String) is
L : constant String := Line'Img;
C : constant String := Col'Img;
begin
Ada.Text_IO.New_Line;
if File = "" then
Ada.Text_IO.Put ("<stream>:");
else
Ada.Text_IO.Put (File & ":");
end if;
Ada.Text_IO.Put_Line
(L (L'First + 1 .. L'Last) & ":" & C (C'First + 1 .. C'Last) & ": " &
Msg);
raise Invalid_JSON_Stream with Msg;
end Report_Error;
----------
-- Read --
----------
function Read
(Strm : Unbounded_String;
Idx : access Natural;
Col : access Natural;
Line : access Natural;
Filename : String) return JSON_Value
is
procedure Error (Msg : String);
pragma No_Return (Error);
procedure Next_Char (N : Natural := 1);
procedure Skip_Blancks;
-- Does Idx + 1 until a non-blanck character is found
function Read_String return UTF8_Unbounded_String;
-- Reads a string
-----------
-- Error --
-----------
procedure Error (Msg : String) is
begin
Report_Error (Filename, Line.all, Col.all, Msg);
end Error;
---------------
-- Next_Char --
---------------
procedure Next_Char (N : Natural := 1) is
begin
if N > 1 then
for J in 1 .. N - 1 loop
Next_Char;
end loop;
end if;
Idx.all := Idx.all + 1;
if Idx.all > Length (Strm) then
Col.all := Col.all + 1;
elsif Element (Strm, Idx.all) = ASCII.CR then
Col.all := 0;
elsif Element (Strm, Idx.all) = ASCII.LF then
Col.all := 1;
Line.all := Line.all + 1;
else
Col.all := Col.all + 1;
end if;
end Next_Char;
------------------
-- Skip_Blancks --
------------------
procedure Skip_Blancks is
begin
while Idx.all <= Length (Strm) loop
exit when Element (Strm, Idx.all) /= ' '
and then Element (Strm, Idx.all) /= ASCII.HT
and then Element (Strm, Idx.all) /= ASCII.CR
and then Element (Strm, Idx.all) /= ASCII.LF;
Next_Char;
end loop;
end Skip_Blancks;
-----------------
-- Read_String --
-----------------
function Read_String return UTF8_Unbounded_String is
Prev : Natural;
begin
Prev := Idx.all;
while Idx.all < Length (Strm) loop
Next_Char;
if Element (Strm, Idx.all) = '\' then
Next_Char;
elsif Element (Strm, Idx.all) = '"' then
exit;
end if;
end loop;
if Idx.all > Length (Strm)
or else Element (Strm, Idx.all) /= '"'
then
Error ("Invalid string: cannot find ending """);
end if;
-- Skip the trailing '"'
Next_Char;
return Utility.Un_Escape_String (Strm, Prev, Idx.all - 1);
end Read_String;
begin
Skip_Blancks;
if Idx.all not in 1 .. Length (Strm) then
Error ("Nothing to read from stream");
end if;
case Element (Strm, Idx.all) is
when 'n' | 'N' =>
-- null
if To_Lower (Slice (Strm, Idx.all, Idx.all + 3)) /= "null" then
Error ("Invalid token");
end if;
Next_Char (4);
return Create;
when 't' =>
-- true
if To_Lower (Slice (Strm, Idx.all, Idx .all + 3)) /= "true" then
Error ("Invalid token");
end if;
Next_Char (4);
return Create (True);
when 'f' =>
-- false
if To_Lower (Slice (Strm, Idx.all, Idx.all + 4)) /= "false" then
Error ("Invalid token");
end if;
Next_Char (5);
return Create (False);
when '-' | '0' .. '9' =>
-- Numerical value
declare
type Num_Part is (Trail, Int, Frac, Exp);
Unb : Unbounded_String;
Part : Num_Part := Trail;
Old_Col : constant Natural := Col.all;
Old_Line : constant Natural := Line.all;
begin
-- Potential initial '-'
if Element (Strm, Idx.all) = '-' then
Append (Unb, Element (Strm, Idx.all));
Next_Char;
if Idx.all > Length (Strm)
or else Element (Strm, Idx.all) not in '0' .. '9'
then
Error
("Expecting a digit after the initial '-' when " &
"decoding a number");
end if;
end if;
while Idx.all <= Length (Strm) loop
if Part = Trail
and then Element (Strm, Idx.all) in '1' .. '9'
then
-- Non-0 value, we can start adding the digits to the
-- Int part of the number
Part := Int;
elsif (Part = Trail or else Part = Int)
and then Element (Strm, Idx.all) = '.'
then
if Part = Trail then
Append (Unb, "0");
end if;
Part := Frac;
Append (Unb, Element (Strm, Idx.all));
Next_Char;
if Idx.all > Length (Strm)
or else Element (Strm, Idx.all) not in '0' .. '9'
then
Error ("Expecting digits after a '.' when decoding " &
"a number");
end if;
elsif Part /= Exp
and then (Element (Strm, Idx.all) = 'e'
or else Element (Strm, Idx.all) = 'E')
then
if Part = Trail then
-- Although legal, so handled here, this case is
-- a number of the form 0e99.
Append (Unb, "0");
end if;
-- Authorized patterns for exponent: (e|E)(+|-)?[0-9]+
Part := Exp;
Append (Unb, Element (Strm, Idx.all));
Next_Char;
if Idx.all > Length (Strm) then
Error ("Invalid number");
end if;
if Element (Strm, Idx.all) = '+'
or else Element (Strm, Idx.all) = '-'
then
Append (Unb, Element (Strm, Idx.all));
Next_Char;
end if;
if Idx.all > Length (Strm)
or else Element (Strm, Idx.all) not in '0' .. '9'
then
Error ("Expecting digits after 'e' when decoding " &
"a number");
end if;
end if;
exit when Idx.all > Length (Strm)
or else Element (Strm, Idx.all) not in '0' .. '9';
-- Ignore trailing zeros
if Part /= Trail then
Append (Unb, Element (Strm, Idx.all));
end if;
Next_Char;
end loop;
if Part = Trail then
-- The number only contains zeros
return Create (Long_Long_Integer'(0));
elsif Part = Int then
-- Protect against too large values to fit in the stack: a
-- 128-bit integer is maximum 39 digits, so any longer
-- string won't fit into an integer, whatever the CPU.
-- Note that the string representation is already striped
-- of trailing zeros, see the decoding part above.
if Length (Unb) > 40 then
Report_Error
(Filename, Old_Line, Old_Col,
"Numerical value too large to fit " &
"into a Long_Long_Integer");
end if;
declare
Int : Long_Long_Integer;
begin
Int := Long_Long_Integer'Value (To_String (Unb));
return Create (Int);
exception
when Constraint_Error | Storage_Error =>
-- The test above is not sufficient ... We still catch
-- too large values here.
Report_Error
(Filename, Old_Line, Old_Col,
"Numerical value too large to fit " &
"into a Long_Long_Integer");
end;
else
declare
Flt : Float;
begin
Flt := Float'Value (To_String (Unb));
if not Flt'Valid then
raise Constraint_Error;
end if;
return Create (Flt);
exception
when Constraint_Error =>
Report_Error
(Filename, Old_Line, Old_Col,
"Numerical value too large to fit " &
"into an IEEE 754 float");
end;
end if;
end;
when '"' =>
return Create (Read_String);
when '[' =>
declare
Arr : constant JSON_Array_Access := new JSON_Array;
First : Boolean := True;
begin
-- Skip '['
Next_Char;
while Idx.all < Length (Strm) loop
Skip_Blancks;
if Idx.all > Length (Strm) then
Error ("Uncomplete JSON array");
end if;
exit when Element (Strm, Idx.all) = ']';
if not First then
if Element (Strm, Idx.all) /= ',' then
Error ("Expected ',' in the array value");
end if;
-- Skip the coma
Next_Char;
end if;
First := False;
Append (Arr.all, Read (Strm, Idx, Col, Line, Filename));
end loop;
if Idx.all > Length (Strm)
or else Element (Strm, Idx.all) /= ']'
then
Error ("Unfinished array, expecting ending ']'");
end if;
Next_Char;
declare
Ret : JSON_Value;
begin
Ret.Kind := JSON_Array_Type;
Ret.Arr_Value := Arr;
return Ret;
end;
end;
when '{' =>
declare
First : Boolean := True;
Ret : JSON_Value;
begin
-- Allocate internal container
Ret.Kind := JSON_Object_Type;
Ret.Obj_Value := new JSON_Object_Internal;
-- Skip '{'
Next_Char;
while Idx.all < Length (Strm) loop
Skip_Blancks;
if Idx.all > Length (Strm) then
Error ("Unterminated object value");
end if;
exit when Element (Strm, Idx.all) = '}';
if not First then
if Element (Strm, Idx.all) /= ',' then
Error ("Expected ',' as object value separator");
end if;
-- Skip the coma
Next_Char;
end if;
First := False;
Skip_Blancks;
declare
Name : constant UTF8_Unbounded_String := Read_String;
begin
Skip_Blancks;
if Idx.all > Length (Strm) then
Error ("Unterminated object value");
end if;
if Element (Strm, Idx.all) /= ':' then
Error
("Expected a value after the name in a JSON object"
& " at index" & Idx.all'Img);
end if;
-- Skip the semi-colon
Next_Char;
declare
Item : constant JSON_Value :=
Read (Strm, Idx, Col, Line, Filename);
begin
Set_Field (Ret, To_String (Name), Item);
end;
end;
end loop;
if Idx.all > Length (Strm)
or else Element (Strm, Idx.all) /= '}'
then
Error ("Unterminated object value");
end if;
Next_Char;
return Ret;
end;
when others =>
Error ("Unexpected token");
raise Invalid_JSON_Stream;
end case;
end Read;
function Read
(Strm : Unbounded_String;
Filename : String := "<data>") return JSON_Value
is
Idx : aliased Natural := 1;
Col : aliased Natural := 1;
Line : aliased Natural := 1;
begin
return Read (Strm, Idx'Access, Col'Access, Line'Access, Filename);
end Read;
function Read
(Strm : String;
Filename : String := "<data>") return JSON_Value
is
begin
return Read (To_Unbounded_String (Strm), Filename);
end Read;
-----------
-- Write --
-----------
procedure Write
(Item : JSON_Value;
Compact : Boolean;
Indent : Natural;
Ret : in out Unbounded_String)
is
procedure Do_Indent (Val : Natural);
-- Adds whitespace characters to Ret corresponding to the indentation
-- level.
---------------
-- Do_Indent --
---------------
procedure Do_Indent (Val : Natural) is
begin
if Compact then
return;
end if;
Append (Ret, (1 .. 2 * Val => ' '));
end Do_Indent;
begin
case Item.Kind is
when JSON_Null_Type =>
Append (Ret, "null");
when JSON_Boolean_Type =>
if Item.Bool_Value then
Append (Ret, "true");
else
Append (Ret, "false");
end if;
when JSON_Int_Type =>
declare
S : constant String := Item.Int_Value'Img;
begin
if S (S'First) = ' ' then
Append (Ret, S (S'First + 1 .. S'Last));
else
Append (Ret, S);
end if;
end;
when JSON_Float_Type =>
declare
S : constant String := Item.Flt_Value'Img;
begin
if S (S'First) = ' ' then
Append (Ret, S (S'First + 1 .. S'Last));
else
Append (Ret, S);
end if;
end;
when JSON_String_Type =>
Append (Ret, JSON.Utility.Escape_String (Item.Str_Value));
when JSON_Array_Type =>
Append (Ret, '[');
if not Compact then
Append (Ret, ASCII.LF);
end if;
for J in Item.Arr_Value.Vals.First_Index ..
Item.Arr_Value.Vals.Last_Index
loop
Do_Indent (Indent + 1);
Write
(Item.Arr_Value.Vals.Element (J),
Compact, Indent + 1, Ret);
if J < Item.Arr_Value.Vals.Last_Index then
Append (Ret, ",");
end if;
if not Compact then
Append (Ret, ASCII.LF);
end if;
end loop;
Do_Indent (Indent);
Append (Ret, ']');
when JSON_Object_Type =>
declare
use Object_Items_Pkg;
J : Object_Items_Pkg.Cursor := Item.Obj_Value.Vals.First;
begin
Append (Ret, '{');
if not Compact then
Append (Ret, ASCII.LF);
end if;
while Has_Element (J) loop
Do_Indent (Indent + 1);
Append (Ret, """");
Append (Ret, Element (J).Key);
Append (Ret, """: ");
Write (Element (J).Val, Compact, Indent + 1, Ret);
Next (J);
if Has_Element (J) then
Append (Ret, ",");
end if;
if not Compact then
Append (Ret, ASCII.LF);
end if;
end loop;
Do_Indent (Indent);
Append (Ret, '}');
end;
end case;
end Write;
-----------
-- Write --
-----------
function Write
(Item : JSON_Value; Compact : Boolean := True) return String
is
begin
return To_String (Write (Item, Compact));
end Write;
-----------
-- Write --
-----------
function Write
(Item : JSON_Value; Compact : Boolean := True) return Unbounded_String
is
Ret : Unbounded_String;
begin
Write (Item, Compact, 0, Ret);
return Ret;
end Write;
------------
-- Length --
------------
function Length (Arr : JSON_Array) return Natural is
begin
return Natural (Arr.Vals.Length);
end Length;
--------------
-- Is_Empty --
--------------
function Is_Empty (Arr : JSON_Array) return Boolean is
begin
return Arr.Vals.Is_Empty;
end Is_Empty;
---------
-- Get --
---------
function Get (Arr : JSON_Array; Index : Positive) return JSON_Value is
begin
return Arr.Vals.Element (Index);
end Get;
------------
-- Append --
------------
procedure Append (Arr : in out JSON_Array; Val : JSON_Value) is
begin
Arr.Vals.Append (Val);
end Append;
-------------
-- Prepend --
-------------
procedure Prepend (Arr : in out JSON_Array; Val : JSON_Value) is
begin
Arr.Vals.Prepend (Val);
end Prepend;
---------
-- "&" --
---------
function "&" (Arr : JSON_Array; Value : JSON_Value) return JSON_Array is
Result : JSON_Array := Arr;
begin
Append (Result, Value);
return Result;
end "&";
function "&" (Value1, Value2 : JSON_Value) return JSON_Array is
Result : JSON_Array;
begin
Append (Result, Value1);
Append (Result, Value2);
return Result;
end "&";
-----------
-- Clear --
-----------
procedure Clear (Arr : in out JSON_Array) is
begin
Arr.Vals.Clear;
end Clear;
----------------
-- Initialize --
----------------
overriding procedure Initialize (Obj : in out JSON_Value) is
begin
Obj.Cnt := new Natural'(1);
end Initialize;
------------
-- Adjust --
------------
overriding procedure Adjust (Obj : in out JSON_Value) is
begin
if Obj.Cnt /= null then
-- Cnt is null for JSON_Null, and we do not want to do reference
-- counting for it.
Obj.Cnt.all := Obj.Cnt.all + 1;
end if;
end Adjust;
--------------
-- Finalize --
--------------
overriding procedure Finalize (Obj : in out JSON_Value) is
C : Counter := Obj.Cnt;
begin
if C = null then
return;
end if;
Obj.Cnt := null;
-- Prevent multiple calls to Finalize, which is valid in Ada
C.all := C.all - 1;
if C.all = 0 then
Free (C);
case Obj.Kind is
when JSON_Null_Type |
JSON_Boolean_Type |
JSON_Int_Type |
JSON_Float_Type =>
null;
when JSON_String_Type =>
Obj.Str_Value := Null_Unbounded_String;
when JSON_Array_Type =>
if Obj.Arr_Value /= null then
Free (Obj.Arr_Value);
end if;
when JSON_Object_Type =>
if Obj.Obj_Value /= null then
Free (Obj.Obj_Value);
end if;
end case;
end if;
end Finalize;
------------
-- Create --
------------
function Create return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Null_Type;
return Ret;
end Create;
function Create (Val : Boolean) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Boolean_Type;
Ret.Bool_Value := Val;
return Ret;
end Create;
function Create (Val : Integer) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Int_Type;
Ret.Int_Value := Long_Long_Integer (Val);
return Ret;
end Create;
function Create (Val : Long_Integer) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Int_Type;
Ret.Int_Value := Long_Long_Integer (Val);
return Ret;
end Create;
function Create (Val : Long_Long_Integer) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Int_Type;
Ret.Int_Value := Val;
return Ret;
end Create;
function Create (Val : Float) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Float_Type;
Ret.Flt_Value := Val;
return Ret;
end Create;
function Create (Val : UTF8_String) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_String_Type;
Ret.Str_Value := To_Unbounded_String (Val);
return Ret;
end Create;
function Create (Val : UTF8_Unbounded_String) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_String_Type;
Ret.Str_Value := Val;
return Ret;
end Create;
function Create (Val : JSON_Array) return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Array_Type;
Ret.Arr_Value := new JSON_Array'(Val);
return Ret;
end Create;
-------------------
-- Create_Object --
-------------------
function Create_Object return JSON_Value is
Ret : JSON_Value;
begin
Ret.Kind := JSON_Object_Type;
Ret.Obj_Value := new JSON_Object_Internal;
return Ret;
end Create_Object;
---------------
-- Set_Field --
---------------
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : JSON_Value)
is
Key : constant UTF8_Unbounded_String :=
To_Unbounded_String (Field_Name);
begin
for J in
Val.Obj_Value.Vals.First_Index .. Val.Obj_Value.Vals.Last_Index
loop
if Key = Val.Obj_Value.Vals.Element (J).Key then
Val.Obj_Value.Vals.Replace_Element (J, (Key, Field));
return;
end if;
end loop;
Val.Obj_Value.Vals.Append
((Key => To_Unbounded_String (Field_Name),
Val => Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : Boolean) is
begin
Set_Field (Val, Field_Name, Create (Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : Integer) is
begin
Set_Field (Val, Field_Name, Create (Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : Long_Integer) is
begin
Set_Field (Val, Field_Name, Create (Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : Float) is
begin
Set_Field (Val, Field_Name, Create (Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : UTF8_String) is
begin
Set_Field (Val, Field_Name, Create (Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : UTF8_Unbounded_String) is
begin
Set_Field (Val, Field_Name, Create (Field));
end Set_Field;
procedure Set_Field
(Val : JSON_Value;
Field_Name : UTF8_String;
Field : JSON_Array)
is
F_Val : constant JSON_Value := Create (Field);
begin
Set_Field (Val, Field_Name, F_Val);
end Set_Field;
----------
-- Kind --
----------
function Kind (Val : JSON_Value) return JSON_Value_Type is
begin
return Val.Kind;
end Kind;
---------
-- Get --
---------
function Get (Val : JSON_Value) return Boolean is
begin
return Val.Bool_Value;
end Get;
function Get (Val : JSON_Value) return Integer is
begin
return Integer (Val.Int_Value);
end Get;
function Get (Val : JSON_Value) return Long_Integer is
begin
return Long_Integer (Val.Int_Value);
end Get;
function Get (Val : JSON_Value) return Long_Long_Integer is
begin
return Val.Int_Value;
end Get;
function Get (Val : JSON_Value) return Float is
begin
return Val.Flt_Value;
end Get;
function Get (Val : JSON_Value) return UTF8_String is
begin
return To_String (Val.Str_Value);
end Get;
function Get (Val : JSON_Value) return UTF8_Unbounded_String is
begin
return Val.Str_Value;
end Get;
function Get
(Val : JSON_Value;
Field : UTF8_String) return JSON_Value
is
Key : constant UTF8_Unbounded_String :=
To_Unbounded_String (Field);
begin
for J in
Val.Obj_Value.Vals.First_Index .. Val.Obj_Value.Vals.Last_Index
loop
if Key = Val.Obj_Value.Vals.Element (J).Key then
return Val.Obj_Value.Vals.Element (J).Val;
end if;
end loop;
return JSON_Null;
end Get;
function Get (Val : JSON_Value) return JSON_Array is
begin
return Val.Arr_Value.all;
end Get;
---------------
-- Has_Field --
---------------
function Has_Field (Val : JSON_Value; Field : UTF8_String) return Boolean is
Key : constant UTF8_Unbounded_String :=
To_Unbounded_String (Field);
begin
for J in
Val.Obj_Value.Vals.First_Index .. Val.Obj_Value.Vals.Last_Index
loop
if Key = Val.Obj_Value.Vals.Element (J).Key then
return True;
end if;
end loop;
return False;
end Has_Field;
---------
-- Get --
---------
function Get (Val : JSON_Value; Field : UTF8_String) return Boolean is
begin
return Get (Get (Val, Field));
end Get;
function Get (Val : JSON_Value; Field : UTF8_String) return Integer is
begin
return Get (Get (Val, Field));
end Get;
function Get (Val : JSON_Value; Field : UTF8_String) return Long_Integer is
begin
return Get (Get (Val, Field));
end Get;
function Get (Val : JSON_Value; Field : UTF8_String) return Float is
begin
return Get (Get (Val, Field));
end Get;
function Get (Val : JSON_Value; Field : UTF8_String) return UTF8_String is
begin
return Get (Get (Val, Field));
end Get;
function Get
(Val : JSON_Value; Field : UTF8_String) return UTF8_Unbounded_String
is
begin
return Get (Get (Val, Field));
end Get;
function Get (Val : JSON_Value; Field : UTF8_String) return JSON_Array is
begin
return Get (Get (Val, Field));
end Get;
---------------------
-- Map_JSON_Object --
---------------------
procedure Map_JSON_Object
(Val : JSON_Value;
CB : access procedure (Name : UTF8_String; Value : JSON_Value))
is
begin
for J in
Val.Obj_Value.Vals.First_Index .. Val.Obj_Value.Vals.Last_Index
loop
CB (To_String (Val.Obj_Value.Vals.Element (J).Key),
Val.Obj_Value.Vals.Element (J).Val);
end loop;
end Map_JSON_Object;
---------------------
-- Map_JSON_Object --
---------------------
procedure Gen_Map_JSON_Object
(Val : JSON_Value;
CB : access procedure
(User_Object : in out Mapped;
Name : UTF8_String;
Value : JSON_Value);
User_Object : in out Mapped)
is
procedure Internal (Name : UTF8_String; Value : JSON_Value);
--------------
-- Internal --
--------------
procedure Internal (Name : UTF8_String; Value : JSON_Value) is
begin
CB (User_Object, Name, Value);
end Internal;
begin
Map_JSON_Object (Val, Internal'Access);
end Gen_Map_JSON_Object;
end GNATCOLL.JSON;
|