libtest-net-ldap-perl 0.04-1 / usr / share / perl5 / Test / Net / LDAP / Mock / Node.pm

This file is indexed.

/usr/share/perl5/Test/Net/LDAP/Mock/Node.pm is in libtest-net-ldap-perl 0.04-1.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
use 5.006;
use strict;
use warnings;

package Test::Net::LDAP::Mock::Node;

use Net::LDAP::Util qw(canonical_dn ldap_explode_dn);
use Scalar::Util qw(blessed);

sub new {
    my ($class) = @_;
    
    return bless {
        entry    => undef,
        submap   => {},
        password => undef,
    }, $class;
}

sub entry {
    my $self = shift;
    
    if (@_) {
        my $old = $self->{entry};
        $self->{entry} = shift;
        return $old;
    } else {
        return $self->{entry};
    }
}

sub make_node {
    my ($self, $spec) = @_;
    
    return $self->_descend_path($spec, sub {
        my ($node, $rdn) = @_;
        return $node->_make_subnode($rdn);
    });
}

sub get_node {
    my ($self, $spec) = @_;
    
    return $self->_descend_path($spec, sub {
        my ($node, $rdn) = @_;
        return $node->_get_subnode($rdn);
    });
}

sub traverse {
    my ($self, $callback, $scope) = @_;
    $scope ||= 0; # 0: base, 1: one, 2: sub
    
    my $visit;
    $visit = sub {
        my ($node, $deep) = @_;
        $callback->($node);
        
        # $deep == 0 or 1
        if ($scope > $deep) {
            $node->_each_subnode(sub {
                my ($subnode) = @_;
                $visit->($subnode, 1);
            });
        }
    };
    
    $visit->($self, 0);
}

sub password {
    my $self = shift;
    my $password = $self->{password};
    $self->{password} = shift if @_;
    return $password;
}

sub _descend_path {
    my ($self, $spec, $callback) = @_;
    
    if (ref $spec eq 'HASH') {
        my $node = $callback->($self, $spec);
        return $node;
    } else {
        my $dn_list;
        
        if (ref $spec eq 'ARRAY') {
            $dn_list = $spec;
        } else {
            my $dn = blessed($spec) ? $spec->dn : $spec;
            $dn_list = ldap_explode_dn($dn, casefold => 'lower');
        }
        
        my $node = $self;
        my $parent;
        
        for my $rdn (reverse @$dn_list) {
            $parent = $node;
            $node = $callback->($node, $rdn) or last;
        }
        
        return $node;
    }
}

sub _make_subnode {
    my ($self, $rdn) = @_;
    # E.g. $rdn == {ou => 'Sales'}
    my $canonical = canonical_dn([$rdn], casefold => 'lower');
    return $self->{submap}{$canonical} ||= ref($self)->new;
}

sub _get_subnode {
    my ($self, $rdn) = @_;
    # E.g. $rdn == {ou => 'Sales'}
    my $canonical = canonical_dn([$rdn], casefold => 'lower');
    return $self->{submap}{$canonical};
}

sub _each_subnode {
    my ($self, $callback) = @_;
    my $submap = $self->{submap};
    
    for my $canonical (keys %$submap) {
        $callback->($submap->{$canonical});
    }
}

1;

APT Browse - Built by Thomas Orozco.